Программное добавление реквизитов управляемой формы 1с бсп

В данной статье описаны примеры программного создания объектов управляемой формы 1С : элементов, команд, реквизитов, а также описание стандартных возможностей для работы с ними.

Рекомендуется модифицировать управляемые формы типового решения 1С программно для удобного будущего обновления и исключения конфликтов, а также для удобной работы с изменениями и надежности при использовании механизма расширений.
В некоторых типовых конфигурациях 1С (ЕРП 2, УТ 11) используется механизм упрощенного изменения конфигурации. Статьи о типовом механизме можно найти в разделе полезных ссылок. Данный механизм используется в БСП, и его необходимо знать при модификации типовых конфигураций.
При добавлении элементов на форму программно можно отредактировать практически любое свойство из панель свойств, которое можно установить вручную в конфигураторе.
Также все описанные в текущем разделе процедуры и функции находятся во внешней обработке УпрФормы.

Примеры работы с объектом «ДанныеФормыКоллекция» и созданием дин. списка и таблицы значений программно можно будет посмотреть в части 2.

Для запуска обработки в режиме предприятия необходимо наличие объектов «Справочники.Номенклатура», подчиненный ему «Справочники.ХарактеристикиНоменклатуры» и «РегистрыСведений.ЦеныНоменклатуры”.

Программное переопределение обработчиков событий формы и элементов формы

Переопределить обработчики событий формы можно в обработчике «ПриСозданииНаСервере» (кроме самого обрабочика «ПриСозданииНаСервере») или в теле модуля формы в контексте сервера (например, Переопределение событий ПриЧтениинаСервере и ПриСозданииНаСервере).

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
    ЭтаФорма.УстановитьДействие(“ОбработкаВыбора”, “пр_ОбработкаВыбора”)
КонецПроцедуры

В теле модуля формы:

#Если Сервер Тогда
    ЭтаФорма.УстановитьДействие("ПриСозданииНаСервере", "пр_ПриСозданииНаСервере");
#КонецЕсли

А в новой процедуре нужно добавить вызов основной, если такая процедура есть.

&НаСервере
Процедура пр_ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
    ПриСозданииНаСервере(Отказ, СтандартнаяОбработка);
КонецПроцедуры

Аналогично можно поступить и с обработчиками элементов формы:

Элементы.Номенклатура.УстановитьДействие(“ПриИзменении”, “пр_НоменклатураПриИзменении”)

Программное создание групп формы.

&НаСервере
Процедура пр_СоздатьГруппы()
    
    ГруппаСтраницы =  Элементы.Добавить("пр_Страницы", Тип("ГруппаФормы"),ЭтаФорма);
    ГруппаСтраницы.Вид = ВидГруппыФормы.Страницы;
    
    НоваяСтраница = Элементы.Добавить("пр_Страница", Тип("ГруппаФормы"),ГруппаСтраницы);
    НоваяСтраница.Вид = ВидГруппыФормы.Страница;
    НоваяСтраница.Заголовок = "Страница 1";
    
    НоваяГруппа = Элементы.Добавить("пр_Группа1", Тип("ГруппаФормы"),НоваяСтраница);
    НоваяГруппа.Вид = ВидГруппыФормы.ОбычнаяГруппа;
    НоваяГруппа.Группировка = ГруппировкаПодчиненныхЭлементовФормы.ГоризонтальнаяЕслиВозможно;
    НоваяГруппа.Заголовок = "Группа 1";
    
КонецПроцедуры

Доступные виды групп формы:

Программное добавление команды на форму.

Удалить команду можно при помощи метода коллекции формы команд: Команды.Удалить(<Команда>). Удалять можно только те команды, которые были созданы программно.

&НаСервере
Процедура пр_СоздатьНовуюКоманду()
    
    //создать новую команду у формы
    НоваяКоманда    		 = Команды.Добавить("пр_Команда1");
    НоваяКоманда.Действие     = "пр_Команда1";
    НоваяКоманда.Картинка     = БиблиотекаКартинок.Облако;
    НоваяКоманда.Отображение = ОтображениеКнопки.Картинка;
    
    //вывести команду в элементы
    ЭлементКоманда    			 = Элементы.Добавить("пр_Команда1", Тип("КнопкаФормы"), Элементы.ФормаКоманднаяПанель);
    ЭлементКоманда.Заголовок     = "Вывести сообщение";
    ЭлементКоманда.ИмяКоманды     = "пр_Команда1";

    //удалить команду
    //Команды.Удалить(НоваяКоманда);
    
КонецПроцедуры

&НаКлиенте
Процедура пр_Команда1(Команда)
    
    Сообщить("Команда выполнена.");
    
КонецПроцедуры

Программное создание декораций форм.

&НаСервере
Процедура пр_СоздатьДекорацию()
    
    //добавить надпись
    Элемент    			 = Элементы.Добавить("Надпись1", Тип("ДекорацияФормы"), Элементы["пр_Группа1"]);
    Элемент.Вид    		 = ВидДекорацииФормы.Надпись;
    Элемент.Заголовок    	 = "Добавленная надпись";
 
    //для того, чтобы добавить картинку, необходимо выбрать ВидДекорацииФормы.Картинка
    Элемент = Элементы.Добавить("Картинка1", Тип("ДекорацияФормы"), Элементы["пр_Группа1"]);
    Элемент.Вид = ВидДекорацииФормы.Картинка;
    Элемент.Картинка = БиблиотекаКартинок.Бесконечность;  
  
КонецПроцедуры

Программное добавление реквизита на форму.

Добавлять новые реквизиты в управляемую форму и удалять необходимо с помощью метода ИзменитьРеквизиты(), куда в параметры передается массив добавляемых реквизитов и массив удаляемых. Удалять при этом можно только те реквизиты, которые были созданы программно.

&НаСервере
Процедура пр_СоздатьРеквизиты()
    
	// Массив для новых реквизитов
	ДобавляемыеРеквизиты    = Новый Массив;
   	 
	// Опишем ревизиты формы
	Реквизит_Использование = Новый РеквизитФормы("пр_Использование",    Новый ОписаниеТипов("Булево"), "", "Использование");
	Реквизит_Номенклатура = Новый РеквизитФормы("пр_Номенклатура",    Новый ОписаниеТипов("СправочникСсылка.Номенклатура"), "", "Номенклатура");
	Реквизит_Характеристика = Новый РеквизитФормы("пр_Характеристика",    Новый ОписаниеТипов("СправочникСсылка.ХарактеристикиНоменклатуры"), "", "Характеристика");
  	 Реквизит_Количество = Новый РеквизитФормы("пр_Количество",    Новый ОписаниеТипов("Число", , , Новый КвалификаторыЧисла(10, 3)), "", "Количество");
  	 Реквизит_УдалитьКоличество = Новый РеквизитФормы("пр_УдалитьКоличество",    Новый ОписаниеТипов("Число", , , Новый КвалификаторыЧисла(10, 3)), "", "Удалить_Количество");
       //если используется БСП, то можно для определения описания типов использовать функцию
       //ОбщегоНазначения.ОписаниеТипаСтрока(ДлинаСтроки)
       //ОбщегоНазначения.ОписаниеТипаЧисло(Разрядность, РазрядностьДробнойЧасти = 0, ЗнакЧисла = Неопределено)
       //ОбщегоНазначения.ОписаниеТипаДата(ЧастиДаты)
  	 Реквизит_Информация = Новый РеквизитФормы("пр_Информация",    ОбщегоНазначения.ОписаниеТипаСтрока(100), "", "Информация");
    
       // Для наглядности заполним массив после описания реквизитов формы
	ДобавляемыеРеквизиты.Добавить(Реквизит_Использование);
	ДобавляемыеРеквизиты.Добавить(Реквизит_Номенклатура);
	ДобавляемыеРеквизиты.Добавить(Реквизит_Характеристика);
	ДобавляемыеРеквизиты.Добавить(Реквизит_Количество);
	ДобавляемыеРеквизиты.Добавить(Реквизит_УдалитьКоличество);
	ДобавляемыеРеквизиты.Добавить(Реквизит_Информация);
    
	// Добавим новые реквизиты в форму
	ИзменитьРеквизиты(ДобавляемыеРеквизиты);
   	 
КонецПроцедуры

&НаСервере
Процедура пр_УдалитьРеквизиты()
    
	// Массив для удаляемых реквизитов
	УдаляемыеРеквизиты    = Новый Массив;
    
    //указываем путь к удаляемому реквизиту
	УдаляемыеРеквизиты.Добавить("пр_УдалитьКоличество");
    //К добавленным реквизитам нужно обращаться через переменную ЭтаФорма
    
	// Добавим новые реквизиты в форму
	ИзменитьРеквизиты(,УдаляемыеРеквизиты);
   	 
КонецПроцедуры

Вывод реквизитов на форму.

&НаСервере
Процедура пр_ВывестиРеквизитыНаФорму()
    
    НовыйЭлемент = Элементы.Добавить("пр_Использование", Тип("ПолеФормы"), Элементы.пр_Страница1);
	НовыйЭлемент.ПутьКДанным              	= "пр_Использование";
	НовыйЭлемент.Вид                      	= ВидПоляФормы.ПолеФлажка;
    НовыйЭлемент.ПоложениеЗаголовка    	   = ПоложениеЗаголовкаЭлементаФормы.Право;
    //установим обработчик события элементы
    НовыйЭлемент.УстановитьДействие("ПриИзменении", "пр_ИспользованиеПриИзменении");
    
    НовыйЭлемент = Элементы.Добавить("пр_Номенклатура", Тип("ПолеФормы"), Элементы.пр_Страница1);
	НовыйЭлемент.ПутьКДанным              	= "пр_Номенклатура";
	НовыйЭлемент.Вид                      	= ВидПоляФормы.ПолеВвода;
    //установить параметр выбора элемента
    НовыйМассив = Новый Массив();
    НовыйПараметр = Новый ПараметрВыбора("Отбор.ПометкаУдаления", Ложь);
    НовыйМассив.Добавить(НовыйПараметр);
    НовыеПараметры = Новый ФиксированныйМассив(НовыйМассив);
	НовыйЭлемент.ПараметрыВыбора = НовыеПараметры;
    НовыйЭлемент.УстановитьДействие("ПриИзменении", "пр_НоменклатураПриИзменении");

    НовыйЭлемент = Элементы.Добавить("пр_Характеристика", Тип("ПолеФормы"), Элементы.пр_Страница1);
	НовыйЭлемент.ПутьКДанным              	= "пр_Характеристика";
	НовыйЭлемент.Вид                      	= ВидПоляФормы.ПолеВвода;
	НовыйЭлемент.Заголовок                	= "Характеристика номенклатуры";
    //добавить связь параметров выбора по реквизиту владелец в зависимости от выбранной номенклатуры
    НоваяСвязь = Новый СвязьПараметраВыбора("Отбор.Владелец", "пр_Номенклатура");
    НовыйМассив = Новый Массив();
    НовыйМассив.Добавить(НоваяСвязь);
	НовыйЭлемент.СвязиПараметровВыбора = Новый ФиксированныйМассив(НовыйМассив);    
    НовыйЭлемент.УстановитьДействие("ПриИзменении", "пр_ХарактеристикаПриИзменении");
    
    НовыйЭлемент = Элементы.Добавить("пр_Количество", Тип("ПолеФормы"), Элементы.пр_Страница1);
	НовыйЭлемент.ПутьКДанным              	= "пр_Количество";
	НовыйЭлемент.Вид                      	= ВидПоляФормы.ПолеВвода;
    //установить формат
	НовыйЭлемент.ФорматРедактирования   	   = "ЧДЦ=0; ЧРГ=.; ЧН=Отсутствует";
    
    НовыйЭлемент = Элементы.Добавить("пр_Информация", Тип("ПолеФормы"), Элементы.пр_Страница1);
	НовыйЭлемент.ПутьКДанным              	= "пр_Информация";
	НовыйЭлемент.Вид                      	= ВидПоляФормы.ПолеВвода;
    //установить список выбора
    НовыйЭлемент.РежимВыбораИзСписка    	   = Истина;
    Массив = Новый Массив;
    Массив.Добавить("Необходимо дозаказать");    
    Массив.Добавить("Достаточно");    
    Массив.Добавить("Оформить полный заказ");    
    НовыйЭлемент.СписокВыбора.ЗагрузитьЗначения(Массив);
    
КонецПроцедуры

&НаКлиенте
Процедура пр_ИспользованиеПриИзменении(Элемент)
КонецПроцедуры

Вызов процедур при создании на сервере 1С

После описания всех процедур выводим их в процедуре ПриСозданииНаСервере. Также можно изменить программно некоторые свойства формы, например, заголовок. Чтобы был виден только наш заголовок, нужно отключить свойство Автозаголовок.

&НаСервере

&НаСервере
Процедура пр_ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	//установим заголовок формы 
	ЭтаФорма.Заголовок 		= "Шаблон для программной работы с реквизитами, командами и элементами формы";
	ЭтаФорма.АвтоЗаголовок 	= Ложь;
	
	пр_СоздатьГруппы();
	пр_СоздатьНовуюКоманду();
	пр_СоздатьДекорацию();
	пр_СоздатьРеквизиты();
	пр_УдалитьРеквизиты();
	пр_ВывестиРеквизитыНаФорму();
	
КонецПроцедуры

Некоторые советы при программном редактировании формы

• Если вы не используете префиксы при создании новых команд и элементов рекомендуется проверять существование создаваемых объектов по имени с помощью метода Найти(), который вернет Неопределено, если объект в коллекции не найден:
  • Элементы.Найти(«пр_Владелец»);
  • Команды.Найти(«пр_НоваяКоманда»);
• Чтобы проверить уникальность реквизита на форме можно воспользоваться следующей функцией:

&НаКлиентеНаСервереБезКонтекста
// Функция определяет существует ли реквизит у объекта.
//
Функция ЕстьРеквизитОбъекта(мОбъект, ИмяРеквизита)
    
    КлючУникальности   = Новый УникальныйИдентификатор;
    СтруктураРеквизита = Новый Структура(ИмяРеквизита, КлючУникальности);
    ЗаполнитьЗначенияСвойств(СтруктураРеквизита, мОбъект);
    Возврат СтруктураРеквизита[ИмяРеквизита] <> КлючУникальности;
    
КонецФункции // ЕстьРеквизитОбъекта()

• Свойства, методы и коллекции управляемой формы описаны в синтакс-помощнике в разделе «Интерфейс (управляемый)»;
• Изучите БСП, если она имеется в вашей конфигурации. Например в общем модуле «ОбщегоНазначения» уже описаны функции для создания объекта ОписаниеТипов, необходимого при создании новых реквизитов на форме:
  • ОбщегоНазначения.ОписаниеТипаСтрока(ДлинаСтроки) — Создает объект ОписаниеТипов, содержащий тип Строка;
  • ОбщегоНазначения.ОписаниеТипаЧисло(Разрядность, РазрядностьДробнойЧасти = 0, ЗнакЧисла = Неопределено) — Создает объект ОписаниеТипов, содержащий тип Число;
  • ОбщегоНазначения.ОписаниеТипаДата(ЧастиДаты) — Создает объект ОписаниеТипов, содержащий тип Дата;
  • ОбщегоНазначенияВызовСервера.ЦветСтиля(ИмяЦветаСтиля) — Функция получает цвет стиля по имени элемента стиля;
  • ОбщегоНазначенияВызовСервера.ШрифтСтиля(ИмяШрифтаСтиля) — Функция получает шрифт стиля по имени элемента стиля.

Итак, взглянем на получившийся результат. Все элементы на форме созданы программно:

Полезные ссылки

1. Типовой механизм упрощенного изменения конфигурации в ERP 2.0 и УТ 11
2. Типовой функционал модификации конфигурации линейки ERP-решений (УТ 11, КА 2 и ERP 2)
3. 1С Управляемые Формы. Программное создание таблицы значений и динамического списка (Часть 2)

При разработке форм нередко возникает необходимость добавить реквизит формы, кнопку или элемент формы. Но если их добавлять из конструктора, то это неоправданно усложняет обновление конфигурации и увеличивает риск возникновения проблем после обновления. Поэтому гораздо лучше, хоть и немного дольше, добавлять реквизиты на форму программно. 

Для добавления реквизитов удобно либо создать процедуру и вызывать ее из обработчика ПриСозданииНаСервере, либо использовать специальный общий модуль РаботаСФормамиПереопределяемый.

Пример добавления реквизитов на форму:

&НаСервере
Процедура ДополнитьЭлементыФормы()

     МассивРеквизитов = Новый Массив;

     РеквизитОткрытаИзОбработкиЛаборатории = Новый РеквизитФормы("ОткрытаИзОбработкиЛаборатории", Новый ОписаниеТипов("Булево"));
     РеквизитРезультат = Новый РеквизитФормы("РезультатАнализа", Новый ОписаниеТипов("Строка"));

     МассивРеквизитов.Добавить(РеквизитОткрытаИзОбработкиЛаборатории);
     МассивРеквизитов.Добавить(РеквизитРезультат);

     ИзменитьРеквизиты(МассивРеквизитов);

КонецПроцедуры

Пример добавления кнопок и элементов на форму:

&НаСервере
Процедура ДополнитьЭлементыФормы()

    НоваяКоманда = ЭтаФорма.Команды.Добавить("ЗагрузкаДанных");
    НоваяКоманда.Действие = "ЗагрузкаДанных";

    НовыйЭлемент = Элементы.Добавить("ЗагрузитьДанные", Тип("КнопкаФормы"), Элементы.РезультатКОбработкеКоманднаяПанель);
    НовыйЭлемент.ИмяКоманды = "ЗагрузкаДанных";
    НовыйЭлемент.Заголовок = "Загрузка данных";

КонецПроцедуры

&НаКлиенте
Процедура ЗагрузкаДанных(Команда)

КонецПроцедуры

Пример указания процедуры-обработчика для событий формы:

&НаСервере
Процедура ДополнитьЭлементыФормы()

    УстановитьДействие("ОбработкаОповещения", "ОбработкаОповещенияФормы");

КонецПроцедуры

Пример создания поля и добавления процедуры-обработчика для элемента формы:

&НаСервере 
Процедура ДополнитьЭлементыФормы()
    ЭлементНазначениеЗаявки = Элементы.Вставить("НазначениеЗаявки", Тип("ПолеФормы"), Элементы.ГруппаЛево, Элементы.ГруппаОрганизация);
    ЭлементНазначениеЗаявки.ПутьКДанным = "Объект.НазначениеЗаявки";
    ЭлементНазначениеЗаявки.Вид = ВидПоляФормы.ПолеПереключателя;
    ЭлементНазначениеЗаявки.Заголовок = "Тип заявки на";
    ЭлементНазначениеЗаявки.УстановитьДействие("ПриИзменении", "ИзменениеНазначенияЗаявки");
КонецПроцедуры

&НаКлиенте
Процедура ИзменениеНазначенияЗаявки(Элемент)
     //Обработчик команды
КонецПроцедуры

Пример программного добавления реквизитов на форме:

МассивРеквизитов = Новый Массив;

//Добавляем три реквизита формы
МассивРеквизитов.Добавить(Новый РеквизитФормы("ОтображатьСвязи", Новый ОписаниеТипов("Булево")));
МассивРеквизитов.Добавить(Новый РеквизитФормы("ОтображатьРабочуюГруппу", Новый ОписаниеТипов("Булево")));
МассивРеквизитов.Добавить(Новый РеквизитФормы("ОтображатьВизы", Новый ОписаниеТипов("Булево")));

//Добавление реквизита в табличную часть "Файлы"
МассивРеквизитов.Добавить(Новый РеквизитФормы("Актуальность", Новый ОписаниеТипов("Булево"), "Файлы", "Актуальность", Истина));

ИзменитьРеквизиты(МассивРеквизитов);

Платформа 1С:Предприятие позволяет программно добавлять и изменять элементы управляемой формы. Разберемся для чего это может потребоваться.

Программная модификация формы может потребоваться в нескольких случаях:

• При доработке типовых конфигураций для облегчения процедуры последующего обновления. В этом случае будет изменен только модуль формы. Модули намного проще обновлять, чем форму.
• При реализации некоторых общих алгоритмов. Например, в подсистеме БСП «Запрет редактирования реквизитов объектов» для всех подключенных к подсистеме объектов предусмотрено программное создание кнопки для включения возможности редактирования реквизитов.
• При реализации некоторых специфических алгоритмов. Например, в справочнике Номенклатура создаются поля для редактирования дополнительных реквизитов.

В управляемой форме можно программно добавить, изменить и удалить:

• реквизиты;
• локальные команды;
• элементы.

Все указанные операции возможны только на сервере.

Программное изменение формы имеет ограничения:

• Удалить можно только программно добавленные реквизиты/команды/элементы. Нельзя программно удалить объекты, созданные в конфигураторе.
• Нельзя назначить реквизит основным.

Изменение команд формы

Для управления составом команд у объекта УправляемаяФорма есть коллекция Команды. У коллекции есть несколько методов:

• Добавить(<ИмяКоманды>)

• Количество()

• Найти(<ИмяКоманды>)

• Удалить(<Команда>)

Коллекция Команды доступна как на клиенте, так и на сервере. Изменять коллекцию (методы Добавить() и Удалить()) можно только на сервере. Искать и получать количество элементов (методы Найти() и Количество()) можно как на клиенте, так и на сервере.

В качестве примера работы с командами формы создадим новую команду ИсторияИзменений с заголовком «История изменений…», которая будет вызвать обработчик ОтобразитьИсторию(). Создание выполняется при открытии формы.

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
Команда = Команды.Добавить(«ИсторияИзменений»);
Команда.Действие = «Подключаемый_ОтобразитьИсторию»;
Команда.Заголовок = «История изменений…»;
КонецПроцедуры
&НаКлиенте
Процедура Подключаемый_ОтобразитьИсторию(Команда)
// действия команды
КонецПроцедуры

Обработчик команды должен располагаться в форме и иметь директиву компиляции &НаКлиенте.

Изменение реквизитов формы

Чтение состава реквизитов формы выполняется функцией ПолучитьРеквизиты(<Путь>), возвращающей массив типа РеквизитФормы. Параметр функции указывает путь к родительскому реквизиту (в виде строки). Если параметр опущен или указана пустая строка, возвращаются реквизиты верхнего уровня.

Изменение реквизитов выполняется методом ИзменитьРеквизиты(<ДобавляемыеРеквизиты>, <УдаляемыеРеквизиты>) объекта УправляемаяФорма. В параметр ДобавляемыеРеквизиты передается массив с элементами типа РеквизитФормы. В параметр УдаляемыеРеквизиты передается массив строк, описывающих пути к удаляемым реквизитам.

---

Внимание!

Процесс изменения состава реквизитов является достаточно ресурсоемким. Фактически выполняется пересоздание формы. В связи с этим работа с реквизитами формы выполняется в пакетном режиме.

---

Создадим новый реквизит формы с именем Покупатель:

// Описание добавляемых реквизитов
ДобавляемыеРеквизиты = Новый Массив;
ДобавляемыеРеквизиты.Добавить(Новый РеквизитФормы(«Покупатель», Новый ОписаниеТипов(«СправочникСсылка.Контрагенты»), , «Клиент»));

// Изменения состава реквизитов
ИзменитьРеквизиты(ДобавляемыеРеквизиты);

Изменение элементов формы

Для управления составом элементов у объекта УправляемаяФорма есть коллекция Элементы. У коллекции есть несколько методов:

• Вставить(<Имя>, <ТипЭлемента>, <Родитель>, <Элемент>)

• Добавить(<Имя>, <ТипЭлемента>, <Родитель>)

• Количество()

• Найти(<Имя>)

• Переместить(<Элемент>, <Родитель>, <МестоРасположения>)

• Удалить(<Элемент>)

Коллекция Элементы доступна как на клиенте, так и на сервере. Изменять коллекцию (методы Вставить(), Добавить(), Переместить() и Удалить()) можно только на сервере. Искать и получать количество элементов (методы Найти() и Количество()) можно как на клиенте, так и на сервере. Элементами коллекции могут быть:

• ГруппаФормы;
• ТаблицаФормы;
• ПолеФормы;
• КнопкаФормы.

Элементам формы можно программно назначить обработчики событий. Для этих целей предназначен метод УстановитьДействие(<ИмяСобытия>, <Действие>).

Рассмотрим несколько наиболее распространенных на практике примеров работы с командами, реквизитами и элементами формы.

Добавление команды и связанной с ней кнопки:

// Создание команды
Команда = Команды.Добавить(«ИсторияИзменений»);
Команда.Действие = «Подключаемый_ОтобразитьИсторию»; // В форме должна быть процедура с указанным наименованием
Команда.Заголовок = «История изменений…»;
// Создание кнопки и связь ее с командой
Элемент = Элементы.Добавить(«ИсторияИзменений», Тип(«КнопкаФормы»));
Элемент.ИмяКоманды = «ИсторияИзменений»;

Добавление реквизита и связанного с ним поля ввода:

// Описание добавляемых реквизитов
ДобавляемыеРеквизиты = Новый Массив;
ДобавляемыеРеквизиты.Добавить(Новый РеквизитФормы(«Покупатель», Новый ОписаниеТипов(«СправочникСсылка.Контрагенты»), , «Клиент»));
// Изменение состава реквизитов
ИзменитьРеквизиты(ДобавляемыеРеквизиты);
// Создание поля ввода и связь с реквизитом
Элемент = Элементы.Добавить(«Покупатель», Тип(«ПолеФормы»));
Элемент.Вид = ВидПоляФормы.ПолеВвода;
Элемент.ПутьКДанным = «Покупатель»;

Назначение элементу формы обработчика события:

ЭлементПокупатель.УстановитьДействие(«ПриИзменении», «Подключаемый_ПокупательПриИзменении»);

&НаКлиенте
Процедура Подключаемый_ПокупательПриИзменении(Элемент)
// Действия события
КонецПроцедуры

---

Внимание!

Процедурам, которые устанавливаются в качестве обработчиков событий из кода с помощью метода УстановитьДействие(), рекомендуется задавать префикс Подключаемый_.

---

---

Внимание!

Скачать обработку с примерами программного поиска и изменения реквизитов, команд и элементов управляемой формы можно ЗДЕСЬ.

---

Содержание:

1.       Функция проверки существования реквизита на управляемой форме

2.       Процедура добавление реквизита управляемой формы

3.       Процедура добавление реквизита управляемой формы «ПолеВвода»

4.       Процедура добавление реквизита управляемой формы «ПолеФлажка»

5.       Процедура добавление реквизита управляемой формы «Кнопка»

6.       Процедура программного добавление реквизита формы «ГруппаФормы»

7.       Вспомогательная функция проверки корректности имени добавляемого элемента управляемой формы

Программная модификация форм используется в нескольких случаях:

· При доработке типовых конфигураций (в частности обновление на новый релиз вендора). В этом случае будет изменен только модуль управляемой формы. Модули намного проще обновлять, чем форму.

· При реализации некоторых общих алгоритмов. Например, в подсистеме БСП.

Программной модификации формы подлежать следующие сущности: реквизиты управляемой формы, локальные команды, элементы управляемой формы.

При программной модификации управляемой формы существует ряд ограничений: нельзя программно удалить объекты, созданные в конфигураторе, удалению подлежат объекты формы созданные программно, реквизиты создаваемые программно нельзя назначать основными.

Все программные модификации формы производятся только на сервере.

Создадим и опишем некоторые функции которые в дальнейшем облегчать разработчикам модификации управляемых форм в 1С 8. Все процедуры и функции необходимо будет поместить в общий модуль с вариантом исполнения на сервере:  

1.      Функция проверки существования реквизита на управляемой форме

Функция РеквизитСуществует(Форма, ИмяРеквизита, ИмяРодителя = «») Экспорт

      Реквизиты = Форма.ПолучитьРеквизиты(ИмяРодителя);

      РеквизитСуществует = Ложь;

      Для Каждого Реквизит Из Реквизиты Цикл

            Если Реквизит.Имя = ИмяРеквизита Тогда

                  РеквизитСуществует = Истина;

                  Прервать;

            КонецЕсли;

      КонецЦикла;

      Возврат РеквизитСуществует;

КонецФункции

Описание функции – В качестве входных параметров передаются: обрабатываемая форма «Форма», «ИмяРеквизита» — имя реквизита поиска, «ИмяРодитя» — область поиска реквизита на форме. Функция получает коллекцию реквизитов управляемой формы и проверяет переданное имя реквизита с текущим реквизитом формы, если есть совпадение функция возвращает Истина иначе Ложь.  

2.     ПРОЦЕДУРА ДОБАВЛЕНИЯ РЕКВИЗИТА управляемой ФОРМЫ

Процедура ДобавитьРеквизитФормы(МассивДобавляемыхРеквизитов, ИмяРеквизита, ТипРеквизита, Путь = «», Заголовок = «») Экспорт

      НовыйРеквизит = Новый РеквизитФормы(ИмяРеквизита, ТипРеквизита, Путь, Заголовок);

      МассивДобавляемыхРеквизитов.Добавить(НовыйРеквизит);

КонецПроцедуры

Описание процедуры:

Входные параметры

·         МассивДобавляемыхРеквизитов – массив;

·         ИмяРеквизита – имя добавляемого реквизита;

·         ТипРеквизита – тип реквизита (Содержит тип реквизита);

·         Путь — содержит путь к реквизиту. Не включает имя реквизита;

·         Заголовок — содержит отображаемый текст реквизита.

Процедура добавляет на управляемую форму новый реквизит формы с именем.  

3.     ПРОЦЕДУРА ДОБАВЛЕНИЯ РЕКВИЗИТА управляемой ФОРМЫ «ПолеВвода»

Процедура ДобавитьПолеВвода(Форма, ИмяЭлемента, ПутьКДанным, Заголовок = «» , Знач Родитель = Неопределено,   Знач ЭлементПредУстановки = Неопределено, ДоступностьПВ = Истина, ТЗОбработчиковСобытий = Неопределено) Экспорт

      Если Не ТипЗнч(Родитель) = Тип(«ГруппаФормы»)

            И Не ТипЗнч(Родитель) = Тип(«ТаблицаФормы»)

            И Не ТипЗнч(Родитель) = Тип(«УправляемаяФорма») Тогда

            // Никогда не знаешь, с чем имеешь дело!

            Родитель = Неопределено

      КонецЕсли;

      Если ИмяЭлемента = «» Или СтрНайти(ИмяЭлемента, » «) Или НачинаетсяСЧисла(ИмяЭлемента) Тогда

            Сообщить(«Не удалось добавить поле формы «»» + ИмяЭлемента + «»». Необходимо исправление!», СтатусСообщения.Внимание);

            Возврат

      КонецЕсли;

      Если ЭлементПредУстановки = Неопределено Тогда

            Элемент = Форма.Элементы.Добавить(ИмяЭлемента, Тип(«ПолеФормы»), Родитель);

      Иначе

            Элемент = Форма.Элементы.Добавить(ИмяЭлемента, Тип(«ПолеФормы»), Родитель);

            Форма.Элементы.Переместить(Элемент, Родитель, ЭлементПредУстановки);

      КонецЕсли;

      Элемент.Заголовок = Заголовок;

      Элемент.ПутьКДанным = ПутьКДанным;

      Элемент.Вид = ВидПоляФормы.ПолеВвода;

      Элемент.Доступность = ДоступностьПВ;

    // Привязка обработчиков событий

      Если ТЗОбработчиковСобытий = Неопределено Тогда

        Возврат;

    КонецЕсли;   

      Для Каждого Строка Из ТЗОбработчиковСобытий Цикл

        Форма.Элементы[ИмяЭлемента].УстановитьДействие(Строка.ИмяСобытия, Строка.Действие);

      КонецЦикла;

КонецПроцедуры

Описание процедуры:

Входные параметры

·         Форма – модифицируемая форма;

·         ИмяЭлемента – имя добавляемого реквизита;

·         ТипРеквизита – тип реквизита (Содержит тип реквизита);

·         ПутьКДанным — содержит путь к реквизиту. Не включает имя реквизита;

·         Заголовок — содержит отображаемый текст реквизита;

·         Родитель — родитель для добавляемого элемента. Если не указан, то добавляется на верхний уровень формы;

·         ЭлементПредУстановки – элемент, перед которым нужно разместить добавляемый элемент. Если не задан, то перемещается в конец коллекции.

·         ДоступностьПВ – свойство «Доступность» добавляемого элемента;

·         ТЗОбработчиковСобытий – таблица значений с описанием действий добавляемого элемента.

Процедура добавляет на управляемую форму новый реквизит формы с типом ПолеВвода.  

4.     ПРОЦЕДУРА ДОБАВЛЕНИЯ РЕКВИЗИТА управляемой ФОРМЫ «ПолеФлажка»

Процедура ДобавитьПолеФлажка(Форма, ИмяЭлемента, ПутьКДанным, Заголовок = «» , Знач Родитель = Неопределено,   Знач ЭлементПредУстановки = Неопределено, ДоступностьПВ = Истина) Экспорт

      Если Не ТипЗнч(Родитель) = Тип(«ГруппаФормы»)

            И Не ТипЗнч(Родитель) = Тип(«ТаблицаФормы»)

            И Не ТипЗнч(Родитель) = Тип(«УправляемаяФорма») Тогда

            // Никогда не знаешь, с чем имеешь дело!

            Родитель = Неопределено

      КонецЕсли;

      Если ИмяЭлемента = «» Или СтрНайти(ИмяЭлемента, » «) Или НачинаетсяСЧисла(ИмяЭлемента) Тогда

            Сообщить(«Не удалось добавить поле формы «»» + ИмяЭлемента + «»». Необходимо исправление!», СтатусСообщения.Внимание);

            Возврат

      КонецЕсли;

      Если ЭлементПредУстановки = Неопределено Тогда

            Элемент = Форма.Элементы.Добавить(ИмяЭлемента, Тип(«ПолеФормы»), Родитель);

      Иначе

            Элемент = Форма.Элементы.Добавить(ИмяЭлемента, Тип(«ПолеФормы»), Родитель);

            Форма.Элементы.Переместить(Элемент, Родитель, ЭлементПредУстановки);

      КонецЕсли;

      Элемент.Заголовок = Заголовок;

      Элемент.ПутьКДанным = ПутьКДанным;

      Элемент.Вид = ВидПоляФормы.ПолеФлажка;

      Элемент.Доступность = ДоступностьПВ;

КонецПроцедуры

Описание процедуры:

Входные параметры

·         Форма – модифицируемая форма;

·         ИмяЭлемента – имя добавляемого реквизита;

·         ТипРеквизита – тип добавляемого реквизита (Содержит тип реквизита);

·         ПутьКДанным — содержит путь к реквизиту. Не включает имя реквизита;

·         Заголовок — содержит отображаемый текст реквизита;

·         Родитель — родитель для добавляемого элемента. Если не указан, то добавляется на верхний уровень формы;

·         ЭлементПредУстановки – элемент, перед которым нужно разместить добавляемый элемент. Если не задан, то перемещается в конец коллекции.

·         ДоступностьПВ – свойство «Доступность» добавляемого элемента.

Процедура добавляет на форму новый реквизит формы с типом ПолеФлажка.   

5.     ПРОЦЕДУРА ДОБАВЛЕНИЯ РЕКВИЗИТА управляемой ФОРМЫ «Кнопка»

Процедура ДобавитьКнопку(Форма, ИмяЭлемента, Заголовок = «», ВидКнопки = Неопределено,

Знач ГруппаКоманд = Неопределено, Знач ЭлементПредУстановки = Неопределено,

КартинкаКнопки = Неопределено, ПодксазкаКнопки = Неопределено) Экспорт

      Если Не ТипЗнч(ГруппаКоманд) = Тип(«ГруппаФормы»)

            И Не ТипЗнч(ГруппаКоманд) = Тип(«УправляемаяФорма») Тогда

            // Никогда не знаешь, с чем имеешь дело!

            ГруппаКоманд = Неопределено;

      КонецЕсли;

      Если ВидКнопки = Неопределено Тогда

            ВидКнопки = ВидКнопкиФормы.ОбычнаяКнопка;

      КонецЕсли;

      НоваяКоманда = Форма.Команды.Добавить(ИмяЭлемента);

      НоваяКоманда.Действие = «плрНажатиеКнопки» + ИмяЭлемента;

      НоваяКоманда.Заголовок = Заголовок;

      Если ЭлементПредУстановки = Неопределено Тогда

            НовыйЭлемент = Форма.Элементы.Вставить(ИмяЭлемента, Тип(«КнопкаФормы»), ГруппаКоманд);

      Иначе

            НовыйЭлемент = Форма.Элементы.Вставить(ИмяЭлемента, Тип(«КнопкаФормы»), ГруппаКоманд, ЭлементПредУстановки);

      КонецЕсли;

      НовыйЭлемент.Заголовок = Заголовок;

      НовыйЭлемент.Вид = ВидКнопки;

      НовыйЭлемент.ИмяКоманды = ИмяЭлемента;

      Если КартинкаКнопки <> Неопределено Тогда

            НовыйЭлемент.Картинка    = КартинкаКнопки;

            НовыйЭлемент.Отображение = ОтображениеКнопки.Картинка;

      КонецЕсли;

      Если ПодксазкаКнопки <> Неопределено Тогда

            НовыйЭлемент.ОтображениеПодсказки = ОтображениеПодсказки.Авто;

            НоваяКоманда.Подсказка = ПодксазкаКнопки;

      КонецЕсли;

КонецПроцедуры

Описание процедуры программного добавления реквизита формы:

Входные параметры

·         Форма – модифицируемая форма;

·         ИмяЭлемента – имя добавляемого реквизита;

·         Вид кнопки – тип добавляемого реквизита (содержит тип реквизита);

·         ГруппаКомманд — родитель для добавляемого элемента. Если не указан, то добавляется на верхний уровень формы;

·         ЭлементПредУстановки – элемент, перед которым нужно разместить добавляемый элемент. Если не задан, то перемещается в конец коллекции.

·         КартинкаКнопки – признак графического отображения кнопки;

·         ПодсказкаКнопки – текстовое представление подсказки кнопки.

Процедура добавляет на форму новый реквизит формы с типом КнопкаФормы.  

6.     ПРОЦЕДУРА программного ДОБАВЛЕНИЯ РЕКВИЗИТА ФОРМЫ «ГруппаФормы»

Процедура ДобавитьГруппуФормы(Форма, ИмяЭлемента, Заголовок, Знач ВидГруппы, БезОтображения = Ложь, Знач Группировка = Неопределено, Знач Родитель = Неопределено) Экспорт

      НовыйЭлемент = Форма.Элементы.Добавить(ИмяЭлемента, Тип(«ГруппаФормы»), Родитель);

      НовыйЭлемент.Заголовок = Заголовок;

      НовыйЭлемент.Вид = ВидГруппы;

      Если ВидГруппы = ВидГруппыФормы.ОбычнаяГруппа Тогда

            Если Группировка = Неопределено Тогда

                  НовыйЭлемент.Группировка = ГруппировкаПодчиненныхЭлементовФормы.ГоризонтальнаяЕслиВозможно;

            ИначеЕсли Группировка Тогда

                  НовыйЭлемент.Группировка = ГруппировкаПодчиненныхЭлементовФормы.ГоризонтальнаяВсегда;

            КонецЕсли;

            Если БезОтображения Тогда

                  НовыйЭлемент.ОтображатьЗаголовок = Ложь;

            КонецЕсли;

      КонецЕсли;

КонецПроцедуры

Описание процедуры программного добавления реквизита формы:

Входные параметры

·         Форма – модифицируемая форма;

·         ИмяЭлемента – имя добавляемого реквизита;

·         ВидГруппы – тип добавляемого реквизита (содержит тип реквизита);

·         БезОтображения – свойство типа элемента формы «ГруппаФормы» отображать заголовок;

·         Группировка – свойство указывающее расположение элементов в группе;

·         Родитель — родитель для добавляемого элемента. Если не указан, то добавляется на верхний уровень формы.

Процедура добавляет на форму новый реквизит формы с типом «ГруппаФормы».   

7.     Вспомогательная функция проверки корректности имени добавляемого элемента управляемой формы

Функция НачинаетсяСЧисла(ИмяЭлемента)

      КодВозврата = Ложь;

      Для Счетчик = 0 По 9 Цикл

            Если СтрНачинаетсяС(ИмяЭлемента, Строка(Счетчик)) Тогда

                  КодВозврата = Истина;

                  Прервать;

            КонецЕсли;       

      КонецЦикла;

      Возврат КодВозврата;

КонецФункции

Описание функции:

Входные параметры

·         ИмяЭлемента – имя добавляемого реквизита.

Функция проверяет корректность передаваемого имени реквизита в 1С. Функция возвращает Истина если имя соответствуют правилу формирования имен объектов иначе Ложь.

Заключение – в статье представлены наиболее часто используемы функции при программной модификации управляемой формы в 1С 8.

Спасибо за внимание уважаемые коллеги.

Специалист компании «Кодерлайн»

Дмитрий Гречушкин

Чтобы вывести реквизиты на форму программно нужно в обработчике «ПриСозданииНаСервере» в форме выполнить следующий алгоритм:

Реквизит должен находится в метаданных.

Листинг кода: