При разработке решений возникает необходимость добавить реквизит формы, состав и типы которых зависят от данных. Например при построении динамических деревьев с периодами, или при выводе контактной информации и т.д.
Содержание
- Задача
- Добавление реквизитов
- Удаление реквизитов
- Добавление реквизита табличной части
- Добавление реквизита с типом Произвольный
Задача
Для наглядности разберем простой пример, в котором можно было обойтись только элементами формы, но мы создадим и реквизиты.
Есть некая конфигурация, в форме элемента справочника Номенклатура необходимо программно создавать реквизиты формы и элементы к ним:
- ЯчейкаХранения, тип СправочникСсылка.ЯчейкиХранения;
- ТекущийОстаток, тип Число.
Элементы объединить в группу с горизонтальной группировкой. На текущий момент форма имеет следующий вид:
Добавление реквизитов
В обработчике формы ПриСозданииНаСервере() опишем код, который разбивается на 3 этапа:
- Описание и создание реквизитов формы;
- Создание элементов формы, объединение в группу без отображения;
- Заполнение данных.
Ниже приведен готовый код, код снабжен комментариями и разбит на области для лучшего понимания
&НаСервере Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка) #Область ДобавлениеРеквизитовФормы // Массив для новых реквизитов ДобавляемыеРеквизиты = Новый Массив; // Опишем ревизиты формы Реквизит_ЯчейкаХранения = Новый РеквизитФормы("ЯчейкаХранения", Новый ОписаниеТипов("СправочникСсылка.ЯчейкиХранения"), , "Ячейка"); Реквизит_ТекущийОстаток = Новый РеквизитФормы("ТекущийОстаток", Новый ОписаниеТипов("Число", , , Новый КвалификаторыЧисла(10, 3)), , "Остаток"); // Для наглядности заполним массив после описания реквизитов формы ДобавляемыеРеквизиты.Добавить(Реквизит_ЯчейкаХранения); ДобавляемыеРеквизиты.Добавить(Реквизит_ТекущийОстаток); // Добавим новые реквизиты в форму ИзменитьРеквизиты(ДобавляемыеРеквизиты); #КонецОбласти #Область ДобавлениеЭлементовФормы // Горизонтальная группа без отображения на форме ГруппаФормы = Элементы.Добавить("Группа_СправочныеДанные", Тип("ГруппаФормы")); ГруппаФормы.Вид = ВидГруппыФормы.ОбычнаяГруппа; ГруппаФормы.Отображение = ОтображениеОбычнойГруппы.Нет; ГруппаФормы.ОтображатьЗаголовок = Ложь; ГруппаФормы.Группировка = ГруппировкаПодчиненныхЭлементовФормы.Горизонтальная; // Элементы НовыйЭлемент = Элементы.Добавить("ЯчейкаХранения", Тип("ПолеФормы"), ГруппаФормы); НовыйЭлемент.ПутьКДанным = "ЯчейкаХранения"; НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода; НовыйЭлемент.ТолькоПросмотр = Истина; НовыйЭлемент = Элементы.Добавить("ТекущийОстаток", Тип("ПолеФормы"), ГруппаФормы); НовыйЭлемент.ПутьКДанным = "ТекущийОстаток"; НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода; НовыйЭлемент.ТолькоПросмотр = Истина; #КонецОбласти #Область ЗаполнениеДанных // Имитируем заполнение данных ЭтаФорма.ЯчейкаХранения = ПредопределенноеЗначение("Справочник.ЯчейкиХранения.Распаковка"); ЭтаФорма.ТекущийОстаток = 12; #КонецОбласти КонецПроцедуры
После выполнения приведенного кода форма будет выглядеть так:
Удаление реквизитов
Для удаления необходимо передать массив содержащий пути реквизитов в качестве второго параметра метода формы ИзменитьРеквизиты().
#Область УдалениеРеквизитовФормы // Массив удаляемых реквизитов УдаляемыеРеквизиты = Новый Массив; УдаляемыеРеквизиты.Добавить("ЯчейкаХранения"); УдаляемыеРеквизиты.Добавить("ТекущийОстаток"); // Удалим реквизиты формы ИзменитьРеквизиты( , УдаляемыеРеквизиты); #КонецОбласти
Внимание!!! Удалять можно только реквизиты созданные программно.
Добавление реквизита табличной части
Добавление реквизита и элемента формы для табличной части почти ничем не отличается, необходимо только указать путь «Объект.<ИмяТабличнойЧасти>». Ниже пример добавления реквизита Ячейка в ТЧ Комплектация.
#Область ДобавлениеРеквизитаТЧ // Массив для новых реквизитов ДобавляемыеРеквизиты = Новый Массив; // Опишем ревизиты формы Реквизит_Ячейка = Новый РеквизитФормы("Ячейка", Новый ОписаниеТипов("СправочникСсылка.ЯчейкиХранения"), "Объект.Комплектация", "Ячейка"); // Для наглядности заполним массив после описания реквизитов формы ДобавляемыеРеквизиты.Добавить(Реквизит_Ячейка); // Добавим новые реквизиты в форму ИзменитьРеквизиты(ДобавляемыеРеквизиты); НовыйЭлемент = Элементы.Добавить("КомплектацияЯчейка", Тип("ПолеФормы"), Элементы.Комплектация); НовыйЭлемент.ПутьКДанным = "Объект.Комплектация.Ячейка"; НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода; #КонецОбласти
Добавление реквизита с типом Произвольный
В одной из задач стало необходимо добавить реквизит с типом Произвольный, но ни СП, ни интернеты ответа не дали. В итоге через несколько попыток было найдено решение
ДобавляемыеРеквизиты.Добавить(Новый РеквизитФормы("Реквизит", Новый ОписаниеТипов("")));
Внимание!!! Данные добавленного реквизита сохраняться в ИБ не будут.
Программное добавление реквизитов в табличную часть. |
Я |
18.06.19 — 11:08
Доброе утро.
На форму в общем модуле добавляю реквизиты в табличную часть «Товары» программно. В самом документе в табличной части реквизиты в конфигураторе добавлены. Добавляю абсолютно одинаково, но почему-то характеристика добавляется, а номенклатура нет.
На что обратить внимание, где может быть ошибка?
Если Форма.ИмяФормы = «Документ.НашДокумент.Форма.ФормаДокумента» тогда
ДобавляемыеРеквизиты = Новый Массив;
//реквизиты ТЧ Товары
Номенклатура = Новый РеквизитФормы(«Номенклатура», Новый ОписаниеТипов(«СправочникСсылка.Номенклатура»), «Объект.Товары», «Номенклатура»);
Характеристика = Новый РеквизитФормы(«Характеристика», Новый ОписаниеТипов(«СправочникСсылка.ХарактеристикиНоменклатуры»), «Объект.Товары», «Характеристика»);
//Заполним массив после описания реквизитов формы
ДобавляемыеРеквизиты.Добавить(Номенклатура);
ДобавляемыеРеквизиты.Добавить(Характеристика);
//Добавим новые реквизиты в форму
Форма.ИзменитьРеквизиты(ДобавляемыеРеквизиты);
//добавление на форму элементов ТЧ
Номенклатура = Форма.Элементы.Добавить(«Номенклатура», Тип(«ПолеФормы»), Форма.Элементы.Товары);
Номенклатура.ПутьКДанным = «Объект.Товары.Номенклатура»;
Номенклатура.Вид = ВидПоляФормы.ПолеВвода;
Характеристика = Форма.Элементы.Добавить(«Характеристика», Тип(«ПолеФормы»), Форма.Элементы.Товары);
Характеристика.ПутьКДанным = «Объект.Товары.Характеристика»;
Характеристика.Вид =ВидПоляФормы.ПолеВвода;
КонецЕсли;
1 — 18.06.19 — 11:10
Замечу, что в отладчике в «Форма.Объект.Товары» оба реквизита присутствуют после обхода этих строк.
А вот уже в предприятии номенклатуры нет, а характеристика есть.
2 — 18.06.19 — 11:12
(1) Да собственно и перед выводом самим в самом конце события «при открытии формы» в отладчике оба реквизита присутствуют.
3 — 18.06.19 — 11:24
Почисти кэш
4 — 18.06.19 — 11:33
(3) Чистил, не помогло. На всякий случай еще раз почистил, снова не помогло.
5 — 18.06.19 — 11:40
>> В самом документе в табличной части реквизиты в конфигураторе добавлены
Зачем добавлять реквизиты формы, если они уже есть в метаданных. По идее ты вообще ошибку должен получить
6 — 18.06.19 — 11:41
(5) А как правильно добавить на форму реквизиты?
Ошибок никаких не получаю.
7 — 18.06.19 — 11:46
(6) Зачем это делать программно? Просто добавьте их в редакторе формы.
Код подобный вашему может быть использован для упрощения поддержки, когда непосредственное редактирование форм не рекомендуется. Но «НашДокумент» явно не тот случай.
8 — 18.06.19 — 11:47
(7) «НашДокумент» это абстрактное название документа. Документ типовой. Как и Номенклатура и Характеристика это абстрактные названия реквизитов.
А сама задача вполне реальна. И требование заключается в том, что все реквизиты на форму добавляются в расширении программно.
9 — 18.06.19 — 11:48
+(5)ТОже не поняла. Достаточно же элементы добавить.
10 — 18.06.19 — 11:48
Вот этого должно хватить, если реквизиты в ТЧ есть:
//добавление на форму элементов ТЧ
Номенклатура = Форма.Элементы.Добавить(«Номенклатура», Тип(«ПолеФормы»), Форма.Элементы.Товары);
Номенклатура.ПутьКДанным = «Объект.Товары.Номенклатура»;
Номенклатура.Вид = ВидПоляФормы.ПолеВвода;
Характеристика = Форма.Элементы.Добавить(«Характеристика», Тип(«ПолеФормы»), Форма.Элементы.Товары);
Характеристика.ПутьКДанным = «Объект.Товары.Характеристика»;
Характеристика.Вид =ВидПоляФормы.ПолеВвода;
11 — 18.06.19 — 11:53
(10) Убрал добавление самих реквизитов. Оставил только добавление элементов.
Все осталось как прежде — один реквизит добавляется, второй нет.
12 — 18.06.19 — 11:54
(7) (10) Вы были правы, добавление реквизитов само по себе излишне. Уберу это в коде.
Но проблема с выводом на форму так и не решена.
13 — 18.06.19 — 11:55
(8) Прикольно. Каков уровень абстракции: реквизит Номенклатура в ТЧ Товары !!!
(10) +1
(8) Проверь права, возможно на абстрактный добавленный тип их забыли установить. Вряд ли у тебя там добавлены абстрактные функциональные опции, но тоже проверь.
14 — 18.06.19 — 11:56
(13) Запускаю с полными правами.
15 — 18.06.19 — 11:58
(14) проверь ещё раз ПутьКДанным. Хотя при ошибке по идее исключение должно выдаваться
16 — 18.06.19 — 12:00
Ещё имена переменных поменяй, вместо
Номенклатура = Форма.Элементы.Добавить(«Номенклатура», Тип(«ПолеФормы»), Форма.Элементы.Товары);
делай
НовыйЭлементФормы = Форма.Элементы.Добавить(«Номенклатура», Тип(«ПолеФормы»), Форма.Элементы.Товары);
17 — 18.06.19 — 12:02
(16) Имена переменных в базе итак другие (Элемент_ИмяЭлемента)
Путь к данным правильный.
В последней строке события «При открытии» по прежнему в «Объект.Товары» есть оба нужных реквизита. А в итоге почему-то только один.
18 — 18.06.19 — 12:03
(17) Не в базе, а в моем коде.
19 — 18.06.19 — 12:05
(17) В Объект.Товары они независимо от твоего кода — из метаданных расширения.
Смотри Форма.Элементы.ИмяТвоегоАбстактногоРеквизита: видимость, доступность…
20 — 18.06.19 — 12:12
ставлю на функциональную опцию
21 — 18.06.19 — 12:20
(19) Сверил.
Все строчки у обоих реквизитов идентичны.
22 — 18.06.19 — 12:25
добавить в конфигураторе, рулить видимостью — не вариант?
23 — 18.06.19 — 12:26
(22) Вы имеете ввиду добавить в конфигураторе на форме не кодом? Не вариант так.
24 — 18.06.19 — 12:29
(23) как пожелаешь
25 — 18.06.19 — 12:31
Вообще-то непонятно. Если реквизиты изначально есть, то почему изначально нет элементов формы для этих реквизитов? Они тоже тогда наверное должны быть. Может они тоже на самом деле уже есть, а их потом где-то дальше в коде скрывают(убирают видимость)?
26 — 18.06.19 — 12:31
(24) Ну это не мое желание. Задание такое.
27 — 18.06.19 — 12:32
(25) Потому что реквизиты добавлены мной вручную. А формы типовые.
28 — 18.06.19 — 12:32
(10) должно работать
29 — 18.06.19 — 12:32
Может просмотреть код на наличие действий с элементами формы?
30 — 18.06.19 — 12:34
(27) А тоесть ты реквизиты в расширении добавил?
31 — 18.06.19 — 13:20
(30) Нет, сами реквизиты добавлены в конфигурации основной. А общий модуль, в котором приведенный код написан, находится в расширении. (29) Что имеется ввиду?
32 — 18.06.19 — 13:24
(31) Озвучь уже тип проблемного реквизита, конфигурацию и вид типового документа. В твоей абстракции возможно совершено другие проблемы и ошибки чем в реальности.
33 — 18.06.19 — 13:26
(32) Комплексная автоматизация 2 (2.4.7.109)
Документ «Коммерческое предложение клиенту».
В табличную часть не добавляется реквизит «Направление» (СправочникСсылка.НаправленияДеятельности)
34 — 18.06.19 — 13:31
(33) Возможно Справочник.НаправленияДеятельности выключен фукнциональными опциями
35 — 18.06.19 — 13:32
(34) Если добавлять просто на форму руками, все добавляется.
Как можно проверить выключен или нет?
36 — 18.06.19 — 14:49
(0) КА — типовая.Пустая.Включена ФО по КП. В модуле формы расширения.В процедуре при создании на сервере.
НовыйЭлементФормы = Элементы.Добавить(«Товары_НаправлениеДеятельности», Тип(«ПолеФормы»), Элементы.Товары);
НовыйЭлементФормы.ПутьКДанным = «Объект.Товары._НаправлениеДеятельности»;
НовыйЭлементФормы.Вид = ВидПоляФормы.ПолеВвода;
В КП добавлен в ТЧ товары новый реквизит «_НаправлениеДеятельности».
37 — 18.06.19 — 15:03
(35) Настройки фин реза и контролинг. раздел финансовый результат. галочка финансовый результат по направлениям деятельности. константа ФормироватьФинансовыйРезультат
НачинающийВ1С
38 — 18.06.19 — 15:21
(37) Спасибо! Это решило вопрос.
Я уже писал об общем принципе программного добавления элементов на управляемую форму, теперь напишу конкретно о том, как добавить колонку табличной части или таблицы значений.
Итак, у нас есть справочник «Тест» с табличной частью «Тест», в табличной части присутствуют реквизиты «Тест1» и «Тест2», а нам нужно добавить еще один реквизит — «Тест3» и показать его на форме.
Выглядит это приблизительно так:
|
&НаСервере Процедура ДобавитьКолонкуНаСервере() нРеквизиты = Новый Массив; нРеквизиты.Добавить(Новый РеквизитФормы(«Тест3», Новый ОписаниеТипов(«Строка»), «Объект.Тест», «Тест3», Истина)); ИзменитьРеквизиты(нРеквизиты); нЭлемент = Элементы.Добавить(«Тест3», Тип(«ПолеФормы»), Элементы.Тест); нЭлемент.Вид = ВидПоляФормы.ПолеВвода; нЭлемент.ПутьКДанным = «Объект.Тест.Тест3»; КонецПроцедуры |
Не думаю, что приведенный код нуждается в комментариях, но на всякий случай скажу, что первые три строки создают новый реквизит типа «Строка» — тут важно указать путь к создаваемому реквизиту — третий параметр.
Точно также можно добавить колонку любой таблице значений (не табличной части) — в этом случае нужно убрать часть «Объект.» из кода.
Следующие три строки добавляют саму колонку на форму.
На этом все, надеюсь данная статья Вам помогла.
Если Вы нашли ошибку или неточность, пожалуйста, выделите фрагмент текста и нажмите Ctrl+Enter.
Загрузка…
Содержание[Убрать]
-
- Как программно добавить Группу на форму?
- Как программно добавить Поле ввода на форму?
- Как программно добавить колонку в ТЧ?
- Как программно вывести табличную часть документа на управляемую форму?
- Как Добавить программно флажок на форму?
- Как установить событие для программно созданного элемента?
В чем удобство использования программного создания элементов формы:
- более удобно находить изменения между конфигурациями
- Изменять форму «на лету» в процессе работы
- Минимизировать изменения типовой конфигурации (в некоторых конфигурациях для этого созданы Переопределяемые модули/процедуры)
Рассмотрим наиболее частые вопросы, все действия показаны здесь проводятся в форме в процедуре ПриСозданииНаСервере
Как программно добавить Группу на форму?
ГруппаТовары = Элементы.Добавить("ГруппаТовары", Тип("ГруппаФормы"),Элементы); // Добавляет группу на форму
ГруппаТовары.Заголовок = "Товары на продажу";Как программно добавить Поле ввода на форму?
НовыйРеквизит = Элементы.Добавить("КонтрагентПоставщик", Тип("ПолеФормы"), ГруппаТовары);
НовыйРеквизит.Заголовок = "Контрагент поставщик";
НовыйРеквизит.Вид = ВидПоляФормы.ПолеВвода;
НовыйРеквизит.ПутьКДанным = "Объект.КонтрагентПоставщик";Как программно добавить колонку в ТЧ?
ТаблицаТовары = Элементы.Товары;
НовыйРеквизит = Элементы.Добавить("Вес", Тип("ПолеФормы"), ТаблицаТовары);
НовыйРеквизит.Заголовок = "Вес";
НовыйРеквизит.Вид = ВидПоляФормы.ПолеВвода;
НовыйРеквизит.ПутьКДанным = "Объект.Товары.Вес";Как программно вывести табличную часть документа на управляемую форму?
ГруппаТовары = Элементы.ГруппаТовары;
ТаблицаТовары = Элементы.Добавить("ТаблицаТовары", Тип("ТаблицаФормы"),ГруппаТовары;
ТаблицаТовары.ПутьКДанным = "Объект.Товары";
// для создания колонок в созданной таблице используется метод описанный выше "Как программно добавить колонку в ТЧ"Как Добавить программно флажок на форму?
НовыйРеквизит = ЭлементыФормы.Добавить("ЭтоИностранныйПоставщик", Тип("ПолеФормы"), ГруппаТовары);
НовыйРеквизит.Заголовок = "Это иностранный поставщик";
НовыйРеквизит.Вид = ВидПоляФормы.ПолеФлажка;
НовыйРеквизит.ПутьКДанным = "Объект.ЭтоИностранныйПоставщик"; Как установить событие для программно созданного элемента?
НовыйРеквизит = ЭлементыФормы.Добавить("ЭтоИностранныйПоставщик", Тип("ПолеФормы"), ГруппаТовары);
НовыйРеквизит.Заголовок = "Это иностранный поставщик";
НовыйРеквизит.Вид = ВидПоляФормы.ПолеФлажка;
НовыйРеквизит.ПутьКДанным = "Объект.ЭтоИностранныйПоставщик";
НовыйРеквизит.УстановитьДействие("ПриИзменении", "ЭтоИностранныйПоставщикПриИзменении"); // ЭтоИностранныйПоставщикПриИзменении - это название процедуры которая находится в модуле формы
Недостаточно прав для комментирования
Файлы материала
Описание
Новый реквизит на форму, можно добавить программно через расширение, при этом не забирать саму форму в расширение (это удобно тем, что последующие обновления внешнего вида формы не смогут сломать наше расширение). В типовых конфигурациях, данный способ можно реализовывать в процедуре “ПриСозданииНаСервере” общего модуля “УправлениеСвойствами” .
Программное добавление реквизита на форму
Для примера, стоит задача в конфигурации ЗУП 3.1 добавить реквизит «Способ отражения зарплаты в БУ» для позиции штатного расписания в группе “Дополнительные данные”.
Создадим расширение и выполним следующую последовательность действий:
- Добавим в расширение справочник “Штатное расписание” и создадим реквизит “АВ_СпособОтражения” с типом данных “СправочникСсылка.СпособыОтраженияЗарплатыВБухУчете”
2. Заберем в расширение процедуру “ПриСозданииНаСервере” из общего модуля “УправлениеСвойствами”, программно добавим поле в форму и свяжем его с реквизитом объекта добавленного на первом шаге.
|
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 |
&После(«ПриСозданииНаСервере») Процедура АВ_ПриСозданииНаСервере(Форма, ДополнительныеПараметры) Если Форма.ИмяФормы = «Справочник.ШтатноеРасписание.Форма.ФормаЭлемента» Тогда #Область ДобавлениеЭлементовФормы ИмяГруппы = «ГруппаДополнительныеРеквизиты»; ГруппаФормы = Форма.Элементы.Найти(ИмяГруппы); Если ГруппаФормы <> Неопределено Тогда ИмяЭлемента = «АВ_СпособОтражения»; Если Форма.Элементы.Найти(ИмяЭлемента) = Неопределено Тогда ЭлементФормы = Форма.Элементы.Добавить(ИмяЭлемента, Тип(«ПолеФормы»), ГруппаФормы); //Вместо Добавить() можно использовать метод Вставить() //в 4-й параметре указывается Элемент перед которым должен быть вставлен новый элемент. //ЭлементФормы = Форма.Элементы.Вставить(ИмяЭлемента, Тип(«ПолеФормы»), ГруппаФормы, Форма.Элементы.Найти(«ИмяСледующегоЭлементаФормы»)); ЭлементФормы.Вид = ВидПоляФормы.ПолеВвода; ЭлементФормы.ПутьКДанным = «Объект.АВ_СпособОтражения»; //ЭлементФормы.МногострочныйРежим = Истина; //ЭлементФормы.Высота = 3; КонецЕсли; КонецЕсли; #КонецОбласти КонецЕсли; КонецПроцедуры |
Образец расширения для скачивания в начале описания.
Программное добавление реквизита в табличную часть формы
Например, таким же способом, добавим в табличную часть “Рабочие места” реквизит “Спецжиры” с типом “Булево”.
|
&После(«ПриСозданииНаСервере») Процедура АВ_ПриСозданииНаСервере(Форма, ДополнительныеПараметры) Если Форма.ИмяФормы = «Документ.РезультатыСпецоценкиУсловийТруда.Форма.ФормаДокумента» Тогда #Область ДобавлениеЭлементовФормы ИмяЭлемента = «АВ_ЕстьСпецжиры»; Если Форма.Элементы.Найти(ИмяЭлемента) = Неопределено Тогда ЭлементФормы = Форма.Элементы.Добавить(«Спецжиры», Тип(«ПолеФормы»), Форма.Элементы.РабочиеМеста); ЭлементФормы.Вид = ВидПоляФормы.ПолеФлажка; ЭлементФормы.ПутьКДанным = «Объект.РабочиеМеста.АВ_ЕстьСпецжиры»; //ЭлементФормы.ТолькоПросмотр = Истина; КонецЕсли; #КонецОбласти КонецЕсли; КонецПроцедуры |
В результате получим табличную часть с новой колонкой.
Программное добавление табличной части на форму
Аналогично добавим табличную часть “АВ_ВредныеФакторы” на форму справочника “Профессии”.
|
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 |
&После(«ПриСозданииНаСервере») Процедура АВ_ПриСозданииНаСервере(Форма, ДополнительныеПараметры) Если Форма.ИмяФормы = «Справочник.ПрофессииРабочих.Форма.ФормаЭлемента» Тогда #Область ДобавлениеЭлементовФормы ИмяГруппы = «ГруппаДополнительныеРеквизиты»; ГруппаФормы = Форма.Элементы.Найти(ИмяГруппы); Если ГруппаФормы <> Неопределено Тогда ИмяЭлемента = «АВ_ВредныеФакторы»; Если Форма.Элементы.Найти(ИмяЭлемента) = Неопределено Тогда ЭлементФормыТаблица = Форма.Элементы.Добавить(ИмяЭлемента, Тип(«ТаблицаФормы»), ГруппаФормы); ЭлементФормыТаблица.ПутьКДанным = «Объект.АВ_ВредныеФакторы»; ЭлементФормы = Форма.Элементы.Добавить(«ВредныйФактор», Тип(«ПолеФормы»), ЭлементФормыТаблица); ЭлементФормы.Вид = ВидПоляФормы.ПолеВвода; ЭлементФормы.ПутьКДанным = «Объект.АВ_ВредныеФакторы.ВредныйФактор»; КонецЕсли; КонецЕсли; #КонецОбласти КонецЕсли; КонецПроцедуры |
Связь реквизитов формы с элементами формы
Кроме того, реквизиты формы можно создавать программно и связывать их с элементами формы
|
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 |
#Область ДобавлениеРеквизитовФормы // Массив для новых реквизитов ДобавляемыеРеквизиты = Новый Массив; // Опишем ревизиты формы Реквизит_РабочееМесто = Новый РеквизитФормы(«АВ_РабочееМесто», Новый ОписаниеТипов(«СправочникСсылка.РабочиеМестаОхраныТруда»), , «Рабочее место»); // Заполним массив после описания реквизитов формы ДобавляемыеРеквизиты.Добавить(Реквизит_РабочееМесто); // Добавим новые реквизиты в форму Форма.ИзменитьРеквизиты(ДобавляемыеРеквизиты); #КонецОбласти #Область ДобавлениеЭлементовФормы ... #КонецОбласти #Область ЗаполнениеДанных Форма.АВ_РабочееМесто = Форма.Объект.АВ_РабочееМесто; #КонецОбласти |
Расширения, Типовые приемы, Шаблоны и заготовки
Программное добавление элементов на формы является очень удобным подходом при доработке типовых конфигураций. Это позволяет минимизировать коллизии и ошибки при объединении форм, использовать при обновлениях трехсторнонее сравнение кода при помощи внешних программ, например KDiff3, переиспользовать однажды написанный код в других доработках.
Содержание
В качестве примера будем использовать пустую обработку, в которой есть реквизит НашНужныйРеквизит. Все манипуляции по добавлению, удалению элементов и реквизитов формы производятся на сервере, и можно использовать как предопределенные обработчики, например &ПриСозданииНаСервере, так и любые другие методы с директивой &НаСервере. В нашем примере будем все элементы добавлять при помощи отдельных команд, для большей наглядности.
Как в 1С программно добавить элемент формы?
Вывести существующий реквизит
&НаСервере Процедура ДобавитьПолеВводаНаСервере() // Проверка нужна, чтобы избежать ошибки при попытке создания элемента с одним и тем же именем несколько раз Если Элементы.Найти("НашНужныйЭлемент") = Неопределено Тогда // Вначале просто добавляем элемент в коллекцию Элементы НовыйЭлемент = Элементы.Добавить("НашНужныйЭлемент", Тип("ПолеФормы")); //Затем донастраиваем его и указываем нужные свойства НовыйЭлемент.ПутьКДанным = "Объект.НашНужныйРеквизит"; НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода; НовыйЭлемент.Заголовок = "Программно добавленное поле ввода"; КонецЕсли; КонецПроцедуры &НаКлиенте Процедура ДобавитьПолеВвода(Команда) ДобавитьПолеВводаНаСервере(); КонецПроцедуры
Создать новый реквизит формы
&НаСервере Процедура ДобавитьРеквизитФлажокНаСервере() Если Элементы.Найти("НужныйФлажок") = Неопределено Тогда НовыеРеквизиты = Новый Массив; //Обратите внимание, типизация реквизитов использует именно Описание типов, а не отдельный тип. ТипРеквизита = Новый ОписаниеТипов("Булево"); РеквизитФлажок = Новый РеквизитФормы("НужныйФлажок", ТипРеквизита, "", "Нужный флажок"); НовыеРеквизиты.Добавить(РеквизитФлажок); ИзменитьРеквизиты(НовыеРеквизиты); НовыйЭлемент = Элементы.Добавить("НужныйФлажок", Тип("ПолеФормы")); НовыйЭлемент.ПутьКДанным = "НужныйФлажок"; НовыйЭлемент.Вид = ВидПоляФормы.ПолеФлажка; КонецЕсли; КонецПроцедуры &НаКлиенте Процедура ДобавитьРеквизитФлажок(Команда) ДобавитьРеквизитФлажокНаСервере(); КонецПроцедуры
Вставить элемент формы в нужное место
&НаСервере Процедура ВставитьКартинкуПередФлажкомНаСервере() Если Элементы.Найти("ВставленнаяКартинка") = Неопределено Тогда СледующийЭлемент = Элементы.Найти("НужныйФлажок"); // Если флажок найден - вставим элемент перед ним, если нет - добавим в конец // Заодно рассмотрим как добавить программно декорацию-картинку на форму ЭлементКартинка = Элементы.Вставить("ВставленнаяКартинка", Тип("ДекорацияФормы"),,СледующийЭлемент); ЭлементКартинка.Вид = ВидДекорацииФормы.Картинка; // Обратите внимание, картинка в этом случае может быть либо Пустая, либо ИзБиблиотеки ЭлементКартинка.Картинка = БиблиотекаКартинок.Реквизит; КонецЕсли; КонецПроцедуры &НаКлиенте Процедура ВставитьКартинкуПередФлажком(Команда) ВставитьКартинкуПередФлажкомНаСервере(); КонецПроцедуры
Как программно добавить команду в управляемую форму?
&НаСервере Процедура ДобавитьПрограммноКомандуНаСервере() Если Элементы.Найти("КнопкаПредупредить") = Неопределено Тогда //Добавим команду в коллекцию команд КомандаПредупредить = Команды.Добавить("Предупредить"); КомандаПредупредить.Заголовок = "Предупредить!"; КомандаПредупредить.Действие = "КомандаПредупредить"; КнопкаКоманды = Элементы.Добавить("КнопкаПредупредить", Тип("КнопкаФормы")); КнопкаКоманды.ИмяКоманды = "Предупредить"; // Если помещаем просто на форму, то вид - обычная кнопка // Если укажем контейнер с типом Командная панель, то вид - КнопкаКоманднойПанели КнопкаКоманды.Вид = ВидКнопкиФормы.ОбычнаяКнопка; КонецЕсли; КонецПроцедуры &НаКлиенте Процедура ДобавитьПрограммноКоманду(Команда) ДобавитьПрограммноКомандуНаСервере(); КонецПроцедуры &НаКлиенте Процедура КомандаПредупредить(Команда) ПоказатьПредупреждение(, "А ведь я предупреждал!"); КонецПроцедуры
Как добавить таблицу на форму программно?
На программном добавлении таблицы на форму стоит остановиться отдельно. Порядок действий следующий:
Сперва создаем основной реквизит – саму таблицу формы. Далее – создаем подчиненные реквизиты-колонки. В простейшем случае колонки можно создать, перебрав колонки таблицы значений – источника. Далее следует создать связанные с только что созданными реквизитами элементы формы – также сперва основной элемент – таблицу, а затем подчиненные элементы – колонки.
&НаСервере Процедура СоздатьТаблицуЗначенийНаСервере() Если Элементы.Найти("ДинамическаяТаблицаЭлемент") <> Неопределено Тогда Возврат; КонецЕсли; НовыеРеквизиты = Новый Массив; ТипРеквизита = Новый ОписаниеТипов("ТаблицаЗначений"); РеквизитТЗ = Новый РеквизитФормы("ДинамическаяТаблица", ТипРеквизита, "", "Динамическая таблица"); НовыеРеквизиты.Добавить(РеквизитТЗ); ТЗ = Новый ТаблицаЗначений; ТЗ.Колонки.Добавить("Отметка", Новый ОписаниеТипов("Булево")); ТЗ.Колонки.Добавить("Дата", Новый ОписаниеТипов("Дата")); ТЗ.Колонки.Добавить("Комментарий", Новый ОписаниеТипов("Строка")); Для Каждого КолонкаТаблицы Из ТЗ.Колонки Цикл НовыеРеквизиты.Добавить(Новый РеквизитФормы(КолонкаТаблицы.Имя, КолонкаТаблицы.ТипЗначения, "ДинамическаяТаблица")); КонецЦикла; ИзменитьРеквизиты(НовыеРеквизиты); ЭлементТаблица = Элементы.Добавить("ДинамическаяТаблицаЭлемент", Тип("ТаблицаФормы")); ЭлементТаблица.ПутьКДанным = "ДинамическаяТаблица"; ЭлементТаблица.Отображение = ОтображениеТаблицы.Список; Для Каждого КолонкаТаблицы Из ТЗ.Колонки Цикл ЭлементКолонкаТаблицы = Элементы.Добавить(КолонкаТаблицы.Имя, Тип("ПолеФормы"), ЭлементТаблица); Если КолонкаТаблицы.ТипЗначения.СодержитТип(Тип("Булево")) Тогда ЭлементКолонкаТаблицы.Вид = ВидПоляФормы.ПолеФлажка; Иначе ЭлементКолонкаТаблицы.Вид = ВидПоляФормы.ПолеВвода; КонецЕсли; ЭлементКолонкаТаблицы.ПутьКДанным = "ДинамическаяТаблица." + КолонкаТаблицы.Имя; КонецЦикла; КонецПроцедуры &НаКлиенте Процедура СоздатьТаблицуЗначений(Команда) СоздатьТаблицуЗначенийНаСервере(); КонецПроцедуры
Как программно установить обработчик события элемента формы?
&НаСервере Процедура ДобавитьОбработчикДействияНаСервере() // Если таблицу еще не создали, ничего не делаем Если Элементы.Найти("ДинамическаяТаблицаЭлемент") = Неопределено Тогда Возврат; КонецЕсли; Элементы.ДинамическаяТаблицаЭлемент.УстановитьДействие("ПриИзменении", "ПриИзмененииТаблицы"); КонецПроцедуры &НаКлиенте Процедура ДобавитьОбработчикДействия(Команда) ДобавитьОбработчикДействияНаСервере(); КонецПроцедуры // Количество и порядок параметров метода-обработчика должны соответствовать событию // Подробнее см. синтакс-помощник &НаКлиенте Процедура ПриИзмененииТаблицы(Элемент) Сообщить("Изменили колонку " + Элемент.ТекущийЭлемент.Имя); КонецПроцедуры
В данной статье описаны примеры программного создания объектов управляемой формы 1С — таблицы значений и динамического списка, и их программный вывод в элементы формы
Contents
- 1 Введение в управляемые формы 1С
- 2 Создание реквизита типа таблица значений и вывод на форму
- 3 Добавление условного оформления таблицы формы
- 4 Создание реквизита типа динамический список с заданными настройками и вывод на форму
- 5 Вывести динамический список в элементы управляемой формы 1С
- 6 Обновление параметров динамического списка программно
- 7 Полезные ссылки
Перед прочтением данной статьи рекомендуется ознакомиться с первой частью, в которой описаны примеры программного создания элементов, команд, реквизитов управляемой формы, а также описание стандартных возможностей для работы с ними.
В данной же части будет рассмотрено программное создание динамических списков, таблиц значений на форме, их вывод в элементы формы и стандартные возможности для работы.
Модифицировать формы рекомендуется программно для удобного обновления конфигураций и исключения конфликтов, а также для удобной поддержки кода. Со статьями о механизмах модификации можно ознакомиться в разделе полезных ссылок.
Также все описанные в текущем разделе процедуры и функции находятся во внешней обработке УпрФормы.
Примеры программного создания элементов, команд, реквизитов управляемой формы, а также описание стандартных возможностей для работы с ними можно будет посмотреть в части 1.
Для запуска обработки в режиме предприятия необходимо наличие объектов «Справочники.Номенклатура», подчиненный ему «Справочники.ХарактеристикиНоменклатуры» и «РегистрыСведений.ЦеныНоменклатуры”.
Создание реквизита типа таблица значений и вывод на форму
&НаСервере
Процедура пр_СоздатьТаблицуЗначений()
МассивДобавляемыхРеквизитов = Новый Массив;
//добавить реквизит ТЗ
МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("пр_ТаблицаЗначений", Новый ОписаниеТипов("ТаблицаЗначений")));
//добавить каждую колонку как отдельный реквизит
МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Период", Новый ОписаниеТипов("Дата",,,,,Новый КвалификаторыДаты(ЧастиДаты.Дата)),"пр_ТаблицаЗначений" ,"Период"));
МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Номенклатура", Новый ОписаниеТипов("СправочникСсылка.Номенклатура"),"пр_ТаблицаЗначений" ,"Номенклатура"));
МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Характеристика", Новый ОписаниеТипов("СправочникСсылка.ХарактеристикиНоменклатуры"),"пр_ТаблицаЗначений" ,"Характеристика"));
МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("ВидЦены", Новый ОписаниеТипов("СправочникСсылка.ВидыЦен"),"пр_ТаблицаЗначений" ,"Вид цены"));
МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Цена", Новый ОписаниеТипов("Число", ,,Новый КвалификаторыЧисла(15,2)), "пр_ТаблицаЗначений" ,"Цена"));
ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);
КонецПроцедуры
&НаСервере
Процедура пр_ВывестиТаблицуЗначений()
пр_ВывестиТаблицуНаФорму(ЭтаФорма, "пр_ТаблицаЗначений", Элементы["пр_Страница2"], "Таблица цен");
КонецПроцедуры
&НаСервере
Процедура пр_ВывестиТаблицуНаФорму(Форма, ИмяТаблицы, Родитель, ЗаголовокТаблицы) Экспорт
ТаблицаФормы = Форма.Элементы.Добавить(ИмяТаблицы, Тип("ТаблицаФормы"), Родитель);
ТаблицаФормы.ПутьКДанным = ИмяТаблицы;
ТаблицаФормы.Заголовок = ЗаголовокТаблицы;
ТаблицаФормы.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Верх;
ТаблицаФормы.ИзменятьПорядокСтрок = Ложь;
ТаблицаФормы.ИзменятьСоставСтрок = Ложь;
ТаблицаФормы.РазрешитьНачалоПеретаскивания = Ложь;
СтруктураСвойств = Новый Структура();
пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, "Период");
пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, "Номенклатура");
пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, "Характеристика");
пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, "ВидЦены");
пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, "Цена", СтруктураСвойств);
КонецПроцедуры
&НаСервере
Процедура пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, ИмяКолонки, СтруктураСвойств = Неопределено)
НоваяКолонка = Форма.Элементы.Добавить(ИмяТаблицы+ИмяКолонки, Тип("ПолеФормы"), ТаблицаФормы);
НоваяКолонка.Заголовок = ИмяКолонки;
НоваяКолонка.ПутьКДанным = ИмяТаблицы + "." + ИмяКолонки;
НоваяКолонка.Вид = ВидПоляФормы.ПолеВвода;
Если НЕ СтруктураСвойств = Неопределено Тогда
Для Каждого КлючЗначение Из СтруктураСвойств Цикл
Попытка
НоваяКолонка[КлючЗначение.Ключ] = СтруктураСвойств[КлючЗначение.Ключ];
Исключение
КонецПопытки;
КонецЦикла;
КонецЕсли;
КонецПроцедуры
Добавление условного оформления таблицы формы
Создаем условное оформление для таблицы:
- если реквизит формы Использование (тип булево) = Истина, тогда разрешаем изменять цену в строках таб. части;
- если в строке таб части цена не заполнена, то выделять фон ячейки «Цена» розовым.
&НаСервере
Процедура пр_ДобавитьУОТаблицыФормы()
//условное оформление формы
//если реквизит Использование = Истина, то разрешать изменять цену
ЭлементОформления = УсловноеОформление.Элементы.Добавить();
// Создаем условие отбора в созданной группе:
ЭлементОтбора = ЭлементОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("пр_Использование"); // имя поля
ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно; // либо задаем свой
ЭлементОтбора.ПравоеЗначение = Ложь;
ЭлементОтбора.Использование = Истина;
// Установка значения элемента УО
ЭлементОформления.Оформление.УстановитьЗначениеПараметра("Доступность", Ложь);
ЭлементОформления.Использование = Истина;
ЭлементОформления.Оформление.УстановитьЗначениеПараметра("ЦветТекста", WebЦвета.КрасноФиолетовый);
ЭлементОформления.Использование = Истина;
// Создаем поля оформления
ПолеОформления = ЭлементОформления.Поля.Элементы.Добавить();
//чтобы выделить ячейку, нужно указать имя соответствующего элемента на форме
ПолеОформления.Поле = Новый ПолеКомпоновкиДанных("пр_ТаблицаЗначенийЦена");
ПолеОформления.Использование = Истина;
//условное оформление формы
//если в строке цена = 0, тогда строку закрашиваем розовым
ЭлементОформления = УсловноеОформление.Элементы.Добавить();
// Создаем условие отбора в созданной группе:
ЭлементОтбора = ЭлементОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("пр_ТаблицаЗначений.Цена"); // имя поля
ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.НеЗаполнено; // либо задаем свой
ЭлементОтбора.Использование = Истина;
// Установка значения элемента УО
ЭлементОформления.Оформление.УстановитьЗначениеПараметра("ЦветФона", WebЦвета.Розовый);
ЭлементОформления.Использование = Истина;
// Создаем поля оформления
//чтобы выделить всю строку, нужно добавить все ячейки строки, пока же выделим одну ячейку "Цена"
ПолеОформления = ЭлементОформления.Поля.Элементы.Добавить();
ПолеОформления.Поле = Новый ПолеКомпоновкиДанных("пр_ТаблицаЗначенийЦена");
ПолеОформления.Использование = Истина;
КонецПроцедуры
В процедуру команды добавим вызов серверной процедуры для заполнения таблицы цен в зависимости от выбранной номенклатуры и характеристики:
&НаКлиенте
Процедура пр_Команда1(Команда)
пр_Команда1НаСервере();
КонецПроцедуры
&НаСервере
Процедура пр_Команда1НаСервере()
ЭтаФорма["пр_ТаблицаЗначений"].Очистить();
Запрос = Новый Запрос;
Запрос.УстановитьПараметр("Номенклатура", ЭтаФорма.пр_Номенклатура);
Запрос.УстановитьПараметр("Характеристика", ЭтаФорма.пр_Характеристика);
Запрос.Текст = "ВЫБРАТЬ
| ЦеныНоменклатурыСрезПоследних.Период КАК Период,
| ЦеныНоменклатурыСрезПоследних.Номенклатура КАК Номенклатура,
| ЦеныНоменклатурыСрезПоследних.Характеристика КАК Характеристика,
| ЦеныНоменклатурыСрезПоследних.ВидЦены КАК ВидЦены,
| ЦеныНоменклатурыСрезПоследних.Цена КАК Цена
|ИЗ
| РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
| ,
| Номенклатура = &Номенклатура
| И Характеристика = &Характеристика) КАК ЦеныНоменклатурыСрезПоследних";
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
Стр = ЭтаФорма["пр_ТаблицаЗначений"].Добавить();
ЗаполнитьЗначенияСвойств(Стр, Выборка);
КонецЦикла;
КонецПроцедуры
Добавляем в процедуру ПриСозданииНаСервере процедуры:
&НаСервере Процедура пр_ПриСозданииНаСервере(Отказ, СтандартнаяОбработка) //установим заголовок формы ЭтаФорма.Заголовок = "Шаблон для программной работы с реквизитами, командами и элементами формы"; ЭтаФорма.АвтоЗаголовок = Ложь; пр_СоздатьГруппы(); пр_СоздатьНовуюКоманду(); пр_СоздатьДекорацию(); пр_СоздатьРеквизиты(); пр_УдалитьРеквизиты(); пр_ВывестиРеквизитыНаФорму(); пр_СоздатьТаблицуЗначений(); пр_ВывестиТаблицуЗначений(); пр_ДобавитьУОТаблицыФормы(); КонецПроцедуры
Заполняем реквизиты Номенклатура, Характеристика и заполняем цены в таблице значений.
Создание реквизита типа динамический список с заданными настройками и вывод на форму
На странице 3 создадим динамический список с выводом всех цен выбранной номенклатуры и характеристики.
Добавим Условное Оформление дин. списка, отбор и сортировку программно.
&НаСервере
Процедура пр_СоздатьДинамическийСписок()
//создать дин. список с произвольным запросом
ТекстЗапроса = "ВЫБРАТЬ
| ЦеныНоменклатуры.Период КАК Период,
| ЦеныНоменклатуры.Номенклатура КАК Номенклатура,
| ЦеныНоменклатуры.Характеристика КАК Характеристика,
| ЦеныНоменклатуры.ВидЦены КАК ВидЦены,
| ЦеныНоменклатуры.Цена КАК Цена,
| ЦеныНоменклатуры.Регистратор КАК Регистратор
|ИЗ
| РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
|ГДЕ
| ЦеныНоменклатуры.Номенклатура = &Номенклатура
| И ЦеныНоменклатуры.Характеристика = &Характеристика";
МассивДобавляемыхРеквизитов = Новый Массив;
//создать реквизит дин. списка
МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("пр_ДинамическийСписок", Новый ОписаниеТипов("ДинамическийСписок"),,,ЛОЖЬ));
ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);
РеквизитДинамическийСписок = ЭтаФорма["пр_ДинамическийСписок"];
//если запрос не произвольный, тогда используем следующий код:
//РеквизитДинамическийСписок.ПроизвольныйЗапрос = Ложь;
//РеквизитДинамическийСписок.ОсновнаяТаблица = "РегистрСведений.ЦеныНоменклатуры";
РеквизитДинамическийСписок.ПроизвольныйЗапрос = Истина;
РеквизитДинамическийСписок.ОсновнаяТаблица = "РегистрСведений.ЦеныНоменклатуры";
РеквизитДинамическийСписок.ТекстЗапроса = ТекстЗапроса;
РеквизитДинамическийСписок.Параметры.УстановитьЗначениеПараметра("Номенклатура", ЭтаФорма["пр_Номенклатура"]);
РеквизитДинамическийСписок.Параметры.УстановитьЗначениеПараметра("Характеристика", ЭтаФорма["пр_Характеристика"]);
//не будем выводить эту колонку в списке, но нужен к ней доступ всегда
РеквизитДинамическийСписок.УстановитьОбязательноеИспользование("Регистратор", Истина);
КонецПроцедуры
&НаСервере
Процедура пр_ДобавитьОтборДинамическийСписок()
ЭлементОтбора = ЭтаФорма["пр_ДинамическийСписок"].Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Период");
ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Больше; // больше или меньше и т.п.
ЭлементОтбора.Использование = Истина;
ЭлементОтбора.ПравоеЗначение = Дата('2015.01.01 00:00:00');
КонецПроцедуры
&НаСервере
Процедура пр_ДобавитьУОДинамическийСписок()
//если цена от 4000 до 5000, то выделять зеленым
ЭлементОформления = ЭтаФорма["пр_ДинамическийСписок"].УсловноеОформление.Элементы.Добавить();
//сначала добавим группу И
ГруппаОформления = ЭлементОформления.Отбор.Элементы.Добавить(Тип("ГруппаЭлементовОтбораКомпоновкиДанных"));
ГруппаОформления.Использование = Истина;
ГруппаОформления.ТипГруппы = ТипГруппыЭлементовОтбораКомпоновкиДанных.ГруппаИ;
// Создаем условие отбора в созданной группе: цена > 4000
ЭлементОтбора = ГруппаОформления.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Цена"); // имя поля
ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Больше; // либо задаем свой
ЭлементОтбора.ПравоеЗначение = 4000;
//правым значением может выступать ПолеКомпоновкиДанных формы или списка
//ЭлементОтбора.ПравоеЗначение = Новый ПолеКомпоновкиДанных(ИмяПоля);
ЭлементОтбора.Использование = Истина;
//второй элемент отбора: цена < 5000
ЭлементОтбора = ГруппаОформления.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
ЭлементОтбора.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Цена"); // имя поля
ЭлементОтбора.ВидСравнения = ВидСравненияКомпоновкиДанных.Меньше; // либо задаем свой
ЭлементОтбора.ПравоеЗначение = 5000;
ЭлементОтбора.Использование = Истина;
// Установка значения элемента УО
ЭлементОформления.Оформление.УстановитьЗначениеПараметра("ЦветФона", WebЦвета.ЗеленыйЛес);
// Возможно обращение как по индексу так и установка через метод
//Элемент = ЭлементОформления.Оформление.Элементы[0];
//Элемент.Значение = Цвет;
ЭлементОформления.Использование = Истина;
// Создаем поля оформления
ПолеОформления = ЭлементОформления.Поля.Элементы.Добавить();
//чтобы выделить ячейку, нуджно указать ее имя поля
ПолеОформления.Поле = Новый ПолеКомпоновкиДанных("Период");
ПолеОформления = ЭлементОформления.Поля.Элементы.Добавить();
ПолеОформления.Поле = Новый ПолеКомпоновкиДанных("Номенклатура");
ПолеОформления = ЭлементОформления.Поля.Элементы.Добавить();
ПолеОформления.Поле = Новый ПолеКомпоновкиДанных("Характеристика");
ПолеОформления = ЭлементОформления.Поля.Элементы.Добавить();
ПолеОформления.Поле = Новый ПолеКомпоновкиДанных("ВидЦены");
ПолеОформления = ЭлементОформления.Поля.Элементы.Добавить();
ПолеОформления.Поле = Новый ПолеКомпоновкиДанных("Цена");
ПолеОформления.Использование = Истина;
КонецПроцедуры
&НаСервере
Процедура пр_ДобавитьСортировкуДинамическийСписок()
ЭлементСортировки = ЭтаФорма["пр_ДинамическийСписок"].Порядок.Элементы.Добавить(Тип("ЭлементПорядкаКомпоновкиДанных"));
ЭлементСортировки.Поле = Новый ПолеКомпоновкиДанных("Период");
ЭлементСортировки.ТипУпорядочивания = НаправлениеСортировкиКомпоновкиДанных.Убыв;
ЭлементСортировки.Использование = Истина;
КонецПроцедуры
Вывести динамический список в элементы управляемой формы 1С
Для вывода дин. списка воспользуемся процедурами, которые использовали при выводе таблицы значений, так как это один тип — ДанныеФормыКоллекция.
&НаСервере
Процедура пр_ВывестиДинамическийСписок()
пр_ВывестиДинамическийСписокНаФорму(ЭтаФорма, "пр_ДинамическийСписок", Элементы["пр_Страница3"], "Таблица цен");
КонецПроцедуры
Процедура пр_ВывестиДинамическийСписокНаФорму(Форма, ИмяТаблицы, Родитель, ЗаголовокТаблицы) Экспорт
ТаблицаФормы = Форма.Элементы.Добавить(ИмяТаблицы, Тип("ТаблицаФормы"), Родитель);
ТаблицаФормы.ПутьКДанным = ИмяТаблицы;
ТаблицаФормы.Заголовок = ЗаголовокТаблицы;
ТаблицаФормы.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Верх;
СтруктураСвойств = Новый Структура("Вид", ВидПоляФормы.ПолеНадписи); //если нужны какие-то специфические свойства колонки, то нужно их добавить в структуру свойств
пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, "Период", СтруктураСвойств);
пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, "Номенклатура", СтруктураСвойств);
пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, "Характеристика", СтруктураСвойств);
пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, "ВидЦены", СтруктураСвойств);
пр_ДобавитьНовуюКолонку(Форма, ТаблицаФормы, ИмяТаблицы, "Цена", СтруктураСвойств);
КонецПроцедуры
Обновление параметров динамического списка программно
Если в запросе дин. списка используются параметры, то их необходимо обновлять при изменении соответствующих реквизитов.
&НаСервере
Процедура пр_ОбновитьПараметрДинСписков(ИмяЭлемента, ТекСсылка)
РеквизитДинамическийСписок = ЭтаФорма["пр_ДинамическийСписок"];
РеквизитДинамическийСписок.Параметры.УстановитьЗначениеПараметра(ИмяЭлемента, ТекСсылка);
КонецПроцедуры
&НаКлиенте
Процедура пр_НоменклатураПриИзменении(Элемент)
пр_ОбновитьПараметрДинСписков("Номенклатура", ЭтаФорма["пр_Номенклатура"]);
КонецПроцедуры
&НаКлиенте
Процедура пр_ХарактеристикаПриИзменении(Элемент)
пр_ОбновитьПараметрДинСписков("Характеристика", ЭтаФорма["пр_Характеристика"]);
КонецПроцедуры
Добавляем в процедуру ПриСозданииНаСервере процедуры:
&НаСервере Процедура пр_ПриСозданииНаСервере(Отказ, СтандартнаяОбработка) //установим заголовок формы ЭтаФорма.Заголовок = "Шаблон для программной работы с реквизитами, командами и элементами формы"; ЭтаФорма.АвтоЗаголовок = Ложь; пр_СоздатьГруппы(); пр_СоздатьНовуюКоманду(); пр_СоздатьДекорацию(); пр_СоздатьРеквизиты(); пр_УдалитьРеквизиты(); пр_ВывестиРеквизитыНаФорму(); пр_СоздатьДинамическийСписок(); пр_ДобавитьОтборДинамическийСписок(); пр_ДобавитьСортировкуДинамическийСписок(); пр_ДобавитьУОДинамическийСписок(); пр_ВывестиДинамическийСписок(); КонецПроцедуры
Заполняем реквизиты Номенклатура, Характеристика и заполняем цены в таблице значений.
Содержимое регистра сведений ЦеныНоменклатуры:
Динамический список на форме:
Полезные ссылки
1. Типовой механизм упрощенного изменения конфигурации в ERP 2.0 и УТ 11
2. Типовой функционал модификации конфигурации линейки ERP-решений (УТ 11, КА 2 и ERP 2)
3. 1С Управляемые Формы. Программное создание реквизитов , команд, элементов (Часть 1)