Регистр сведений заполнять реквизит при записи

23.03.10 — 11:38

Есть измерение — показатель(составной тип)

Есть реквизит — ТипЗначения(просто строка)

Как заполнять ТипЗначения при записи в регистр, в зависимости от типа показателя? ну чтобы пользователь ТипЗначения вручную не заполнял

1 — 23.03.10 — 11:40

Перед записью обходишь набор и присваиваешь чо надо.

2 — 23.03.10 — 11:40

ПередЗаписью никто не отменял

3 — 23.03.10 — 11:40

В модуле регистра есть два обработчика ПередЗаписью и ПриЗаписи. Там все и делать

4 — 23.03.10 — 11:46

(0) А связь по типу не работает?

А что за регистр? И почему для хранения таких наборов не используется ПВХ?

5 — 23.03.10 — 12:02

перед записью в отборе записи еще нет

6 — 23.03.10 — 12:03

т.е. не в отборе, а в наборе

7 — 23.03.10 — 12:05

(5) Ага, а заводится она там от сырости.

Не болтайте ерундой!

8 — 23.03.10 — 12:17

(7) сори, обшипся)

9 — 23.03.10 — 12:26

а если передзаписью обходит набор и присвоить что надо — его же снова надо будет записат — и тогда вечный кайф)

10 — 23.03.10 — 12:27

(9) Нафига его перезаписывать, если он еще не записан?

11 — 23.03.10 — 12:44

12 — 23.03.10 — 13:27

ау! научите грамоте)) куда все пропали??

13 — 23.03.10 — 13:38

(11) проверить — не судьба?

14 — 23.03.10 — 14:06

не работает так) вот и спрашиваю

15 — 23.03.10 — 16:28

есть еще добрые знающие люди?:)

16 — 23.03.10 — 16:31

В модуле-то в модуле, а в каком обработчике?

17 — 23.03.10 — 16:35

(16) в том то и вопрос! если ПередЗаписью — то объект ЭтотОбъект записей еще не содержит — это ж набор записей, че там будет перед записью — все правильно — ничего. А ПриЗаписи — записи в нем есть, но как их изменить? если их поменять — надо снова записывать

18 — 23.03.10 — 16:35

(17) Это все одна транзакция! Есть там объект и в ПередЗаписью.

19 — 23.03.10 — 16:42

20 — 23.03.10 — 16:47

(19) Не понял, зачем читать?

21 — 23.03.10 — 16:58

(20) пока не прочитать в нем записей нет

22 — 23.03.10 — 17:00

(21) Ищи лучше — должны быть.

23 — 23.03.10 — 17:01

(21) Не болтайте ерунодй!

Убери нафиг все свои Прочитать() и Записать().

24 — 23.03.10 — 17:02

25 — 23.03.10 — 17:05

блин, нету нифига, обыскался уже

(25) а точно добавление записи у тебя, а не замещение существующей?

Регистры сведений в 1С предназначены для хранения произвольных данных в разрезе нескольких измерений и, при необходимости, в разрезе времени. Рассмотрим подробнее работу с этим прикладным объектом.

• Предназначение регистра сведений
• Добавление записей
• Изменение записей
• Чтение записей
• Удаление записей
• Очистка регистра сведений

Предназначение регистра сведений

Регистры сведений в 1С — это прикладные объекты конфигурации для хранения данных в структурированном виде (в разрезе измерений). Например, в регистре сведений можно хранить курсы валют в разрезе валют, цены номенклатуры в разрезе номенклатур, ФИО физических лиц в разрезе физических лиц и т.д.

При проектировании разработчик указывает необходимость хранения данных в разрезе времени и минимальную периодичность, с которой записи будут храниться в регистре:

Регистры сведений, для которых указана периодичность, называются периодическими.

Изменение данных в регистре может осуществляться как вручную, так и при помощи документов. Режим записи в регистр определяет разработчик на этапе проектирования:

Физически регистр сведений представляет собой таблицу, в которой хранятся следующие данные:

• измерения — описывают разрезы, в которых хранится информация;
• период — поле, используемое для разворота данных по времени. Поле добавляется автоматически при указании свойства «Периодичность», отличного от «Непериодический»;
• регистратор — поле, используемое для хранения документа, с которым связана запись. Поле добавляется автоматически при указании свойства «Режим записи» в значение «Подчинение регистратору»;
• ресурсы — непосредственно хранят информацию для комбинации измерений;
• реквизиты — дополнительная произвольная информация, относящаяся к конкретной записи регистра.

Для всех регистров сведений обеспечивается контроль уникальности записей, т.е. в регистре не может быть двух одинаковых записей. Одинаковыми считаются записи, у которых совпадают значения измерений, период (если регистр периодический) и регистратор (если регистр подчинен регистратору).

Добавление записей

Программно добавить записи в регистр сведений можно при помощи:

• объекта НаборЗаписей;
• объекта МенеджерЗаписи.

Объект МенеджерЗаписи можно использовать только для работы с независимыми регистрами. Причем можно обрабатывать только одну запись. Объект предназначен в основном для интерактивной работы, но программно с ним также можно работать. На системном уровне МенеджерЗаписи использует объект НаборЗаписей.

Общая схема добавления записей в регистр сведений при помощи объекта НаборЗаписей выглядит так:

1. создание объекта НаборЗаписей;
2. наложение отборов на измерения, период (если регистр периодический) и регистратора (если регистр подчинен регистратору);
3. добавление и заполнение значений полей записей;
4. запись набора записей.

// Добавление записи в независимый непериодический регистр сведений
НаборЗаписей = РегистрыСведений.ВерсииПодсистем.СоздатьНаборЗаписей(); // Этап 1
НаборЗаписей.Отбор.ИмяПодсистемы.Установить(ИмяПодсистемы); // Этап 2
// Этап 3
НоваяЗапись = НаборЗаписей.Добавить();
НоваяЗапись.ИмяПодсистемы = ИмяПодсистемы;
НоваяЗапись.Версия = НомерВерсии;
НаборЗаписей.Записать(); // Этап 4

// Добавление записи в независимый периодический регистр сведений
НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей(); // Этап 1
// Этап 2
НаборЗаписей.Отбор.Валюта.Установить(Доллар);
НаборЗаписей.Отбор.Период.Установить(НачалоДня(ТекущаяДата()));
// Этап3
НоваяЗапись = НаборЗаписей.Добавить();
НоваяЗапись.Период = ТекущаяДата();
НоваяЗапись.Валюта = Доллар;
НоваяЗапись.Курс = 57.92;
НоваяЗапись.Кратность = 1;
НаборЗаписей.Записать(); // Этап 4

Общая схема добавления записей в регистр сведений при помощи объекта МенеджерЗаписи выглядит так:

1. создание объекта МенеджерЗаписи;
2. заполнение значений полей записи;
3. запись записи.

// Добавление записи в независимый непериодический регистр сведений
Запись = РегистрыСведений.ВерсииПодсистем.СоздатьМенеджерЗаписи(); // Этап 1

// Этап 2
Запись.ИмяПодсистемы = ИмяПодсистемы;
Запись.Версия = НомерВерсии;

Запись.Записать(); // Этап 3

// Добавление записи в независимый периодический регистр сведений
Запись = РегистрыСведений.КурсыВалют.СоздатьМенеджерЗаписи(); // Этап 1

// Этап 2
Запись.Период = ТекущаяДата();
Запись.Валюта = Доллар;
Запись.Курс = 57.92;
Запись.Кратность = 1;

Запись.Записать(); // Этап 3

Изменение записей

Изменять существующие записи регистров сведений возможно при помощи объектов НаборЗаписей и МенеджерЗаписи. Ограничения объекта МенеджерЗаписи были описаны в разделе Добавление записей.

Общая схема редактирования записей регистров сведений:

1. создание объекта НаборЗаписей или МенеджерЗаписи;
2. наложение отборов;
3. чтение записей базы данных, соответствующих наложенным отборам;
4. редактирование прочитанных записей;
5. запись отредактированных записей.

// Редактирование записей с использованием объекта НаборЗаписей
НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей(); // Этап 1
// Этап 2
НаборЗаписей.Отбор.Период.Установить(ДатаКурса);
НаборЗаписей.Отбор.Валюта.Установить(Доллар);
НаборЗаписей.Прочитать(); // Этап 3
Для Каждого Запись Из НаборЗаписей Цикл
Запись.Курс = 57.84; // Этап 4
КонецЦикла;
НаборЗаписей.Записать(); // Этап 5

// Редактирование записей с использованием объекта МенеджерЗаписи
Запись = РегистрыСведений.КурсыВалют.СоздатьМенеджерЗаписи(); // Этап 1
// Этап 2
Запись.Период = ДатаКурса;
Запись.Валюта = Доллар;
Запись.Прочитать(); // Этап 3
Если Запись.Выбран() Тогда // Проверка, что запись существует
Запись.Курс = 57.92; // Этап 4
Запись.Записать(); // Этап 5
КонецЕсли;

Чтение записей

Чтение информации из базы данных рекомендуется выполнять при помощи запросов. Данный способ обеспечивает гибкое применение отборов и группировок, а также возможность выбора записей из нескольких таблиц.

Запрос = Новый Запрос;
Запрос.Текст =
«ВЫБРАТЬ
| КурсыВалют.Период,
| КурсыВалют.Валюта,
| КурсыВалют.Курс
|ИЗ
| РегистрСведений.КурсыВалют КАК КурсыВалют»;

Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
// обход результата выполнения запроса
КонецЦикла;

Для периодических регистров сведений есть возможность получить наиболее поздние записи, период которых меньше указанной даты — срез последних, и наиболее ранние записи, период которых больше указанной даты — срез первых. Для получения среза первых и среза последних запросом необходимо использовать одноименные виртуальные таблицы, в параметрах которых сразу можно задать дату среза и отборы. Отборы, если они необходимы, рекомендуется накладывать именно в параметрах виртуальных таблиц, т.к. это позволяет ускорить выполнение запроса.

// Получение записи, у которой валюта равна значению из переменной «ВыбраннаяВалюта» и период МЕНЬШЕ или равен значению из переменной «ВыбраннаяДата»
Запрос = Новый Запрос;
Запрос.Текст =
«ВЫБРАТЬ
| КурсыВалютСрезПоследних.Период,
| КурсыВалютСрезПоследних.Валюта,
| КурсыВалютСрезПоследних.Курс
|ИЗ
| РегистрСведений.КурсыВалют.СрезПоследних(&Период, Валюта = &Валюта) КАК КурсыВалютСрезПоследних»;

Запрос.УстановитьПараметр(«Валюта», ВыбраннаяВалюта);
Запрос.УстановитьПараметр(«Период», ВыбраннаяДата);

Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
// обход результата выполнения запроса
КонецЦикла;

// Получение записи, у которой валюта равна значению из переменной «ВыбраннаяВалюта» и период БОЛЬШЕ или равен значению из переменной «ВыбраннаяДата»
Запрос = Новый Запрос;
Запрос.Текст =
«ВЫБРАТЬ
| КурсыВалютСрезПервых.Период,
| КурсыВалютСрезПервых.Валюта,
| КурсыВалютСрезПервых.Курс
|ИЗ
| РегистрСведений.КурсыВалют.СрезПервых(&Период, Валюта = &Валюта) КАК КурсыВалютСрезПервых»;

Запрос.УстановитьПараметр(«Валюта», ВыбраннаяВалюта);
Запрос.УстановитьПараметр(«Период», ВыбраннаяДата);

Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
// обход результата выполнения запроса
КонецЦикла;

Кроме чтения запросом возможно использование методов объектной модели.

Для непериодических регистров сведений:

• Выбрать(<Отбор>, <Порядок>) — выбирает записи с указанным отбором;
• ВыбратьПоРегистратору(<Регистратор>) — выбирает все записи указанного регистратора;
• Получить(<Отбор>) — получает ресурсы записи с отбором по всем измерениям.

Для периодических регистров сведений:

• Выбрать(<НачалоИнтервала>, <КонецИнтервала>, <Отбор>, <Порядок>) — выбирает записи с указанным отбором, у которых период находится между <НачалоИнтервала> и <КонецИнтервала>;
• ВыбратьПоРегистратору(<Регистратор>) — выбирает все записи указанного регистратора;
• Получить(<Период>, <Отбор>) — получает ресурсы записи с отбором по всем измерениям и периоду;
• ПолучитьПервое(<НачалоПериода>, <Отбор>) — получает ресурсы наиболее ранней записи, соответствующей указанным периоду и отбору;
• ПолучитьПоследнее(<КонецПериода>, <Отбор>) — получает ресурсы наиболее поздней записи, соответствующей указанным периоду и отбору;
• СрезПервых(<НачалоПериода>, <Отбор>) — получает таблицу наиболее ранних записей, соответствующую указанным периоду и отбору;
• СрезПоследних(<КонецПериода>, <Отбор>) — получает таблицу наиболее поздних записей, соответствующую указанным периоду и отбору.

Удаление записей

Для удаления записи(записей) в независимом регистре сведений необходимо:

1. создать набор записей;
2. наложить требуемые отборы на измерения и период (если регистр периодический);
3. записать набор записей без предварительного чтения.

НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей();

НаборЗаписей.Отбор.Валюта.Установить(Доллар);
НаборЗаписей.Отбор.Период.Установить(НачалоДня(ТекущаяДата()));

НаборЗаписей.Записать();

Для удаления записей в подчиненном регистре сведений необходимо:

1. создать набор записей;
2. наложить отбор на регистратора;
3. записать набор записей без предварительного чтения.

НаборЗаписей = РегистрыСведений.ЦеныНоменклатуры.СоздатьНаборЗаписей();
НаборЗаписей.Отбор.Регистратор.Установить(СсылкаНаДокументРегистратор);
НаборЗаписей.Записать();

Очистка регистра сведений

Для удаления всех записей в независимом регистре сведений достаточно записать набор записей этого регистра без установки отборов:

НаборЗаписей = РегистрыСведений.КурсыВалют.СоздатьНаборЗаписей();
НаборЗаписей.Записать();

Запись в регистр сведений, подчиненный регистратору, возможна только при установке отбора по регистратору, поэтому для очистки таких регистров необходимо:

1. получить перечень ссылок всех регистраторов регистра сведений;
2. последовательно записать пустой набор записей с отбором по регистраторам из пункта 1.

Запрос = Новый Запрос(«ВЫБРАТЬ
| ЦеныНоменклатуры.Регистратор
|ИЗ
| РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры»);

Выборка = Запрос.Выполнить().Выбрать();

НаборЗаписей = РегистрыСведений.ЦеныНоменклатуры.СоздатьНаборЗаписей();
Пока Выборка.Следующий() Цикл
НаборЗаписей.Отбор.Регистратор.Установить(Выборка.Регистратор);
НаборЗаписей.Записать();

Событие ПередЗаписью регистра сведений. Как перед записью изменить значение реквизита записи?

 Процедура ПередЗаписью(Отказ, Замещение)

	Для Каждого ТекЗапись Из ЭтотОбъект Цикл

		Если ТекЗапись.СерияНоменклатуры.Восстановленный Тогда 

			ТекЗапись.Цвет="2551650";	

		Иначе

			ТекЗапись.Цвет="";

		КонецЕсли;

	КонецЦикла;	

КонецПроцедуры   

 Процедура ПередЗаписью (Отказ, Замещение)

            ДатаРегистрации = Константы.ДатаРегистрации.Получить ();

            Для Каждого ТекЗапись Из ЭтотОбъект Цикл

             
                        Если ТекЗапись.Период < ДатаРегистрации Тогда

// Если период раньше даты регистрации

            Отказ = Истина; // отказ от записи

                        Сообщить(" Запись от " + ТекЗапись.Период +

                                               " с курсом " + ТекЗапись.Курс +

                                               " раньше даты регистрации фирмы!");

                        КонецЕсли;

            КонецЦикла;

             
    Если Отказ Тогда

            Сообщить ("Запись не выполнена!");

            КонецЕсли;

КонецПроцедуры   

Содержание:

1.      Свойства регистров сведений, влияющие на указание их ключа при записи в режиме конфигурации 1С

2.      Объект встроенного языка программирования 1С для записи регистров сведений в 1С 8.3  

1.      Свойства регистров сведений, влияющие на указание их ключа при записи в режиме конфигурации 1С

Регистры сведений – удобный механизм хранения различной информации (ресурсов) в сопоставлении с какими-то наборами 1С ключевых полей (измерений – или «ключами записей»). Одному (уникальному) набору ключа может соответствовать только один набор ресурсов, что отличает их, например, от справочников, которые в принципе могут иметь одинаковые значения ключевых полей (код, наименование и т.д.). Если в 1С 8 регистр сведений периодический, то уникальность набора измерений расширяется еще и в разрезе периода – т.е. ключ записи регистра составляет уникальный набор измерений плюс значение периода записи. Кроме того, регистры сведений, в отличие от тех же справочников, обладают большими возможностями по параллельной работе с СУБД (операции записи/чтения), т.к. архитектура их таблиц в СУБД позволяет производить более тонкие блокировки.

Рассмотрим, какие бывают особенности записи регистров сведений 1С 8.3 программно.

К таковым относятся:

·        Режим записи 1С

—   Независимый

—   Подчинение регистратору

·        Периодичность

—   Непериодический

—   Периодический: в переделах секунды, дня, месяца, квартала или года; если регистр сведений подчиненный регистратору, то к вариантам периодичности добавляется еще и «по позиции регистратора»

Таким образом, существует четыре разновидности свойств регистров сведений, каждой из которых соответствует своя полнота указания в 1С ключевых полей при записи.

Самый простой механизм записи имеет независимый, непериодический регистр сведений: для его записи достаточно указать значения обязательных к заполнению измерений (но не менее одного).

Если регистр «подчинен регистратору», то среди ключевых полей появляется обязательное для заполнения поле «Регистратор». Запись таки регистров ведется, как правило, в процедурах обработки проведения документов – но это не обязательно – важно, чтобы было заполнено поле «Регистратор». Интересно, что в качестве регистратора может выступать не только ссылка на проводимый документ, но и ссылка на любой другой документ допустимого типа – т.е. текущий проводимый документ может формировать по регистру сведений движения для другого документа.

Если регистр периодический, то среди 1С ключевых полей появляется обязательное для заполнения поле «Период». При передаче значения в этой поле оно (значение) всегда преобразуется к «началу периода» выбранного для регистра варианта периодичности: например, если периодичность регистра «В пределах месяца», а мы отправляем в поле «Период» значение 09.10.2022 19:29:35, то в этом поле «Период» будет зафиксировано значение 01.10.2022 0:00:00 – и именно оно будет участвовать в запросах. Для вариантов периодичности «По позиции регистратора» и «В пределах секунды» эти преобразования не столь очевидны, но, тем не менее, о разнице между «позицией» и «секундой» помнить нужно.

Для периодического регистра 1С подчиненного регистратору требуется самая полная форма заполнения ключа: помимо обязательных измерений следует заполнять и «Период» и «Регистратор».  

2.      Объект встроенного языка программирования 1С для записи регистров сведений в 1С 8.3

В 1С 8 регистр сведений можно заполнять (записывать) с помощью двух объектов:

·        РегистрСведенийМенеджерЗаписи

·        РегистрСведенийНаборЗаписей

С точки зрения производительности важно понимать, что когда мы используем менеджер записи 1С, то каждая запись отправляется в СУБД отдельным запросом (например, в цикле), в то время, как в 1С набор записей регистра сведений за одно обращение к СУБД можно записать сразу много записей.

Также следует помнить, что в 1С 8 регистр сведений по одному ключу может хранить только один набор ресурсов, и если вы попытаетесь добавить запись с уже существующим набором 1С ключевых полей, то в общем случае получите ошибку «запись с такими ключевыми полями уже существует». Для управления такой ситуацией в команде «Записать» есть параметр «Замещать» (как у менеджера записи, так и у набора записей). При «Замещать» = Истина мы перепишем значения существующих ключей и уникальность будет сохранена.

Еще одна особенность наборов записей: он предоставляет разработчику возможность работы с «событиями», такими как «ОбработкаЗаполнения», «ПередЗаписью», «ПриЗаписи» и другими (см. описание встроенного языка), что может быть полезно при решении многих задач.

Мы рассмотрели особенности регистров, которые влияет на их запись. Конкретные пр

имеры программного кода 1С по записи регистров можно легко найти в документации и на просторах интернета.

Специалист компании «Кодерлайн»

Игорь Борисенко