Обращение к реквизитам формы в УФ |
Я |
26.06.17 — 17:20
Господа! Как правильно обращаться к реквизитам формы в режиме управляемых форм?
Создал реквизит формы обработки (в «общих» реквизитах). В модуле объекта обращаюсь к нему «ЭтотОбъект.<ИмяРеквизита>». Ошибки не возникает.
В модуле формы обращаюсь «Объект.<ИмяРеквизита>». Пусто.
Делаю реквизит конкретной формы (в правом разделе дизайнера формы). В модуле объекта обращаться к этому реквизиту оно не желает.
Задача-то собственно лишь отображать в форме обработки то, чем сейчас она занимается в модуле объекта, чтобы не скучно было, блин.
1 — 26.06.17 — 17:25
(0) реквизит формы не должен быть виден в модуле объекта
2 — 26.06.17 — 17:32
(0) после того, как что-то сделал в модуле объекта, сделай
ОбновитьОтображениеДанных
на форме.
3 — 26.06.17 — 19:20
(0) Для начала научиться различать реквизит формы и реквизит объекта.
4 — 27.06.17 — 09:42
> после того, как что-то сделал в модуле объекта, сделай
> ОбновитьОтображениеДанных
> на форме.
В первом случае (реквизит объекта, если быть точнее) — не обновляется. Вообще может ли быть реквизит объекта доступен на клиенте в модуле формы?
И подскажите pls, можно ли передавать от клиента к серверу ЭлементDOM (парсинг XML). На клиенте ведь может в принципе выполняться парсинг XML, на сервере тоже.
Но когда верхний цикл парсинга делаю сначала на клиенте в модуле формы, потом передаю ЭлементDOM в модуль объекта, генерит ошибку отображения. Цель — отображать на форме текущее состояние, что он на данный момент парсит.
5 — 27.06.17 — 10:00
Или может я в принципе выбрал не тот подход.
Может, стоило весь парсинг начиная от пути файла делать на сервере в модуле объекта, а клиенту передавать лишь алерты, чтобы он отображал текущее состояние выполнения процедуры на форме? Как?
6 — 27.06.17 — 12:28
Еще попробовал реквизиты объекта (обработка) заюзать для хранения промежуточных данных, необходимых для модуля объекта. Фиг. Оказывается, их значения между вызовами не сохраняются. Напрашивается резонный вопрос: а зачем они тогда нужны?
7 — 27.06.17 — 12:34
(6) Если я правильно понял, ты каждый раз при вызове процедуры из модуля объекта делаешь РеквитиФормыВОбъект?
Чтобы потом сохранить их, надо еще обратно ЗначениеВДанныеФормы делать
8 — 27.06.17 — 12:39
а ты посмотри в сторону фоновых заданий…может они тебе помогут с этим делом справиться…
9 — 27.06.17 — 15:22
>зове процедуры из модуля объекта делаешь РеквитиФормыВОбъект?
Нет, так делал. ЭтотОбъект.<ИмяРеквизита>
Позволяло.
Бум иметь в виду. Спасибо. Что получиццо, нопейшу.
10 — 27.06.17 — 15:25
(9) Может не надо?
11 — 27.06.17 — 16:44
Не получается.
Объявил реквизит объекта с именем КонтекстДанных тип СписокЗначений.
В модуле объекта пишем:
_КонтекстДанных=ДанныеФормыВЗначение(КонтекстДанных,Тип(«СписокЗначений»));
либо
_КонтекстДанных=ДанныеФормыВЗначение(ЭтотОбъект.КонтекстДанных,Тип(«СписокЗначений»));
ругается на несоответствие типов (параметр номер 1).
Аналогичная ошибка возникает при
ЗначениеВДанныеФормы(_КонтекстДанных,ЭтотОбъект.КонтекстДанных);
Как первый параметр преобразовать?
12 — 27.06.17 — 16:49
(11) Погоди, если у тебя управляемые формы, то к модулю объекта ты можешь получить доступ только с объектом
То-есть как-то так, если я не путаю:
РеквизитОбъект = РеквизитФормыВЗначение(«Объект»);
РеквизитОбъект.ТвояПроцедураИлиФункция();
ЗначениеВРеквизитФормы(РеквизитОбъект, «Объект»);
13 — 27.06.17 — 16:49
прогресс выполнения делается совсем не так.
Если встроенный в конфу — то через задание. если внешняя, то
https://github.com/a-sitnikov/ExtForms-grdok/blob/master/Admin/ОбработкаНаСервереСИндикатором.epf
14 — 27.06.17 — 20:42
>РеквизитОбъект = РеквизитФормыВЗначение(«Объект»);
>РеквизитОбъект.ТвояПроцедураИлиФункция();
>ЗначениеВРеквизитФормы(РеквизитОбъект, «Объект»);
Так вроде работает, но при возврате возникает ошибка отображения на некоторых типах, в частности ЭлементDOM.
Всё понял. Дохлый номер. Прогресс бум делать по другому.
Спасибо откликнувшимся. Тему можно считать закрытой.
15 — 28.06.17 — 01:15
(0) Платформу 8.2 придумали 150 лет назад вместе с её управляемыми формами и прочими плюшками, а народ до сих пор её готовить не научился. Стыдно должно быть, господа.
(14) Не используйте в таких случаях модуль объекта в управляемом приложении. Просто переносите его методы в модуль формы или модуль менеджера с передачей всех необходимых параметров.
y-soft
16 — 28.06.17 — 10:47
>вместе с её управляемыми формами
Кому нужны по сути эти управляемые формы? WEB-интерфейс это редкость с учетом тормозов интернета, а так просто досадное недоразумение, очередная стена, через которую перепрыгивать.
>Не используйте в таких случаях модуль объекта в управляемом приложении
Принципиальной разницы не вижу. Все обращения к базе данных идут с директивой &НаСервере, даже в модуле формы. То есть все равно возникнут проблемы при передаче параметров от процедуры &НаКлиенте к процедуре &НаСервере — будет та же ошибка отображения.
Содержание
Формы
Формы используются для удобного отображения данных базы пользователю. С формами можно работать как пользователь интерактивно, так и программист управляя поведением и внешним видом формы с помощью кода.
Типы форм
Формы делятся на два типа: обычные и управляемые, обычные формы это формы которые были в линейке 8 с самого начала и по текущий момент. Смысл этих форм заключается в том что форма в прямом смысле рисуется разработчиком, он указывает на то место (вплоть до пикселя)где будут располагаться элементы формы. Обычные формы работают только в толстом клиенте, в то время когда управляемые формы работают и в толстом и в тонком клиенте. Управляемые формы доступны в версии 1С начиная с 8.2 и выше и только когда конфигурация настроена как «Управляемое приложение». В тонком клиенте возможно использование только управляемых форм. Управляемую форму нельзя нарисовать мышкой. Элементы в ней не рисуются, а декларируются или объявляются, что накладывает некоторые ограничения. Вы можете указать что реквизиты будут группироваться горизонтально а не вертикально к примеру, но нельзя указать системе: «вон то поле ввода на 2пикселя выше пусть будет». В управляемых формах код делится строго на клиентский и серверный. В обычных формах можно встретить некоторые серверные ограничения только в режиме клиент-сервер и только для функций которые не расположены в модулях форм.
Программное открытие формы
Программно открыть форму можно с помощью метода «Открыть форму». Этот метод доступен в различных контекстах(форма может существовать и быть открыта только на клиенте) и отличается при использовании обычного и управляемого приложения(в толстом клиенте нельзя передать параметру в форму) но в целом имеет следующие основные параметры:
ОткрытьФорму(<ИмяФормы>, <Параметры>, <Владелец>, <Уникальность>)
-
Имя формы: имя открываемой формы, так как для объекта метаданных могут быть не определены никакие формы, возможно указать просто тип формы который надо открыть, например «ФормаСписка» или «ФормаЭлемента».
-
Параметры — параметры передаваемые в форму, с их помощью можно управлять отборами, устанавливать строку в нужном месте, или просто передавать в форму нужные параметры.
-
Владелец – используется для организации подбора, обработкой результата выбора если форма открыта для подбора, будет заниматься форма или элемент указанные в этом параметре, так же есть возможность закрывать форму, если закрыта форма-владелец.
-
Уникальность – этот определенный ключ отвечающий за уникальность формы, если этот параметр указан, то при открытии формы будет произведен поиск формы открытой с этим ключом и если такая будет найдена, то будет активирована уже открытая форма.
Принадлежность форм
Формы могут общими(принадлежать к общим формам) или принадлежать определенному виду объектов, например справочнику номенклатура. Если формы принадлежат какому то виду объекта то они могут быть специального типа: например форма списка, эту форму можно использовать для того, что бы просмотреть список документов или форма документа, эту форму можно использовать для редактирования документа. Здесь мы говорим, «можно использовать» так как когда мы щелкаем по документу в списке или когда мы открываем список документов, будет открываться та форма, которая назначена основной. Если основная форма не назначена, при открытии форма будет сгенерирована, вне зависимости от того есть ли в списке форм, форма нужного вида. По сути форма это просто набор полей и кнопок, Форма выбора, форма списка и форма элемента могут отличаться друг от друга только основным реквизитом, который и служит идентификатором для платформы. Основными реквизитами у форм документа и у элемента справочника являются СправочникОбъект и ДокументОбъект.
Для форм выбора и форм списка обычного приложения это СправочникСписок.ВидСправочника и ДокументСписок.ВидДокумента. У управляемого приложения у форм выбора и форм списка основной реквизит ДинамическийСписок.
Форма выбора отличается от формы списка установленным свойством Режим выбора у основного реквизита.
Если форма принадлежит справочникудокументу то для них доступны следующие типы:
-
Форма элемента справочникадокумента
-
Форма группы справочника
-
Форма списка справочникадокумента
-
Форма выбора справочникаъдокумента
-
Форма выбора группы справочника
Разница между элементами формы, и реквизитами объекта.
Для корректной работы с элементами формы, следует для себя четко разделить где нужно пользоваться элементами формы, а где реквизитами объекта. К примеру,
Элементы.Организация
Отвечает за поведение реквизита на форме, начиная от видимости, заканчивая цветом заголовка. В то время как
Объект.Организация
Предоставляет доступ непосредственно к данным.
Обращение к данным формы из модуля объекта.
Обратиться к реквизиту формы(не путайте с реквизитом документасправочника) из модуля документа или справочника невозможно, потому, что модуль не может знать какая форма сейчас открыта(а их ведь может много) да и не факт, что при выполнении процедуры или функции модуля формы, какая то форма будет вообще открыта. Реквизиты формы существуют, только до тех пор, пока форма открыта.
«Толстые» объекты на управляемой форме.
Так как на тонком клиенте недостуны, данные базы данных, серверные объекты(например таблица значений) то на форме их как таковые разместить нельзя в то время, когда они как типы для реквизитов доступны. Здесь дело в том что, при добавлении на форму, добавляется не табличное поле, и не сам список элементов справочника номенклатура к примеру, а коллекция например типа ДанныеФормыКоллекция или ДанныеФормыСтруктура с урезанным функционалом, суть которой заключается в том, чтобы отображать данные таблицы значений которая является реквизитом формы или документа. Список методов, доступных для этих типов, позволяет вести комфортную работу, с данными тех объектов которые они отображают.
Преобразование Реквизит – Данные формы и обратно.
Несмотря на то, что типы ДанныеФормыКоллекция, имеют достаточно широкий функционал, иногда возникает необходимость на сервере получить, «оригинал» — тот объект который отображает форма. Особенно это актуально для реквизитов формы, ведь данные реквизитов объекта, можно получить из самого объекта. Для таких случаев существует метод РеквизитФормыВЗначение(), например:
РеквизитФормыВЗначение (ИмяРеквизита, ТипКоторыйМыХотимПолучитьНаВыходе)
Второй параметр необязательный.
(и не совсем понятно зачем он нужен). Возможно и обратное преобразование, бывает необходимо когда полученный извне или сгенерированный объект «засунуть» в уже существующий реквизит формы, соответствующего типа для этого существует
ЗначениеВРеквизитФормы(ЗначениеКотороеНадоПоложитьНаФорму, ИмяРеквизитаНаФорме)
Перезаполнение реквизитов формы в случае изменения объекта.
Бывают случаи когда объект изменяется не из формы а с помощью какой то процедуры, которая находится в модуле объекта или в любом другом месте. Если действие было инициализировано с помощью кнопки на форме, то после, например таких действий:
ТекущийОбъект = РеквизитФормыВЗначение ("Объект")
ИмяМодуля.КакаяТоПроцедура(ТекущийОбъект);
//или
ТекущийОбъект.ПроцедураФункцияМодуля();
Вы не увидите изменений на форме, все дело в том, что форма не делает лишних вызовов к серверу без необходимости и как следствие не в курсе, что с объектом, что-то происходило. В этом случае надо перечитать данные объекта, следующим образом:
ЗначениеВРеквизитФормы(ТекущийОбъект, "Объект")
Только авторизованные участники могут оставлять комментарии.
Содержание
1. Задача передачи параметров 1С
2. Реализация с модулем объекта документа 1С
Иногда возникает необходимость передачи параметров 1С, установленных в определенной управляемой форме документа 1С, в модуль объекта 1С 8.3. При этом крайне нежелательно создавать отдельные реквизиты для этого документа. Поэтому в данной ситуации можно пользоваться глобальными переменными 1С. В дальнейшем они могут быть использованы в процедурах и функциях этого модуля. Если переменная определена с ключевым словом «экспорт», то она будет доступна вне данного модуля.
1. Задача передачи параметров 1С
Предположим, есть некий документ, на основной форме документа которого располагается гиперссылка в 1С, вызывающая другую форму с вводом определенных настроек. Необходимо чтобы после выбора настроек они были переданы в модуль объекта 1С 8.3 документа для последующей обработки в процедуре проведения.
2. Реализация с модулем объекта документа 1С
В самом начале модуля объекта документа 1С необходимо определить переменную, в которую будут передаваться выбранные настройки. Также необходимо ей присвоить признак «экспорт», чтобы переменная была доступна в любом месте документа.
В модуле основной формы документа в обработчике события 1С кнопки, открывающей форму с выбором настроек, необходимо указать процедуру Новый ОписаниеОповещения(). Это определяет результат после закрытия формы настроек в 1С 8.3.
В форме настроек для сохранении и передачи параметров 1С (в нашем случаи это структура) необходимо указывать процедуру ОповеститьОВыборе()
Далее нужно создать саму процедуру оповещения, в которой будем обрабатывать в результате закрытия формы настроек. В качестве приемника создаем реквизит основной формы ПараметрыПереоценки (можно создать глобальную переменную в модуле основной формы) и в нее передаем результат закрытия.
И в заключительном этапе (например, в процедуре ПередЗаписьНаСервере() передадим из реквизита формы сохраненную структуру настроек в глобальную переменную, которую определяли в модуле объекта документа.
В итоге настройки, выбранные на дочерней форме открытой из основной формы документа, теперь доступны в модуле объекта и могут быть обработаны в любой его процедуре, например, в процедуре проведения.
Разработчик 1С компании ООО “Кодерлайн”
Игорь Цебоев.
gvk2009 подробно и доходчиво описал разницу методов, за что ему огромное спасибо:
В Синтаксис-Помощнике очень скупо написано о процедуре ДанныеФормыВЗначение(), чуть побольше — о РеквизитФормыВЗначение(). И совсем нет примеров использования. Попробуем с этим разобраться.
РеквизитФормыВЗначение()
Является методом управляемой формы, компилируется только &НаСервере, контекст формы является для него необходимым, поэтому компиляция &НаСервереБезКонтекста недоступна. На клиенте не работает, поскольку в результате получаем прикладной объект.
Где и когда его нужно использовать?
Метод РеквизитФормыВЗначение() необходим, если требуется из модуля формы вызвать стандартный метод объекта или метод (процедуру, функцию) из модуля объекта, из общего модуля.
Этот метод будет отрабатывать с данными, взятыми из формы, т.е. еще не записанными в базу.
Для того, чтобы измененные данные вернуть на форму, используется метод ЗначениеВРеквизитФормы().
Вторым параметром метода РеквизитФормыВЗначение является тип значения. Это необязательный параметр. Если обрабатываемый реквизит не является составным типом, то тип будет автоматически получен из реквизита формы. Иначе генерируется исключение времени выполнения.
Примеры:
Код 1C v 8.2 УП
// 1)
&НаСервере
Процедура ЗаполнитьТЧПоДаннымПоследнегоДокумента(Контрагент)
ДокОбъект = РеквизитФормыВЗначение("Объект");
ДокОбъект.ЗаполнитьТЧПоДаннымПоследнегоДокумента(Контрагент);
ЗначениеВРеквизитФормы(ДокОбъект, "Объект");
КонецПроцедуры
// 2)
&НаСервере
Процедура ОчиститьСтрокиСПустойЦенойНаСервере()
ДокОбъект = РеквизитФормыВЗначение("Объект");
ДокОбъект.ОчиститьСтрокиСПустойЦеной();
ЗначениеВРеквизитФормы(ДокОбъект, "Объект");
КонецПроцедуры
//3)
&НаСервере
Функция ОбъектЗаполнен()
Возврат РеквизитФормыВЗначение("Объект").ПроверитьЗаполнение();
КонецФункции
В указанных выше случаях метод РеквизитФормыВЗначение() похож на метод ПолучитьОбъект(). Разница в том, что первый получает объект, заполненный данными формы, а второй — объект с данными из базы.
ДанныеФормыВзначение()
В отличие от метода управляемой формы РеквизитФормыВЗначение(), процедура глобального контекста ДанныеФормыВЗначение() может работать без контекста формы, но именно поэтому, в частности, ей необходимо указывать тип конвертируемых данных.
Обратной процедурой является ЗначениеВДанныеФормы().
Примеры:
Код 1C v 8.2 УП
// 1)
&НаСервере
// Инициализация набора констант
НаборКонстантОбъект = ДанныеФормыВЗначение(НаборКонстант, Тип("КонстантыНабор"));
НаборКонстантОбъект.Прочитать();
ЗначениеВДанныеФормы(НаборКонстантОбъект, НаборКонстант);
// 2)
&НаСервере
НаборФорма = Объект.Движения.РегистрУправленческий;
Набор = ДанныеФормыВЗначение(НаборФорма, Тип("РегистрБухгалтерииНаборЗаписей.РегистрУправленческий"));
Если Набор.Количество()=0 Тогда
Возврат;
КонецЕсли;
Набор.УстановитьАктивность(НЕ Набор[0].Активность);
ЗначениеВДанныеФормы(Набор, НаборФорма);
В этом примере на форме отображен набор записей регистра бухгалтерии. При отработке процедуры, активность набора меняется только на форме, в базе при этом ничего не происходит. Активность у набора записей регистра в базе поменяется только после выполнения операции Записать.
Код 1C v 8.2 УП
// 3)
&НаКлиенте
Процедура Заполнить(Команда)
ОснРеквизит = Объект;
ВыполнитьНаСервереБезКонтекста(ОснРеквизит);
КопироватьДанныеФормы(ОснРеквизит,Объект)
КонецПроцедуры
&НаСервереБезКонтекста
Процедура ВыполнитьНаСервереБезКонтекста(ОснРеквизит)
ОбъектЗначение = ДанныеФормыВЗначение(ОснРеквизит, Тип("ДокументОбъект.АктСверкиВзаиморасчетов"));
//...Выполнение операций с Объектом "ОбъектЗначение"
ЗначениеВДанныеФормы(ОбъектЗначение, ОснРеквизит);
КонецПроцедуры
В этом примере на клиент возвращается ОснРеквизит, содержащий измененные данные. Но его еще нужно «запихать» в отображаемую форму. Для этого используем процедуру глобального контекста КопироватьДанныеФормы().
В большинстве случаев процедуры ДанныеФормыВзначение() и РеквизитФормыВЗначение() взаимозаменяемы. При этом РеквизитФормыВЗначение проще в использовании. Но если требуется использование &НаСервереБезКонтекста — тогда только ДанныеФормыВЗначение.
В качестве иллюстрации взаимозаменяемости Пример 2 еще в двух вариантах:
Код 1C v 8.2 УП
// ВАРИАНТ 1
&НаКлиенте
Процедура Активность(Команда)
ОснРеквизитДвижения = Объект.Движения.РегистрУправленческий;
АктивностьНаСервереБезКонтекста(ОснРеквизитДвижения);
КопироватьДанныеФормы(ОснРеквизитДвижения,Объект.Движения.РегистрУправленческий);
КонецПроцедуры // Активность()
&НаСервереБезКонтекста
Процедура АктивностьНаСервереБезКонтекста(ОснРеквизитДвижения)
Набор = ДанныеФормыВЗначение(ОснРеквизитДвижения, Тип("РегистрБухгалтерииНаборЗаписей.РегистрУправленческий"));
Если Набор.Количество()=0 Тогда
Возврат;
КонецЕсли;
Набор.УстановитьАктивность(НЕ Набор[0].Активность);
ЗначениеВДанныеФормы(Набор, ОснРеквизитДвижения);
КонецПроцедуры // АктивностьНаСервереБезКонтекста()
// ВАРИАНТ 2
&НаСервере
Процедура АктивностьНаСервере()
НаборФорма = РеквизитФормыВЗначение("Объект");
Набор = НаборФорма.Движения.РегистрУправленческий;
Если Набор.Количество()=0 Тогда
Возврат;
КонецЕсли;
Набор.УстановитьАктивность(НЕ Набор[0].Активность);
ЗначениеВРеквизитФормы(НаборФорма, "Объект");
КонецПроцедуры // АктивностьНаСервере()
1С, получить из модуля объекта элемент формы
В разработке иногда возникает следующая ситуация:
- Из модуля объекта требуется получить реквизит формы элемента;
- При этом реквизит формы элемента (который необходимо получить) не сохраняется в реквизиты объекта;
План действий для решения задачи
- Создать реквизит объекта «АдресВХ», тип строка неограниченной длины;
- В свойствах формы элемента добавим обработчик «Перед записью»:
- В обработчик добавим следующий программный код:
&НаКлиенте Процедура ПередЗаписью(Отказ, ПараметрыЗаписи) Объект.АдресВХ = ПоместитьВоВременноеХранилище(ТабДок); КонецПроцедуры
В нашем случае во временной хранилище мы помещаем «ТабДок», данный реквизит будем получать в модуле объекта;
- Переходим в модуль объекта и создаем процедуру «Перед записью», добавляем код:
Процедура ПередЗаписью(Отказ) ТабДок = ПолучитьИзВременногоХранилища(АдресВХ); КонецПроцедуры
В результате мы передали элемент из формы в модуль объекта, хоть и добавили в дерево метаданных вспомогательный реквизит «АдресВХ»;
Связанные статьи
В данной статье описаны примеры программного создания объектов управляемой формы 1С : элементов, команд, реквизитов, а также описание стандартных возможностей для работы с ними.
Contents
- 1 Введение в управляемая форма 1С реквизиты элементы команды
- 2 Программное переопределение обработчиков событий формы и элементов формы
- 3 Программное создание групп формы.
- 4 Программное добавление команды на форму.
- 5 Программное создание декораций форм.
- 6 Программное добавление реквизита на форму.
- 7 Вывод реквизитов на форму.
- 8 Вызов процедур при создании на сервере 1С
- 9 Некоторые советы при программном редактировании формы
- 10 Полезные ссылки
Рекомендуется модифицировать управляемые формы типового решения 1С программно для удобного будущего обновления и исключения конфликтов, а также для удобной работы с изменениями и надежности при использовании механизма расширений.
В некоторых типовых конфигурациях 1С (ЕРП 2, УТ 11) используется механизм упрощенного изменения конфигурации. Статьи о типовом механизме можно найти в разделе полезных ссылок. Данный механизм используется в БСП, и его необходимо знать при модификации типовых конфигураций.
При добавлении элементов на форму программно можно отредактировать практически любое свойство из панель свойств, которое можно установить вручную в конфигураторе.
Также все описанные в текущем разделе процедуры и функции находятся во внешней обработке УпрФормы.
Примеры работы с объектом «ДанныеФормыКоллекция» и созданием дин. списка и таблицы значений программно можно будет посмотреть в части 2.
Для запуска обработки в режиме предприятия необходимо наличие объектов «Справочники.Номенклатура», подчиненный ему «Справочники.ХарактеристикиНоменклатуры» и «РегистрыСведений.ЦеныНоменклатуры”.
Программное переопределение обработчиков событий формы и элементов формы
Переопределить обработчики событий формы можно в обработчике «ПриСозданииНаСервере» (кроме самого обрабочика «ПриСозданииНаСервере») или в теле модуля формы в контексте сервера (например, Переопределение событий ПриЧтениинаСервере и ПриСозданииНаСервере).
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
ЭтаФорма.УстановитьДействие(“ОбработкаВыбора”, “пр_ОбработкаВыбора”)
КонецПроцедуры
В теле модуля формы:
#Если Сервер Тогда
ЭтаФорма.УстановитьДействие("ПриСозданииНаСервере", "пр_ПриСозданииНаСервере");
#КонецЕсли
А в новой процедуре нужно добавить вызов основной, если такая процедура есть.
&НаСервере
Процедура пр_ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
ПриСозданииНаСервере(Отказ, СтандартнаяОбработка);
КонецПроцедуры
Аналогично можно поступить и с обработчиками элементов формы:
Элементы.Номенклатура.УстановитьДействие(“ПриИзменении”, “пр_НоменклатураПриИзменении”)
Программное создание групп формы.
&НаСервере
Процедура пр_СоздатьГруппы()
ГруппаСтраницы = Элементы.Добавить("пр_Страницы", Тип("ГруппаФормы"),ЭтаФорма);
ГруппаСтраницы.Вид = ВидГруппыФормы.Страницы;
НоваяСтраница = Элементы.Добавить("пр_Страница", Тип("ГруппаФормы"),ГруппаСтраницы);
НоваяСтраница.Вид = ВидГруппыФормы.Страница;
НоваяСтраница.Заголовок = "Страница 1";
НоваяГруппа = Элементы.Добавить("пр_Группа1", Тип("ГруппаФормы"),НоваяСтраница);
НоваяГруппа.Вид = ВидГруппыФормы.ОбычнаяГруппа;
НоваяГруппа.Группировка = ГруппировкаПодчиненныхЭлементовФормы.ГоризонтальнаяЕслиВозможно;
НоваяГруппа.Заголовок = "Группа 1";
КонецПроцедуры
Доступные виды групп формы:
Программное добавление команды на форму.
Удалить команду можно при помощи метода коллекции формы команд: Команды.Удалить(<Команда>). Удалять можно только те команды, которые были созданы программно.
&НаСервере
Процедура пр_СоздатьНовуюКоманду()
//создать новую команду у формы
НоваяКоманда = Команды.Добавить("пр_Команда1");
НоваяКоманда.Действие = "пр_Команда1";
НоваяКоманда.Картинка = БиблиотекаКартинок.Облако;
НоваяКоманда.Отображение = ОтображениеКнопки.Картинка;
//вывести команду в элементы
ЭлементКоманда = Элементы.Добавить("пр_Команда1", Тип("КнопкаФормы"), Элементы.ФормаКоманднаяПанель);
ЭлементКоманда.Заголовок = "Вывести сообщение";
ЭлементКоманда.ИмяКоманды = "пр_Команда1";
//удалить команду
//Команды.Удалить(НоваяКоманда);
КонецПроцедуры
&НаКлиенте
Процедура пр_Команда1(Команда)
Сообщить("Команда выполнена.");
КонецПроцедуры
Программное создание декораций форм.
&НаСервере
Процедура пр_СоздатьДекорацию()
//добавить надпись
Элемент = Элементы.Добавить("Надпись1", Тип("ДекорацияФормы"), Элементы["пр_Группа1"]);
Элемент.Вид = ВидДекорацииФормы.Надпись;
Элемент.Заголовок = "Добавленная надпись";
//для того, чтобы добавить картинку, необходимо выбрать ВидДекорацииФормы.Картинка
Элемент = Элементы.Добавить("Картинка1", Тип("ДекорацияФормы"), Элементы["пр_Группа1"]);
Элемент.Вид = ВидДекорацииФормы.Картинка;
Элемент.Картинка = БиблиотекаКартинок.Бесконечность;
КонецПроцедуры
Программное добавление реквизита на форму.
Добавлять новые реквизиты в управляемую форму и удалять необходимо с помощью метода ИзменитьРеквизиты(), куда в параметры передается массив добавляемых реквизитов и массив удаляемых. Удалять при этом можно только те реквизиты, которые были созданы программно.
&НаСервере
Процедура пр_СоздатьРеквизиты()
// Массив для новых реквизитов
ДобавляемыеРеквизиты = Новый Массив;
// Опишем ревизиты формы
Реквизит_Использование = Новый РеквизитФормы("пр_Использование", Новый ОписаниеТипов("Булево"), "", "Использование");
Реквизит_Номенклатура = Новый РеквизитФормы("пр_Номенклатура", Новый ОписаниеТипов("СправочникСсылка.Номенклатура"), "", "Номенклатура");
Реквизит_Характеристика = Новый РеквизитФормы("пр_Характеристика", Новый ОписаниеТипов("СправочникСсылка.ХарактеристикиНоменклатуры"), "", "Характеристика");
Реквизит_Количество = Новый РеквизитФормы("пр_Количество", Новый ОписаниеТипов("Число", , , Новый КвалификаторыЧисла(10, 3)), "", "Количество");
Реквизит_УдалитьКоличество = Новый РеквизитФормы("пр_УдалитьКоличество", Новый ОписаниеТипов("Число", , , Новый КвалификаторыЧисла(10, 3)), "", "Удалить_Количество");
//если используется БСП, то можно для определения описания типов использовать функцию
//ОбщегоНазначения.ОписаниеТипаСтрока(ДлинаСтроки)
//ОбщегоНазначения.ОписаниеТипаЧисло(Разрядность, РазрядностьДробнойЧасти = 0, ЗнакЧисла = Неопределено)
//ОбщегоНазначения.ОписаниеТипаДата(ЧастиДаты)
Реквизит_Информация = Новый РеквизитФормы("пр_Информация", ОбщегоНазначения.ОписаниеТипаСтрока(100), "", "Информация");
// Для наглядности заполним массив после описания реквизитов формы
ДобавляемыеРеквизиты.Добавить(Реквизит_Использование);
ДобавляемыеРеквизиты.Добавить(Реквизит_Номенклатура);
ДобавляемыеРеквизиты.Добавить(Реквизит_Характеристика);
ДобавляемыеРеквизиты.Добавить(Реквизит_Количество);
ДобавляемыеРеквизиты.Добавить(Реквизит_УдалитьКоличество);
ДобавляемыеРеквизиты.Добавить(Реквизит_Информация);
// Добавим новые реквизиты в форму
ИзменитьРеквизиты(ДобавляемыеРеквизиты);
КонецПроцедуры
&НаСервере
Процедура пр_УдалитьРеквизиты()
// Массив для удаляемых реквизитов
УдаляемыеРеквизиты = Новый Массив;
//указываем путь к удаляемому реквизиту
УдаляемыеРеквизиты.Добавить("пр_УдалитьКоличество");
//К добавленным реквизитам нужно обращаться через переменную ЭтаФорма
// Добавим новые реквизиты в форму
ИзменитьРеквизиты(,УдаляемыеРеквизиты);
КонецПроцедуры
Вывод реквизитов на форму.
&НаСервере
Процедура пр_ВывестиРеквизитыНаФорму()
НовыйЭлемент = Элементы.Добавить("пр_Использование", Тип("ПолеФормы"), Элементы.пр_Страница1);
НовыйЭлемент.ПутьКДанным = "пр_Использование";
НовыйЭлемент.Вид = ВидПоляФормы.ПолеФлажка;
НовыйЭлемент.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Право;
//установим обработчик события элементы
НовыйЭлемент.УстановитьДействие("ПриИзменении", "пр_ИспользованиеПриИзменении");
НовыйЭлемент = Элементы.Добавить("пр_Номенклатура", Тип("ПолеФормы"), Элементы.пр_Страница1);
НовыйЭлемент.ПутьКДанным = "пр_Номенклатура";
НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;
//установить параметр выбора элемента
НовыйМассив = Новый Массив();
НовыйПараметр = Новый ПараметрВыбора("Отбор.ПометкаУдаления", Ложь);
НовыйМассив.Добавить(НовыйПараметр);
НовыеПараметры = Новый ФиксированныйМассив(НовыйМассив);
НовыйЭлемент.ПараметрыВыбора = НовыеПараметры;
НовыйЭлемент.УстановитьДействие("ПриИзменении", "пр_НоменклатураПриИзменении");
НовыйЭлемент = Элементы.Добавить("пр_Характеристика", Тип("ПолеФормы"), Элементы.пр_Страница1);
НовыйЭлемент.ПутьКДанным = "пр_Характеристика";
НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;
НовыйЭлемент.Заголовок = "Характеристика номенклатуры";
//добавить связь параметров выбора по реквизиту владелец в зависимости от выбранной номенклатуры
НоваяСвязь = Новый СвязьПараметраВыбора("Отбор.Владелец", "пр_Номенклатура");
НовыйМассив = Новый Массив();
НовыйМассив.Добавить(НоваяСвязь);
НовыйЭлемент.СвязиПараметровВыбора = Новый ФиксированныйМассив(НовыйМассив);
НовыйЭлемент.УстановитьДействие("ПриИзменении", "пр_ХарактеристикаПриИзменении");
НовыйЭлемент = Элементы.Добавить("пр_Количество", Тип("ПолеФормы"), Элементы.пр_Страница1);
НовыйЭлемент.ПутьКДанным = "пр_Количество";
НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;
//установить формат
НовыйЭлемент.ФорматРедактирования = "ЧДЦ=0; ЧРГ=.; ЧН=Отсутствует";
НовыйЭлемент = Элементы.Добавить("пр_Информация", Тип("ПолеФормы"), Элементы.пр_Страница1);
НовыйЭлемент.ПутьКДанным = "пр_Информация";
НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;
//установить список выбора
НовыйЭлемент.РежимВыбораИзСписка = Истина;
Массив = Новый Массив;
Массив.Добавить("Необходимо дозаказать");
Массив.Добавить("Достаточно");
Массив.Добавить("Оформить полный заказ");
НовыйЭлемент.СписокВыбора.ЗагрузитьЗначения(Массив);
КонецПроцедуры
&НаКлиенте
Процедура пр_ИспользованиеПриИзменении(Элемент)
КонецПроцедуры
Вызов процедур при создании на сервере 1С
После описания всех процедур выводим их в процедуре ПриСозданииНаСервере. Также можно изменить программно некоторые свойства формы, например, заголовок. Чтобы был виден только наш заголовок, нужно отключить свойство Автозаголовок.
&НаСервере &НаСервере Процедура пр_ПриСозданииНаСервере(Отказ, СтандартнаяОбработка) //установим заголовок формы ЭтаФорма.Заголовок = "Шаблон для программной работы с реквизитами, командами и элементами формы"; ЭтаФорма.АвтоЗаголовок = Ложь; пр_СоздатьГруппы(); пр_СоздатьНовуюКоманду(); пр_СоздатьДекорацию(); пр_СоздатьРеквизиты(); пр_УдалитьРеквизиты(); пр_ВывестиРеквизитыНаФорму(); КонецПроцедуры
Некоторые советы при программном редактировании формы
- Если вы не используете префиксы при создании новых команд и элементов рекомендуется проверять существование создаваемых объектов по имени с помощью метода Найти(), который вернет Неопределено, если объект в коллекции не найден:
- Элементы.Найти(«пр_Владелец»);
- Команды.Найти(«пр_НоваяКоманда»);
- Чтобы проверить уникальность реквизита на форме можно воспользоваться следующей функцией:
&НаКлиентеНаСервереБезКонтекста
// Функция определяет существует ли реквизит у объекта.
//
Функция ЕстьРеквизитОбъекта(мОбъект, ИмяРеквизита)
КлючУникальности = Новый УникальныйИдентификатор;
СтруктураРеквизита = Новый Структура(ИмяРеквизита, КлючУникальности);
ЗаполнитьЗначенияСвойств(СтруктураРеквизита, мОбъект);
Возврат СтруктураРеквизита[ИмяРеквизита] <> КлючУникальности;
КонецФункции // ЕстьРеквизитОбъекта()
- Свойства, методы и коллекции управляемой формы описаны в синтакс-помощнике в разделе «Интерфейс (управляемый)»;
- Изучите БСП, если она имеется в вашей конфигурации. Например в общем модуле «ОбщегоНазначения» уже описаны функции для создания объекта ОписаниеТипов, необходимого при создании новых реквизитов на форме:
- ОбщегоНазначения.ОписаниеТипаСтрока(ДлинаСтроки) — Создает объект ОписаниеТипов, содержащий тип Строка;
- ОбщегоНазначения.ОписаниеТипаЧисло(Разрядность, РазрядностьДробнойЧасти = 0, ЗнакЧисла = Неопределено) — Создает объект ОписаниеТипов, содержащий тип Число;
- ОбщегоНазначения.ОписаниеТипаДата(ЧастиДаты) — Создает объект ОписаниеТипов, содержащий тип Дата;
- ОбщегоНазначенияВызовСервера.ЦветСтиля(ИмяЦветаСтиля) — Функция получает цвет стиля по имени элемента стиля;
- ОбщегоНазначенияВызовСервера.ШрифтСтиля(ИмяШрифтаСтиля) — Функция получает шрифт стиля по имени элемента стиля.
Итак, взглянем на получившийся результат. Все элементы на форме созданы программно:
Полезные ссылки
1. Типовой механизм упрощенного изменения конфигурации в ERP 2.0 и УТ 11
2. Типовой функционал модификации конфигурации линейки ERP-решений (УТ 11, КА 2 и ERP 2)
3. 1С Управляемые Формы. Программное создание таблицы значений и динамического списка (Часть 2)
Перейти к содержанию
Как из управляемой формы вызвать процедуру модуля объекта
На чтение 2 мин Просмотров 14к. Опубликовано 20.04.2017
Довольно часть встречается ситуация, когда из формы какого-то прикладного объекта необходимо вызвать экспортную процедуру или функцию, расположенную в модуле этого объекта.
Напрямую обратиться к процедурам модуля объекта из формы не получится. Связано это с тем, что прикладных объектов на клиенте нет, они существуют только на сервере. На клиенте доступны только специальные типы для отображения данных.
Общая схема вызова серверной процедуры/функции состоит из нескольких этапов:
- Вызов контекстной серверной процедуры формы;
- Преобразование основного реквизита формы в прикладной объект;
- Вызов экспортной процедуры/функции модуля объекта;
- Обратное преобразование прикладного объекта в реквизит формы.
Рассмотрим описанные действия на примере. Предположим, что у документа есть табличная часть с товарами и ценами. Необходимо из формы документа вызвать процедуру модуля объекта, которая применяет для всех строк табличной части скидку в процентах.
Процедура модуля объекта документа для применения скидки:
Процедура ПрименитьСкидку(ПроцентСкидки) Экспорт
Для каждого СтрокаТЧ Из Товары Цикл
СтрокаТЧ.Цена = СтрокаТЧ.Цена - СтрокаТЧ.Цена / 100 * ПроцентСкидки;
КонецЦикла;
КонецПроцедуры
Внимание!
Процедуры/функции модуля объекта, которые предназначены для вызова извне модуля должны быть экспортными, т.е. иметь ключевое слово Экспорт.
На форме документа расположим кнопку, вызывающую серверную процедуру:
&НаКлиенте
Процедура ПересчитатьЦены(Команда)
// Этап 1. Вызов серверной процедуры
ПересчитатьЦеныНаСервре();
КонецПроцедуры
&НаСервере
Процедура ПересчитатьЦеныНаСервре()
// Этап 2. Преобразование основного реквизита формы в прикладной объект
ДокументОбъект = РеквизитФормыВЗначение("Объект");
// Этап 3. Вызов процедуры модуля объекта
ДокументОбъект.ПрименитьСкидку(5);
// Этап 4. Обратное преобразование прикладного объекта в реквизит формы
ЗначениеВРеквизитФормы(ДокументОбъект, "Объект");
КонецПроцедуры