Реквизит формы в значение 1с дерево значений

Содержание:

1.     Что такое Дерево значений в 1С

2.     Как создать дерево значений в 1C 8.3 

1.   Что такое Дерево значений в 1С

Дерево значений в 1С (тип значения «ДеревоЗначений») – это Универсальная коллекция значений в системе 1С, где Элементы упорядочены по Индексу (нумерация начинается с 0). Каждое значение Элемента содержит в себе Коллекцию подчиненных Строк, где у каждой Строки коллекции указывается Родитель – Элемент, находящийся на уровень выше. У корневого Элемента (элемент первого уровня) Родитель отсутствует. Доступ к Элементам осуществляется через Индекс, по номеру которого можно получить доступ к значению Элемента и коллекции подчиненных ему Строк.

Описание из Синтакс-помощника: используется для доступа к свойствам и методам дерева значений 1С в целом. Объект, представляющий собой древовидную структуру, обладает сходной функциональностью с таблицей значений, а также обладает возможностью добавлять подчиненные строки к какой-либо строке дерева.

Внимание! В толстом клиенте (обычное приложение) передача значений данного типа с клиента на сервер и обратно приводит к возникновению исключения.

Доступность: сервер, толстый клиент, внешнее соединение, мобильное приложение (сервер), мобильный автономный сервер.

Сериализуется: данный объект может быть сериализован в/из XDTO. Тип XDTO, соответствующий данному объекту, определяется в пространстве имен {http://v8.1c.ru/8.1/data/core}. Имя типа XDTO: ValueTree.  

2.     Как создать дерево значений в 1C 8.3

Так как Дерево значений в 1С 8.3 является усложненной конструкцией с точки зрения программной реализации, и достаточно ресурсоемкой, её не часто используют в разработках. Однако, она очень удобна для реализации нестандартных задач, в том числе, когда требуется отобразить множество значений с возможностью группировки по Родителю.

Необходимо однозначно разделять Дерево значений как объявленную переменную (через конструктор «Новый ДеревоЗначений») и как Реквизит Формы 1С 8.3 (обратите внимание, что ДЗ нельзя выбрать как тип данных Реквизита Объекта).

Если объявленное (далее – ОП) ДЗ можно читать НаКлиенте, передавать НаСервере для обработки и возвращать обратно, то ДЗ как Реквизит Формы 1С 8.3 (далее – РФ) будет читабельным только НаКлиенте. НаСервере даже при попытке чтения дерево выдаст Исключение, а изменять данные, конечно же, не позволит вообще.

Далее рассмотрим поведение одинаковых действий при условии объявления переменной (в рамках одной процедуры/функции) и условиях добавленного реквизита формы 1С 8.3. Варианты работы с глобальными переменными, экспортными или не экспортными переменными модуля мы рассматривать не будем, так как применение зависит от контекста задачи и Вашей веры в объявление глобальных и внеконтекстных переменных.

У ДЗ как РФ есть свое преимущество: вы можете задать колонки и тип данных в самом РФ и программно обращаться к данным из любой процедуры или функции модуля формы (не забывая о директивах компиляции). Для ДЗ как ОП требуется описать все необходимые колонки (для начинающих это может быть проблематично, если нет четкого представления того, что это за «зверь» такой), а также понимать, что по окончании процедуры/функции кончается и жизненный цикл переменной (конечно, если мы не объявили ее глобальной, но это уже совсем другая история).

Пример описания ДЗ программе 1С Предприятие 8:

Как видно из примера, в ДЗ задаются колонки, где будут размещаться данные, но чтобы добавить это данные, необходимо обратиться к Коллекции Строк: ДеревоДанных.Строки.Добавить(). Таким образом добавляются строки первого уровня, после чего в строку первого уровня добавляем коллекцию строк и так далее. При этом, используя метод Добавить(), Родитель присваивается автоматически, но, конечно, его можно изменить. Так и строится дерево, однако не стоит забывать, что чем больше данных, тем больше потребление ресурсов.

Пример ДЗ как РФ:

Добавление данных происходит, в сущности, таким же образом, как при описании, но есть программные различия. Опишем основные:

*Пример преобразования:

** Пример работы «преобразование-запись-преобразование»:

Развернутое дерево значений по своей сути напоминает Результат запроса с группировками, где чем больше группировок, тем больше совокупное количество строк.

Поэтому если требуется результат запроса (где данные сгруппированы) загрузить в ДЗ, необходимо:

1.     (необязательно) преобразовать из реквизита формы;

2.     загрузить результат;

3.     преобразовать в реквизит формы.

При необходимости загрузки данных в ДЗ из табличной части 1С можно воспользоваться несколькими способами:

1. Запись с помощью циклов: тут нужно помнить, что есть строки «корневые», и надо их каким-то образом найти, чтобы правильно построить связь Корень-Подчиненный.

2. Загрузить с помощью Запроса (и здесь есть два варианта):

a.      выгрузить табличную часть 1С во временную переменную, передать ее как параметр, сформировать результат с использованием иерархии и загрузить результат в дерево;

b.     сформировать запрос, в который передаем как параметр ссылку принятого к обработке документа в 1С 8.3, после чего формируем результат с использованием иерархии и загружаем его в дерево.

*Варианты 2а и 2b кажутся похожими. Однако разница между ними есть. Она заключается в производительности, которая зависит от контекста использования (количество данных, количество пользователей, нагрузка на сервер и другое). С одной стороны, при использовании директивы НаСервере у нас уже есть табличная часть 1С (конечно, на стороне сервера, но она уже загружена), которую мы можем без потерь и других действий передать в Запрос и выполнить его. С другой стороны, обращаясь по ссылке в результате выполнения Запроса, система повторно обратится к БД, но, возможно, сделает это быстрее, чем в первом случае. Этот момент требует исследования уже на конкретной БД.

Для записи данных в табличную часть 1С или Таблицу значений потребуется построить цикл, который будет выполнять запись в Приемник по следующим правилам:

1. обход дерева выполняется от Корня к Подчиненным до последнего уровня вложенности;

2. если у Корня есть Подчиненные элементы, то количество результирующих строк в Таблице высчитывается по формуле: , где n – количество элементов на заданном уровне, m — количество уровней (глубина вложенности дерева);

3. рекомендуется записывать Корень – Подчиненный элемент, в связи с этим требуется запись рекурсивным методом.

Пример рекурсивной записи из ДЗ в Табличную часть Товары:

Для чтения данных все немного проще: читать можно как НаКлиенте, так и НаСервере. Разница только в том, что для директивы НаКлиенте потребуется сначала вызвать метод ПолучитьЭлемент(), чего не требуется для серверной директивы. Внимание! Не забудьте, что чтение в процедуре/функции с директивой НаКлиентеНаСервереБезКонтекста компилируется одновременно на клиенте и на сервере, а это значит, что описав Чтение как для клиента при вызове исполнения из процедуры/функции с директивой сервера, программа выдаст исключение (и наоборот). При необходимости вызова чтения как НаКлиенте, так и НаСервере рекомендуется создавать обработчики с соответствующими директивами.

Кроме всего прочего, ДЗ можно использовать в особо изощренном способе работы. Допустим, поставили задачу, что необходимо иметь на форме две таблицы, таблица слева – дерево, в котором есть все уровни, кроме последнего; справа – таблица, в которой отображаются данные последнего уровня вложенности. Таким образом активация строки в Дереве приведет к отображению всех подчиненных элементов.

Реализованный пример такой задачи:

*Естественно, текущие данные тестовые. Задачей предполагалось, что корневых уровней может быть до 15, второй уровень – примерно так же, а вот на последнем уровне может быть до 50 строк. В такой компоновке удобно видеть все элементы нижнего уровня, переключаясь между Родителями.

Использование Дерева значений — это достаточно нетривиальный и филигранный способ, который имеет свои плюсы (особенно когда группы товаров можно сворачивать). Использовать его для больших таблиц (где более 100 строк) можно, но важно исследовать производительность в каждом конкретном случае.

Специалист компании ООО «Кодерлайн»

Каплин Иван Александрович

Как заполнить Реквизит УФ Дерево значений.

Я

   simol

01.09.12 — 19:33

   Wobland

1 — 01.09.12 — 19:34

а есть такой реквизит у формы?

   simol

2 — 01.09.12 — 19:36

   Wobland

3 — 01.09.12 — 19:39

   simol

4 — 01.09.12 — 19:42

(3)Какая-то особенность дерева я думаю

   Wobland

5 — 01.09.12 — 19:49

   simol

6 — 01.09.12 — 19:50

(5)Я на сервере

   simol

7 — 01.09.12 — 19:53

(0)Непосредственное заполнение через ПолучитьЭлементы() вместо «.Строки» получилось, то хотел бы сначала Дерево подготовить, а потом его загрузить в реквизит формы.

   Wobland

8 — 01.09.12 — 19:54

(4) со строкой то же самое

ЗначениеВРеквизитФормы(стр, «Реквизит1»)

   Wobland

9 — 01.09.12 — 19:57

   simol

10 — 01.09.12 — 19:57

(9)Щас поищу УТ11 и гляну

   simol

11 — 01.09.12 — 20:03

   Wobland

12 — 01.09.12 — 20:03

   Wobland

13 — 01.09.12 — 20:03

(11) я нашёл. у тебя Новый Дерево

   simol

14 — 01.09.12 — 20:04

(13)Да, тоже это понял, спасибо

   Wobland

15 — 01.09.12 — 20:04

(13) хотя, вон в (9) тоже на месте создавалось…

   Wobland

16 — 01.09.12 — 20:04

(14) что спасибо? понял что-то? я ни черта

   simol

17 — 01.09.12 — 20:06

   Wobland

18 — 01.09.12 — 20:06

(17) если поймёшь, расскажешь, как работает (9)?

   simol

19 — 01.09.12 — 20:27

(18) попробовал (17) Так работает, секрет (9) неясен, может там предварительно сохраняли пустое дерево для ускорения работы.

   Wobland

20 — 01.09.12 — 20:29

   simol

21 — 01.09.12 — 20:30

(20)в УФ много странного,вроде уже нравится и на те, очередная непонятка….

(0) Чтобы подобное сработало, нужно чтобы структура (колонок и типов) у дерева на форме и загружаемого дерева совпадала 1 в 1

Так как работа с ДеревомЗначений и ТаблицейЗначений в данном контексте практически не отличается, в примере будет использоваться ДеревоЗначений, все тоже самое за исключением иерархии применимо и к ТаблицеЗначений. Как известно, в платформе 1С 8.1 не составляло никакого труда связать дерево значений с табличным полем на форме, единственное что при этом нужно было не забыть так это СоздатьКолонки(). В управляемом приложении 1С 8.2 сделать это не так просто как кажется на первый взгляд.
Обращаю внимание, что ДеревоЗначений доступно только на сервере, в толстом клиенте и внешнем соединение. В данных самой управляемой формы для моделирования дерева используется тип ДанныеФормыДерево. Для преобразования ДеревоЗначений <-> ДанныеФормыДерево используются методы управляемой формы ЗначениеВРеквизитФормы() и РеквизитФормыВЗначение(). Для непосредственного отображения дерева используется элемент формы типа ТаблицаФормы связанный через реквизит ПутьКДанным с реквизитом формы типа ДанныеФормыДерево. Если Вам не очень понятна вышеописанная связь объектов, не огорчайтесь, ниже рассмотрим практический пример и все встанет на свои места.

Задача: Имеется дерево значений, необходимо отобразить его на управляемой форме.
Создаем новую внешнюю обработку ( Скачивать файлы может только зарегистрированный пользователь! ), добавляем управляемую форму и создаем обработчик ПриСозданииНаСервере(). Никаких реквизитов и элементов “вручную” не добавляем, будем делать это программно.

Код 1C v 8.2 УП

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)


    // Создание и заполнение "обычного" объекта прикладного типа ДеревоЗначений,

    // который будет отображен на управляемой форме

    ДеревоОбъект = Новый ДеревоЗначений;

    ДеревоОбъект.Колонки.Добавить("Узел", Новый ОписаниеТипов("Строка"));

    Для к1 = 1 По 3 Цикл

        СтрокаУ1 = ДеревоОбъект.Строки.Добавить();

        СтрокаУ1.Узел = "Узел"+к1;

        Для к2 = 1 По 3 Цикл

            СтрокаУ2 = СтрокаУ1.Строки.Добавить();

            СтрокаУ2.Узел = СтрокаУ1.Узел+к2;

            Для к3 = 1 По 3 Цикл

                СтрокаУ3 = СтрокаУ2.Строки.Добавить();

                СтрокаУ3.Узел = СтрокаУ2.Узел+к3;

            КонецЦикла;

        КонецЦикла;

    КонецЦикла;


    // Создание Реквизита формы типа ДанныеФормыДерево

    МассивДобавляемыхРеквизитов = Новый Массив;

    МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Дерево",

        Новый ОписаниеТипов("ДеревоЗначений")));

    Для Каждого Колонка Из ДеревоОбъект.Колонки Цикл

        МассивДобавляемыхРеквизитов.Добавить(

           Новый РеквизитФормы(Колонка.Имя, Колонка.ТипЗначения, "Дерево"));

    КонецЦикла;

    ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);



  


                       
  





    // Преобразование объекта прикладного типа ДеревоЗначений

    // в реквизит управляемой формы (данные формы)

    ЗначениеВРеквизитФормы(ДеревоОбъект, "Дерево");


    // Создание элемента формы типа ТаблицаФормы для отображения дерева

    ЭлементДерево = Элементы.Добавить("Дерево", Тип("ТаблицаФормы"));

    ЭлементДерево.ПутьКДанным = "Дерево";

    ЭлементДерево.Отображение = ОтображениеТаблицы.Дерево;


    Для Каждого Колонка Из ДеревоОбъект.Колонки Цикл

        НовыйЭлемент = Элементы.Добавить(Колонка.Имя, Тип("ПолеФормы"),

            ЭлементДерево);

        НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;

        НовыйЭлемент.ПутьКДанным = "Дерево." + Колонка.Имя;

    КонецЦикла;


КонецПроцедуры   

Механизм Drag and D_rop (или проще говоря “Перетаскивания”) для ДереваЗначений расположенного на управляемой форме управляемого приложения
Основная сложность реализации механизма перетаскивания заключается в том, что у строки ДереваЗначений платформа не позволяет просто изменить родителя, т.е. переподчинить строку. Единственный способ это сделать – создать новую строку вместе со всеми подчиненными строками, т.е. полностью скопировать всю ветку дерева вместе со всей иерархией и подчинить ее требуемой строке-родителю, после чего удалить исходную ветку. Данная задача распадается на две подзадачи:
1). Перед перетаскиванием необходимо проверить корректность данной операции, узел дерева нельзя переносить в узлы подчиненные ему самому, т.е. родительский узел нельзя переносить в дочерние, т.к. это приведет к “бесконечной рекурсии” и “падению” платформы. Это реализуется с помощью обработчика события ЭлементДеревоПроверкаПеретаскивания(…)
2). Если перетаскивание возможно, то при помощи обработчика ЭлементДеревоПеретаскивание(…) запускается рекурсивная функция, которая создает новую ветку дерева, подчиненную требуемому родителю, а исходную удаляет.
Обращаю особое внимание на то, что в платформе 8.2 реализован механизм множественного выбора элементов, поэтому вышеуказанные операции необходимо произвести для всех выбранных пользователем элементов. ( Скачивать файлы может только зарегистрированный пользователь! )

Код 1C v 8.2 УП

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)


    // Создание и заполнение "обычного" объекта прикладного типа ДеревоЗначений,

    // который будет отображен на управляемой форме


    // Здесь необходимо расположить код из предыдущей статьи

    // «Работа с деревом значений и таблицей значений. Часть I (Основы)»

    // .....................................................


    // Добавим обработчики и установим свойства

    ЭлементДерево.МножественныйВыбор=Истина;

    ЭлементДерево.РазрешитьПеретаскивание=Истина;

    ЭлементДерево.РазрешитьНачалоПеретаскивания=Истина;

    ЭлементДерево.УстановитьДействие("ПроверкаПеретаскивания",

        "ЭлементДеревоПроверкаПеретаскивания");

    ЭлементДерево.УстановитьДействие("Перетаскивание",

        "ЭлементДеревоПеретаскивание");


КонецПроцедуры



  


                       
  





&НаКлиенте

Функция ПроверитьВозможностьПереноса(ПереносимыйЭлемент, Знач НовыйРодитель)


    Пока НЕ НовыйРодитель = Неопределено Цикл

        Если ПереносимыйЭлемент = НовыйРодитель Тогда

            Возврат Ложь;

        КонецЕсли;

        НовыйРодитель = НовыйРодитель.ПолучитьРодителя();

    КонецЦикла;


    Возврат Истина;


КонецФункции


&НаКлиенте

Функция СкопироватьСтрокуДерева(РеквизитДерево, Приемник, Источник)


    Перем НоваяСтрока, ОбратныйИндекс, КолПодчиненныхСтрок;


    // Источник может быть уже перенесен

    // Это происходит если выделены несколько элементов

    // одной и той же ветви дерева на разных уровнях иерархии

    Если Источник = Неопределено Тогда

        Возврат Неопределено;

    КонецЕсли;


    Если Приемник = Неопределено Тогда

        // Добавляем в корень

        НоваяСтрока = РеквизитДерево.ПолучитьЭлементы().Добавить();

    Иначе

        НоваяСтрока = Приемник.ПолучитьЭлементы().Добавить();

    КонецЕсли;


    ЗаполнитьЗначенияСвойств(НоваяСтрока, Источник);


    КолПодчиненныхСтрок = Источник.ПолучитьЭлементы().Количество();

    Для ОбратныйИндекс = 1 По КолПодчиненныхСтрок Цикл

        ПодчиненнаяСтрока = Источник.ПолучитьЭлементы()

            [КолПодчиненныхСтрок - ОбратныйИндекс];

        СкопироватьСтрокуДерева(РеквизитДерево, НоваяСтрока, ПодчиненнаяСтрока);

    КонецЦикла;



  


                       
  





    Если Источник.ПолучитьРодителя() = Неопределено Тогда

        РеквизитДерево.ПолучитьЭлементы().Удалить(Источник);

    Иначе

        Источник.ПолучитьРодителя().ПолучитьЭлементы().Удалить(Источник);

    КонецЕсли;


    Возврат НоваяСтрока;


КонецФункции


&НаКлиенте

Процедура ЭлементДеревоПроверкаПеретаскивания(Элемент, ПараметрыПеретаскивания,

        СтандартнаяОбработка, Строка, Поле)


    // Узел нельзя переносить в узлы подчиненные ему самому

    // т.е. родительский узел нельзя переносить в дочерние.

    // Проверим это условие для всех выделенных элементов


    СтандартнаяОбработка = Ложь;


    РеквизитДерево = ЭтаФорма["Дерево"];


    ИДНовыйРодитель = Строка;

    // Если НовыйРодитель = Неопределено => Корень дерева

    НовыйРодитель = ?(ИДНовыйРодитель = Неопределено, Неопределено,

        РеквизитДерево.НайтиПоИдентификатору(ИДНовыйРодитель));


    МассивИДПереносимыхЭлементов = ПараметрыПеретаскивания.Значение;


    Для каждого ИДПереносимыйЭлемент из МассивИДПереносимыхЭлементов Цикл



  


                       
  





        ПереносимыйЭлемент = РеквизитДерево.НайтиПоИдентификатору(

            ИДПереносимыйЭлемент);


        Если НЕ ПроверитьВозможностьПереноса(ПереносимыйЭлемент,

                    НовыйРодитель) Тогда

            ПараметрыПеретаскивания.Действие=ДействиеПеретаскивания.Отмена;

            Прервать;

        КонецЕсли;

    КонецЦикла;


КонецПроцедуры


&НаКлиенте

Процедура ЭлементДеревоПеретаскивание(Элемент, ПараметрыПеретаскивания,

        СтандартнаяОбработка, Строка, Поле)


    СтандартнаяОбработка=Ложь;


    РеквизитДерево = ЭтаФорма["Дерево"];


    ИДПриемник = Строка;

    // Если ИДПриемник = Неопределено => Корень дерева

    Приемник = ?(ИДПриемник = Неопределено, Неопределено,

        РеквизитДерево.НайтиПоИдентификатору(ИДПриемник));


    МассивИДИсточник = ПараметрыПеретаскивания.Значение;


    Для Каждого ИДИсточник Из МассивИДИсточник Цикл

        Источник = РеквизитДерево.НайтиПоИдентификатору(ИДИсточник);

        НоваяСтрока = СкопироватьСтрокуДерева(РеквизитДерево, Приемник, Источник);

        // Производится копирование в корень

        // Для "красоты" развернем вновь созданную ветвь

        Если Приемник = Неопределено и НоваяСтрока<>Неопределено Тогда

            Элементы["Дерево"].Развернуть(НоваяСтрока.ПолучитьИдентификатор(),

                Истина);

        КонецЕсли;

    КонецЦикла;


    // Для "красоты" развернем ветвь-родителя

    Если НЕ Приемник = Неопределено Тогда

        Элементы["Дерево"].Развернуть(ИДПриемник, Истина);

    КонецЕсли;



  


                       
  





КонецПроцедуры   

Реализовать трехпозиционный флажок в ДеревеЗначений на управляемой форме
который работает по следующему алгоритму:
* Если у элемента ДереваЗначений нет подчиненных элементов, то флажок может быть либо “включен”, либо “выключен”.
* Если у элемента есть подчиненные, то флажок “включен”, если ВКЛЮЧЕНЫ флажки у ВСЕХ подчиненных элементов, “выключен” если ВЫКЛЮЧЕНЫ флажки у ВСЕХ подчиненных элементов.
Если у некоторых подчиненных элементов флажки включены, а у некоторых выключены, то флажок родительского элемента имеет значение “неопределенно”.
* При включении флажка у родительского элемента, включаются флажки ВСЕХ подчиненных, при выключении флажка у родительского элемента, выключаются флажки ВСЕХ подчиненных.
Возьмем из первой статьи процедуру построения дерева значений и доработаем ее, добавив в дерево еще одну колонку, которая будет содержать элемент управления флажок и реализуем для него обработчик события “ПриИзменении”. Весь алгоритм сводится к обработке изменения флажка: у всех подчиненных элементов необходимо включить/выключить флажки в зависимости от состояния флажка текущего элемента, а у всех родителей текущего элемента (которые расположены на верхних уровнях иерархии) проставить флажки в состояния “включен”/”выключен”/”неопределенно” в соответствии с вышеописанным алгоритмом. ( Скачивать файлы может только зарегистрированный пользователь! )

Код 1C v 8.2 УП

 &НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)


    // Создание и заполнение "обычного" объекта прикладного типа ДеревоЗначений,

    // который будет отображен на управляемой форме

    ДеревоОбъект = Новый ДеревоЗначений;

    ДеревоОбъект.Колонки.Добавить("Узел", Новый ОписаниеТипов("Строка"));

    ДеревоОбъект.Колонки.Добавить("Пометка", Новый ОписаниеТипов("Число"));

    Для к1 = 1 По 3 Цикл

        СтрокаУ1 = ДеревоОбъект.Строки.Добавить();

        СтрокаУ1.Узел = "Узел"+к1;

        Для к2 = 1 По 3 Цикл

            СтрокаУ2 = СтрокаУ1.Строки.Добавить();

            СтрокаУ2.Узел = СтрокаУ1.Узел+к2;

            Для к3 = 1 По 3 Цикл

                СтрокаУ3 = СтрокаУ2.Строки.Добавить();

                СтрокаУ3.Узел = СтрокаУ2.Узел+к3;

            КонецЦикла;

        КонецЦикла;

    КонецЦикла;



  


                       
  





    // Создание Реквизита формы типа ДанныеФормыДерево

    МассивДобавляемыхРеквизитов = Новый Массив;

    МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Дерево",

        Новый ОписаниеТипов("ДеревоЗначений")));

    Для Каждого Колонка Из ДеревоОбъект.Колонки Цикл

        МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы(Колонка.Имя,

            Колонка.ТипЗначения, "Дерево"));

    КонецЦикла;

    ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);


    // Преобразование объекта прикладного типа ДеревоЗначений

    // в реквизит управляемой формы (данные формы)

    ЗначениеВРеквизитФормы(ДеревоОбъект, "Дерево");


    // Создание элемента формы типа ТаблицаФормы для отображения дерева

    ЭлементДерево = Элементы.Добавить("Дерево", Тип("ТаблицаФормы"));

    ЭлементДерево.ПутьКДанным = "Дерево";

    ЭлементДерево.Отображение = ОтображениеТаблицы.Дерево;


    Для Каждого Колонка Из ДеревоОбъект.Колонки Цикл

        НовыйЭлемент = Элементы.Добавить(Колонка.Имя, Тип("ПолеФормы"),

            ЭлементДерево);

        НовыйЭлемент.ПутьКДанным = "Дерево." + Колонка.Имя;

        Если НЕ Колонка.Имя = "Пометка" Тогда

            НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;

        Иначе

            НовыйЭлемент.Вид = ВидПоляФормы.ПолеФлажка;

            НовыйЭлемент.ТриСостояния = Истина;

            НовыйЭлемент.УстановитьДействие("ПриИзменении", 

                "ФлажокПриИзменении");

        КонецЕсли;

    КонецЦикла;


КонецПроцедуры


&НаКлиенте

Процедура ФлажокПриИзменении(Элемент)



  


                       
  





    ИДТекущейСтроки = Элементы["Дерево"].ТекущаяСтрока;


    Если ИДТекущейСтроки <> Неопределено Тогда


        ЭлементКоллекции = ЭтаФорма["Дерево"].НайтиПоИдентификатору(

            ИДТекущейСтроки);


        Если ЭлементКоллекции.Пометка = 2 Тогда

            ЭлементКоллекции.Пометка = 0;

        КонецЕсли;


        УстановкаФлажков(ЭлементКоллекции, ЭлементКоллекции.Пометка);


        Родитель = ЭлементКоллекции.ПолучитьРодителя();

        Пока Родитель <> Неопределено Цикл

            Родитель.Пометка = ?(УстановленноДляВсех(ЭлементКоллекции),

                ЭлементКоллекции.Пометка, 2);

            ЭлементКоллекции = Родитель;

            Родитель = ЭлементКоллекции.ПолучитьРодителя();

        КонецЦикла;


    КонецЕсли;


КонецПроцедуры


&НаКлиенте

Процедура УстановкаФлажков(ЭлементКоллекции, ЗначениеПометки)


    ПодчинЭлементы = ЭлементКоллекции.ПолучитьЭлементы();

    Для Каждого ТекЭлемент Из ПодчинЭлементы Цикл

        ТекЭлемент.Пометка = ЗначениеПометки;

        УстановкаФлажков(ТекЭлемент, ТекЭлемент.Пометка);

    КонецЦикла;


КонецПроцедуры


&НаКлиенте

Функция УстановленноДляВсех(ЭлементКоллекции)


    СоседниеЭлементы =

        ЭлементКоллекции.ПолучитьРодителя().ПолучитьЭлементы();

    Для Каждого ТекЭлемент Из СоседниеЭлементы Цикл

        Если ТекЭлемент.Пометка <> ЭлементКоллекции.Пометка Тогда

            Возврат Ложь;

        КонецЕсли;

    КонецЦикла;

    Возврат Истина;


КонецФункции   

Источник

Дерево значений в управляемой форме

Свойства и методы универсальных коллекции значений типа дерево значений как и  таблицы значений не доступны в тонком клиенте. Их нужно создавать на сервере, а затем методом контекста формы  ЗначениеВРеквизитФормы(<Значение>, <ИмяРеквизита>)    преобразовать  значение объекта в   реквизит управляемой формы  с указанным именем ИмяРеквизита

Мне дали задание  –  создать форму списка заказа в виде дерева значений, как показано на рис 1

Форма создается очень просто в конфигураторе  ( см рис 2)

Однако, у меня не получилось  на сервере создавать дерево значений в путем выгрузки результата запроса по группировкам в дерево таким образом :
Дерево = РезультатЗапроса.Выгрузить(ОбходРезультатаЗапроса.ПоГруппировкам);
У меня возникала  ошибка при вызове метода контекста формы:
ЗначениеВРеквизитФормы(Дерево, “ДеревоЗаказов”);
Причина ошибки была в том, что структура колонок реквизита формы ДеревоЗаказов не соответствовала структуре объекта  дерево, полученного в результате выгрузки запроса. Я не стал глубоко об этом думать и решил создавать дерево значений  в цикле. Программный код показан ниже:

&НаСервере
Процедура ЗаполнитьДеревоНаСервере()
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| Заказ.Ссылка КАК Ссылка,
| НАЧАЛОПЕРИОДА(Заказ.ДатаПриема, ЧАС) КАК Время
|ИЗ
| Документ.Заказ КАК Заказ
|ГДЕ
| Заказ.ДатаПриема МЕЖДУ &ДатаНач И &ДатаКон
|
|УПОРЯДОЧИТЬ ПО
| Заказ.ДатаПриема
|ИТОГИ ПО
| Время";

Запрос.УстановитьПараметр("ДатаКон", Период.ДатаОкончания);
Запрос.УстановитьПараметр("ДатаНач", Период.ДатаНачала);
РезультатЗапроса = Запрос.Выполнить();
// Так не получается и пришлось создать дерево в цикле. Тема  статьи
//Дерево = РезультатЗапроса.Выгрузить(ОбходРезультатаЗапроса.ПоГруппировкам); 
Дерево = Новый ДеревоЗначений;
Дерево.Колонки.Добавить("Время");
Дерево.Колонки.Добавить("Заказ");
ВыборкаВремя = РезультатЗапроса.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
Пока ВыборкаВремя.Следующий() Цикл
Строка = Дерево.Строки.Добавить();
Строка.Время= ВыборкаВремя.Время;
ВыборкаДетальныеЗаписи = ВыборкаВремя.Выбрать();
Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
Нов=Строка.Строки.Добавить(); 
Нов.Заказ= ВыборкаДетальныеЗаписи.Ссылка; 
КонецЦикла;
КонецЦикла;
ЗначениеВРеквизитФормы(Дерево, "ДеревоЗаказов");
КонецПроцедуры

Для создания полной копии исходного дерева значений можно использовать метод метод скопировать:

НовоеДеревоСостава =  ДеревоСостава.Скопировать();

Следующая процедура предназначена для заполнения реквизита формы типа «ДеревоЗначений»
Параметры:
КоллекцияЭлементовДерева – реквизит формы, который имеет тип «ДеревоЗначений» . Реквизит заполняется значениями из второго параметра процедуры.
ДеревоЗначений – ДеревоЗначений – параметр содержит данные для заполнения.

 &НаСервере 
Процедура ЗаполнитьКоллекциюЭлементовДереваДанныхФормы(КоллекцияЭлементовДерева, ДеревоЗначений) Экспорт
  Для Каждого Строка Из ДеревоЗначений.Строки Цикл
 ЭлементДерева = КоллекцияЭлементовДерева.Добавить();
 ЗаполнитьЗначенияСвойств(ЭлементДерева, Строка);  
    Если Строка.Строки.Количество() > 0 Тогда 
заполнитьКоллекциюЭлементовДереваДанныхФормы(ЭлементДерева.ПолучитьЭлементы(), Строка); 
 КонецЕсли;
  КонецЦикла;
  КонецПроцедуры

Пример вызова процедуры:

КоллекцияЭлементовДерева =Элементы.Дерево.ПолучитьЭлементы();
  КоллекцияЭлементовДерева.Очистить();
ЗаполнитьКоллекциюЭлементовДереваДанныхФормы(КоллекцияЭлементовДерева, ДеревоРезультатСКД);