КоличествоВложенныхПеременных = СтрЧислоВхождений(ИмяРеквизита, «.»);
Если КоличествоВложенныхПеременных > 0 Тогда
МассивПеременных = СтрокаМассив(ИмяРеквизита, «.»);
ПолученныйРеквизит = Документ[МассивПеременных[0]];
Для Сч2 = 0 По КоличествоВложенныхПеременных — 1 Цикл
ТекРеквизит = МассивПеременных[КоличествоВложенныхПеременных — Сч2];
ПолученныйРеквизит = ПолученныйРеквизит[ТекРеквизит];
КонецЦикла;
КонецЕсли;
Функция СтрокаМассив(Знач Значение,Разделитель)
Если ТипЗнч(Значение) = Тип(«Строка») Тогда
МнСтр = СтрЗаменить(Значение, Разделитель, Символы.ПС);
Массив = Новый Массив;
Для н = 1 По СтрЧислоСтрок(МнСтр) Цикл
Массив.Добавить(СтрПолучитьСтроку(МнСтр, н));
КонецЦикла;
Возврат Массив;
ИначеЕсли ТипЗнч(Значение) = Тип(«Массив») Тогда
Строка = «»;
Для Каждого Элемент Из Значение Цикл
Строка = Строка + ?(Строка <> «», Разделитель, «») + Элемент;
КонецЦикла;
Возврат Строка;
Иначе
Возврат Неопределено;
КонецЕсли;
КонецФункции
Как получить доступ к реквизитам объекта?
Статья носит справочный характер. Предназначена для начинающих программистов.
Получить массив реквизитов объекта можно при помощи самого объекта:
ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
ДокОбъект = ДокСсылка.ПолучитьОбъект();
МассивРеквизитовОбъекта = ДокОбъект.Метаданные().Реквизиты;
Получив массив реквизитов, можно организовать Цикл для просмотра имен реквизитов:
Для каждого Реквизит Из ДокОбъект.Метаданные().Реквизиты Цикл
Сообщить(Реквизит.Имя + " :" + Реквизит.Представление());
КонецЦикла;
Для того, чтобы получить значения реквизитов объекта вообще говоря надо обратиться с запросом к БД, типа:
Запрос = "ВЫБРАТЬ
| ИмяРеквизита,
|ИЗ
| Объект.ТипОбъекта КАК ОбъектТипОбъекта
|ГДЕ
| ОбъектТипОбъекта.Ссылка = &СсылкаНаОбъект
Запрос.УстановитьПараметр("СсылкаНаОбъект", СсылкаНаОбъект);
В запрос надо передать ссылку на объект и имя реквизита. Запрос вернет таблицу или выборку со значением реквизита.
Удобнее конечно для поиска значений реквизитов воспользоваться готовыми решениями, например фунцией ПолучитьЗначенияРеквизитов() общего модуля ОбщегоНазначения.
// Возвращает структуру, содержащую значения реквизитов прочитанные из информационной базы
// по ссылке на объект.
//
// Если доступа к одному из реквизитов нет, возникнет исключение прав доступа.
// Если необходимо зачитать реквизит независимо от прав текущего пользователя,
// то следует использовать предварительный переход в привилегированный режим.
//
// Параметры:
// Ссылка - ссылка на объект, - элемент справочника, документ, ...
// ИменаРеквизитов - Строка или Структура - Если Строка, то имена реквизитов,
// перечисленные через запятую, в формате требований к свойствам структуры.
// Например, "Код, Наименование, Родитель".
// Если Структура, то в качестве ключа передается псевдоним поля для
// возвращаемой структуры с результатом, а в качестве значения (опционально)
// - фактическое имя поля в таблице.
// Если значение не определено, то имя поля берется из ключа.
//
// Возвращаемое значение:
// Структура - содержит список свойств, как список имен в строке
// ИменаРеквизитов, со значениям реквизитов, прочитанных
// из информационной базы.
//
Функция ПолучитьЗначенияРеквизитов(Ссылка, ИменаРеквизитов) Экспорт
Если ТипЗнч(ИменаРеквизитов) = Тип("Структура") Тогда
СтруктураРеквизитов = ИменаРеквизитов;
ИначеЕсли ТипЗнч(ИменаРеквизитов) = Тип("Строка") Тогда
СтруктураРеквизитов = Новый Структура(ИменаРеквизитов);;
Иначе
ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
НСтр("ru = 'Неверный тип второго параметра ИменаИлиСтруктураРеквизитов: %1'"),
Строка(ТипЗнч(ИменаРеквизитов)));
КонецЕсли;
ТекстПолей = "";
Для каждого КлючИЗначение Из СтруктураРеквизитов Цикл
ИмяПоля = ?(ЗначениеЗаполнено(КлючИЗначение.Значение), СокрЛП(КлючИЗначение.Значение), СокрЛП(КлючИЗначение.Ключ));
Псевдоним = СокрЛП(КлючИЗначение.Ключ);
ТекстПолей = ТекстПолей + ?(ПустаяСтрока(ТекстПолей), "", ",") + "
| " + ИмяПоля + " КАК " + Псевдоним;
КонецЦикла;
Запрос = Новый Запрос(
"ВЫБРАТЬ
|" + ТекстПолей + "
|ИЗ
| " + Ссылка.Метаданные().ПолноеИмя() + " КАК ПсевдонимЗаданнойТаблицы
|ГДЕ
| ПсевдонимЗаданнойТаблицы.Ссылка = &Ссылка
|");
Запрос.УстановитьПараметр("Ссылка", Ссылка);
Выборка = Запрос.Выполнить().Выбрать();
Выборка.Следующий();
Результат = Новый Структура;
Для каждого КлючИЗначение Из СтруктураРеквизитов Цикл
Результат.Вставить(КлючИЗначение.Ключ);
КонецЦикла;
ЗаполнитьЗначенияСвойств(Результат, Выборка);
Возврат Результат;
КонецФункции
Значение реквизитов в этой функции получено через запрос к БД. Возвращаемое значение — структура (ключ-значение). Пример использования:
ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
СтруктураНастроек = Новый Структура;
//инициируем структуру настроек именами реквизитов
Для каждого Реквизит Из ДокОбъект.Метаданные().Реквизиты Цикл
СтруктураНастроек.Вставить(Реквизит.Имя, Реквизит.Имя);
КонецЦикла;
ЗначенияРеквизитов = ПолучитьЗначенияРеквизитов(ДокСсылка , СтруктураНастроек);
СканПростойСтруктуры(ЗначенияРеквизитов); //вывести структуру для просмотра
Поскольку в функцию ПолучитьЗначенияРеквизитов() во второй параметр надо передать структуру, то мы создали структуру и организовали Цикл ее инициализации данными из массива имен реквизитов объекта. Возвращает функция так же структуру (ключ-значение), с которой удобно работать. Для просмотра этой структуры можно воспользоваться циклом, либо вызвать функцию СканПростойСтруктуры(), которой передать структуру для просмотра.
Функция СканПростойСтруктуры(Структура)
Для каждого Элемент из Структура Цикл
Сообщить(Элемент.Ключ + ": " + Элемент.Значение);
КонецЦикла;
КонецФункции
Если исследуемый объект использует так же еще и общие реквизиты, и их необходимо найти, то можно воспользоваться функцией МассивИменРеквизитовОбъекта(), которая находит не только реквизиты объекта но и общие и даже стандартные реквизиты, которые использует объект:
// Возвращает массив имен всех реквизитов переданного объекта
//
Функция МассивИменРеквизитовОбъекта(Объект) Экспорт
МассивИменРеквизитов = Новый Массив;
Если ТипЗнч(Объект) = Тип("ОбъектМетаданных") Тогда
МетаданныеОбъекта = Объект;
Иначе
МетаданныеОбъекта = Метаданные.НайтиПоТипу(ТипЗнч(Объект));
Если МетаданныеОбъекта = Неопределено Тогда
Возврат МассивИменРеквизитов;
КонецЕсли;
КонецЕсли;
Для индекс = 0 по 1 Цикл
// КоллекцияРеквизитов = ?(индекс = 0, МетаданныеОбъекта.СтандартныеРеквизиты, МетаданныеОбъекта.Реквизиты);
КоллекцияРеквизитов = МетаданныеОбъекта.Реквизиты;
Для каждого Реквизит Из КоллекцияРеквизитов Цикл
МассивИменРеквизитов.Добавить(Реквизит.Имя);
КонецЦикла;
КонецЦикла;
Для каждого ОбщийРеквизит Из Метаданные.ОбщиеРеквизиты Цикл
Если ИспользуетсяОбщийРеквизит(ОбщийРеквизит, МетаданныеОбъекта) Тогда
МассивИменРеквизитов.Добавить(ОбщийРеквизит.Имя);
КонецЕсли;
КонецЦикла;
Возврат МассивИменРеквизитов;
КонецФункции
Тогда программа будет выглядеть так:
ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
ДокОбъект = ДокСсылка.ПолучитьОбъект();
мМассивИмен = МассивИменРеквизитовОбъекта(ДокОбъект);
СтруктураНастроек = Новый Структура;
Для каждого эл Из мМассивИмен Цикл
СтруктураНастроек.Вставить(эл, эл);
КонецЦикла;
ЗначенияРеквизитов = ОбщегоНазначения.ПолучитьЗначенияРеквизитов(ДокСсылка , СтруктураНастроек);
СканПростойСтруктуры(ЗначенияРеквизитов);
Вспомогательная функция:
// Проверяет используется ли в Объекте указанный общий реквизит
//
Функция ИспользуетсяОбщийРеквизит(ОбщийРеквизит, Объект) Экспорт
Если ТипЗнч(Объект) = Тип("ОбъектМетаданных") Тогда
МетаданныеОбъекта = Объект;
Иначе
МетаданныеОбъекта = Метаданные.НайтиПоТипу(ТипЗнч(Объект));
Если МетаданныеОбъекта = Неопределено Тогда
Возврат Ложь;
КонецЕсли;
КонецЕсли;
Если ТипЗнч(ОбщийРеквизит) = Тип("ОбъектМетаданных") Тогда
МетаданныеОбщегоРеквизита = ОбщийРеквизит;
Иначе
МетаданныеОбщегоРеквизита = Метаданные.ОбщиеРеквизиты.Найти(ОбщийРеквизит);
Если МетаданныеОбщегоРеквизита = Неопределено Тогда
Возврат Ложь;
КонецЕсли;
КонецЕсли;
ЭлементСостава = МетаданныеОбщегоРеквизита.Состав.Найти(МетаданныеОбъекта);
Если ЭлементСостава = Неопределено Тогда
Возврат Ложь;
КонецЕсли;
пИспользованиеОбщегоРеквизита = Метаданные.СвойстваОбъектов.ИспользованиеОбщегоРеквизита;
Если ЭлементСостава.Использование = пИспользованиеОбщегоРеквизита.Использовать Тогда
Возврат Истина;
ИначеЕсли ЭлементСостава.Использование = пИспользованиеОбщегоРеквизита.НеИспользовать Тогда
Возврат Ложь;
Иначе
пАвтоИспользованиеОбщегоРеквизита = Метаданные.СвойстваОбъектов.АвтоИспользованиеОбщегоРеквизита;
Если МетаданныеОбщегоРеквизита.АвтоИспользование = пАвтоИспользованиеОбщегоРеквизита.Использовать Тогда
Возврат Истина;
Иначе
Возврат Ложь;
КонецЕсли;
КонецЕсли;
КонецФункции
Как получить значение отдельного реквизита объекта?
Иногда необязательно получать значения всего массива реквизитов. Программист как правило знает имя реквизита, значение которого необходимо получить. К отдельному реквизиту объекта можно обратиться просто по его имени:
Поставщик = ДокОбъект.Метаданные().Реквизиты.Поставщик;
Получить значение этого реквизита можно так же через запрос, написанный специально для этого реквизита. Но можно воспользоваться все той же функцией ПолучитьЗначенияРеквизитов(). Цикл для настройки структуры в этом случае не нужен, так как нам надо найти значение всего одного элемента:
ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
ДокОбъект = ДокСсылка.ПолучитьОбъект();
Организация = Строка(ДокОбъект.Метаданные().Реквизиты.Организация);
СтруктураНастроек = Новый Структура;
СтруктураНастроек.Вставить(Организация, Организация);
ЗначенияРеквизитов = ОбщегоНазначения.ПолучитьЗначенияРеквизитов(ДокСсылка , СтруктураНастроек);
СканПростойСтруктуры(ЗначенияРеквизитов);
Обратите внимание что здесь реквизит который необходимо найти преобразовывается к типу Строка, потому, что в структуру настроек надо передать именно строку.
Как найти имена реквизитов в таб части объекта?
Функция определяет есть ли реквизит в таб части документа:
// Позволяет определить есть ли среди реквизитов табличной части документа
// реквизит с переданным именем.
//
// Параметры:
// ИмяРеквизита - строковое имя искомого реквизита,
// МетаданныеДокумента - объект описания метаданных документа, среди реквизитов которого производится поиск.
// ИмяТабЧасти - строковое имя табличной части документа, среди реквизитов которого производится поиск
//
// Возвращаемое значение:
// Истина - нашли реквизит с таким именем, Ложь - не нашли.
//
Функция ЕстьРеквизитТабЧастиДокумента(ИмяРеквизита, МетаданныеДокумента, ИмяТабЧасти) Экспорт
ТабЧасть = МетаданныеДокумента.ТабличныеЧасти.Найти(ИмяТабЧасти);
Если ТабЧасть = Неопределено Тогда // Нет такой таб. части в документе
Возврат Ложь;
Иначе
Возврат НЕ (ТабЧасть.Реквизиты.Найти(ИмяРеквизита) = Неопределено);
КонецЕсли;
КонецФункции
Пример использования:
ИмяРеквизита = "Номенклатура";
МетаданныеДокумента = ДокОбъект.Метаданные();
ИмяТабЧасти = "Товары";
Если ЕстьРеквизитТабЧастиДокумента(ИмяРеквизита, МетаданныеДокумента, ИмяТабЧасти) Тогда
Сообщить("Реквизит есть!");
Иначе
Сообщить("Реквизита нет");
КонецЕсли;
Сообщить имя реквизитов таб части:
Для каждого Реквизит Из ДокОбъект.Метаданные().ТабличныеЧасти.Найти("Товары").Реквизиты Цикл
Собщить(Реквизит.Имя);
КонецЦикла;
Как найти значение всех реквизитов всех таб частей документа через запрос
Чтобы найти значения всех реквизитов всех табличных частей объекта через запрос воспользуемся функцией
ПолучитьЗначенияРеквизитовТабЧасти().
Функция ПолучитьЗначенияРеквизитовТабчасти(Ссылка, ИменаРеквизитов, ИмяТабЧасти) Экспорт
ИмяТЧ = ИмяТабЧасти;
ПолноеИмя = Ссылка.Метаданные().ПолноеИмя();
Если ТипЗнч(ИменаРеквизитов) = Тип("Структура") Тогда
СтруктураРеквизитов = ИменаРеквизитов;
ИначеЕсли ТипЗнч(ИменаРеквизитов) = Тип("Строка") Тогда
СтруктураРеквизитов = Новый Структура(ИменаРеквизитов);;
Иначе
ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
НСтр("ru = 'Неверный тип второго параметра ИменаИлиСтруктураРеквизитов: %1'"),
Строка(ТипЗнч(ИменаРеквизитов)));
КонецЕсли;
ТекстПолей = "";
Для Каждого КлючИЗначение Из СтруктураРеквизитов Цикл
ИмяПоля = ?(ЗначениеЗаполнено(КлючИЗначение.Значение), СокрЛП(КлючИЗначение.Значение), СокрЛП(КлючИЗначение.Ключ));
Псевдоним = СокрЛП(КлючИЗначение.Ключ);
ТекстПолей = ТекстПолей + ?(ПустаяСтрока(ТекстПолей), "", ",") + "
| " + ИмяПоля + " КАК " + Псевдоним;
КонецЦикла;
Запрос = Новый Запрос(
"ВЫБРАТЬ
|" + ТекстПолей + "
|ИЗ
| " + ПолноеИмя + "." + ИмяТЧ + " КАК ПсевдонимЗаданнойТаблицы
|ГДЕ
| ПсевдонимЗаданнойТаблицы.Ссылка = &Ссылка
|");
Запрос.УстановитьПараметр("Ссылка", Ссылка);
Результат = Запрос.Выполнить().Выгрузить();
Возврат Результат;
КонецФункции
Пример использования:
ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
ДокОбъект = ДокСсылка.ПолучитьОбъект();
МассивТабЧастей = Новый Массив;
Для каждого ТабЧасть Из ДокОбъект.Метаданные().ТабличныеЧасти Цикл
МассивТабЧастей.Добавить(ТабЧасть.Имя);
КонецЦикла;
Для Каждого ТабЧасть Из МассивТабЧастей Цикл
СтруктураНастроек = Новый Структура;
Для каждого Реквизит Из ДокОбъект.Метаданные().ТабличныеЧасти.Найти(ТабЧасть).Реквизиты Цикл
СтруктураНастроек.Вставить(Реквизит.Имя, Реквизит.Имя);
КонецЦикла;
Сообщить("Имя таб части: " + ТабЧасть);
ТабЗнач = ПолучитьЗначенияРеквизитовТабЧасти(ДокСсылка , СтруктураНастроек, ТабЧасть);
ПоказатьТаблицу(ТабЗнач);
КонецЦикла;
Вспомогательная функция:
функция ПоказатьТаблицу(Табл)
Сообщить("///Функция ПоказатьТаблицу///");
Количество = Табл.Колонки.Количество();
Для каждого Строка из Табл Цикл
Для Индекс = 0 По Количество-1 Цикл
Сообщить(СокрЛП(Индекс)+" "+СокрЛП(Табл.Колонки[Индекс].Имя)+ ": " + Строка[СокрЛП(Табл.Колонки[Индекс].Имя)]);
КонецЦикла;
КонецЦикла;
Сообщить("///Конец Функция ПоказатьТаблицу///");
КонецФункции
Результат для документа «Реализация товаров услуг»:
Имя таб части: Товары
///Функция ПоказатьТаблицу///
0 ЕдиницаИзмерения: шт
1 ЕдиницаИзмеренияМест:
2 Качество: Новый
3 Количество: 1
4 КоличествоМест: 0
5 Коэффициент: 1
6 Номенклатура: Вентилятор настольный
7 ПроцентСкидкиНаценки: 0
8 СерияНоменклатуры: Н-908, С-890 от 01.01.2003
9 СпособСписанияОстаткаТоваров: Со склада
10 СтавкаНДС: Без НДС
11 Сумма: 445,5
12 СуммаНДС: 0
13 ХарактеристикаНоменклатуры:
14 Цена: 450
15 Склад: Магазин «Бытовая техника»
16 ПроцентАвтоматическихСкидок: 1
17 УсловиеАвтоматическойСкидки: По виду дисконтных карт
18 ЗначениеУсловияАвтоматическойСкидки: Серебряная карта
19 КлючСтроки: 3
20 КлючСвязи: 0
21 ЗаказПокупателя: Заказ покупателя ТД000000001 от 08.06.2008 12:00:00
0 ЕдиницаИзмерения: шт
1 ЕдиницаИзмеренияМест:
2 Качество: Новый
3 Количество: 1
4 КоличествоМест: 0
5 Коэффициент: 1
6 Номенклатура: Набор вентиляторов
7 ПроцентСкидкиНаценки: 0
8 СерияНоменклатуры:
9 СпособСписанияОстаткаТоваров: Со склада
10 СтавкаНДС: Без НДС
11 Сумма: 1948,32
12 СуммаНДС: 0
13 ХарактеристикаНоменклатуры:
14 Цена: 1968
15 Склад: Магазин «Бытовая техника»
16 ПроцентАвтоматическихСкидок: 1
17 УсловиеАвтоматическойСкидки: По виду дисконтных карт
18 ЗначениеУсловияАвтоматическойСкидки: Серебряная карта
19 КлючСтроки: 4
20 КлючСвязи: 0
21 ЗаказПокупателя: Заказ покупателя ТД000000001 от 08.06.2008 12:00:00
///Конец Функция ПоказатьТаблицу///
Имя таб части: ВозвратнаяТара
///Функция ПоказатьТаблицу///
///Конец Функция ПоказатьТаблицу///
Имя таб части: Услуги
///Функция ПоказатьТаблицу///
///Конец Функция ПоказатьТаблицу///
Имя таб части: СоставНабора
///Функция ПоказатьТаблицу///
0 Номенклатура: Вентилятор BINATONE ALPINE 160вт, напольный ,
1 ХарактеристикаНоменклатуры:
2 СерияНоменклатуры: 01234/11020/7654321, БОЛГАРИЯ
3 Количество: 1
4 ЕдиницаИзмерения: шт
5 Склад: Магазин «Бытовая техника»
6 Качество: Новый
7 СпособСписанияОстаткаТоваров: Со склада
8 КлючСтроки: 4
9 Цена: 1068
10 КлючСвязи: 0
0 Номенклатура: Вентилятор JIPONIC (Тайв.),
1 ХарактеристикаНоменклатуры:
2 СерияНоменклатуры: 11234/11020/7654321, ТАЙВАНЬ (КИТАЙ)
3 Количество: 1
4 ЕдиницаИзмерения: шт
5 Склад: Магазин «Бытовая техника»
6 Качество: Новый
7 СпособСписанияОстаткаТоваров: Со склада
8 КлючСтроки: 4
9 Цена: 900
10 КлючСвязи: 0
///Конец Функция ПоказатьТаблицу///
Имя таб части: СерийныеНомера
///Функция ПоказатьТаблицу///
///Конец Функция ПоказатьТаблицу///
Имя таб части: СерийныеНомераСоставНабора
///Функция ПоказатьТаблицу///
///Конец Функция ПоказатьТаблицу///
Имя таб части: ДокументыРасчетовСКонтрагентом
///Функция ПоказатьТаблицу///
///Конец Функция ПоказатьТаблицу///
В этой статье разберем метаданные 1С. Метаданные или объекты метаданных в 1С – это «кирпичики», из которых строится конфигурация 1С. Узнаем, что такое метаданные (объекты метаданных) и научимся получать значения свойств объектов метаданных.
В учебной конфигурации, справочник Номенклатура – это объект метаданных. Документ Закупка товаров – тоже объект метаданных.
Все объекты метаданных 1С перечислены в дереве конфигурации.
У объектов метаданных имеются прототипы. Визуально в дереве конфигурации прототипы представлены в виде веток дерева.
Например, у справочника Номенклатура прототип Справочники.
А у документа Закупка товаров – прототип Документы.
У объектов одного прототипа похожие свойств и методы. Кроме принадлежности к прототипу свойства и методы объектов метаданных определяются дополнительными характеристиками. Например, включена у справочников иерархия или нет.
В процессе конфигурирования разработчик настраивает свойства объектов метаданных. Например, длина кода справочника 1С это свойство. В учебной конфигурации у справочника Номенклатура длина кода 9.
А у справочника Валюта – 3.
На свойства объекта метаданных можно посмотреть, как в редакторе объекта. Редактор открывается при двойном клике мышкой по объекту. Так и в палитре свойств объекта. Для того, чтобы открыть палитру свойств, следует выделить объект, вызвать контекстное меню и выполнить команду «Свойства».
После, справа откроется палитра свойств объекта метаданных, в которой можно прочитать или отредактировать разные свойства объекта. Например, длину наименования.
К свойствам объектов метаданных можно обратиться при помощи программного кода. Сделать это можно воспользовавшись свойством глобального контекста, которое так и называется Метаданные.
Это свойство является коллекцией объектов метаданных и включает в себя все метаданные конфигурации 1С, которые даже не созданы.
У свойства Метаданные имеются свойства, которые отображают прототипы объектов. Это тоже коллекции. Например, для справочников имеется свое свойство.
Которое, также является коллекцией.
В этой коллекции содержатся все объекты метаданных, которые входят в ветку Справочники дерева конфигурации 1С.
Мы можем прочитать свойство того или иного объекта метаданных. Например, длину кода у справочника Валюта.
Поскольку свойство Метаданные и его свойства, которые соответствуют прототипам, являются коллекциями, то их можно обойти циклом.
Например, обойдем циклом справочники и выведем имя справочника, синоним и длину кода.
Для Каждого стрСправочника из Метаданные.Справочники Цикл Сообщить("Имя " + стрСправочника.Имя + ", синоним: " + стрСправочника.Синоним + " (длина кода: " + стрСправочника.ДлинаКода + ")"); КонецЦикла;
В учебной конфигурации, у этого кода будет следующий результат.
Обратите внимание, что этот код должен выполняться в серверном контексте (или в клиентском на толстом клиенте), поскольку у свойства Метаданные доступность Сервер, Толстый клиент и т.д.
Кроме свойств объекта можно получить доступ к свойствам реквизитов при помощи всё того же свойства глобального контекста Метаданные. Для того, чтобы обратиться к реквизитам объекта, необходимо получить доступ к этому объекту посредством свойства глобального контекста Метаданные, а потом уже обратиться к свойству Реквизиты полученного объекта.
Например, к реквизитам конкурентного справочника можно обратиться так:
РеквизитыСправочника = Метаданные.Справочники.Контрагенты.Реквизиты;
А к реквизитам конкурентного документа – так:
РеквизитыДокумента = Метаданные.Документы.ЗакупкаТоваров.Реквизиты;
Получаемые реквизиты являются коллекцией, которая содержит все реквизиты объекта. Её также можно обойти циклом и прочитать тот или иной реквизит.
РеквизитыДокумента = Метаданные.Документы.ЗакупкаТоваров.Реквизиты; Сообщить("Выводим реквизиты документа " + Метаданные.Документы.ЗакупкаТоваров.Синоним); Для Каждого стрРеквизит из РеквизитыДокумента Цикл Сообщить(" Имя: " + стрРеквизит.Имя + ", синоним " + стрРеквизит.Синоним); КонецЦикла;
Результат работы этого кода в учебной конфигурации будет следующим.
Некоторые свойства объектов имеют перечисленный тип, т.е. перечисление определенных значений. Например, у документов имеется свойство Проведение. У этого свойства есть несколько значений: Разрешить и Запретить. Свойство Проведение и является перечисленным типом.
При помощи свойства глобального контекста Метаданные мы можем проверить какое значение перечисленного типа установлено у того или иного объекта. Для этого нужно воспользоваться свойством СвойстваОбъектов. Оно содержит в себе все перечисленные типы и их значения.
Мы можем сравнить значение перечисленного типа в реквизите объекта метаданных со значением из коллекции соответствующего типа в свойстве СвойстваОбъектов. Например, выведем все документы и сообщим можно эти документы проводить или нельзя.
Для Каждого стрДокумент Из Метаданные.Документы Цикл Сообщить("Выводим " + стрДокумент.Представление() + "(" + стрДокумент.ПолноеИмя() + ")"); Если СтрДокумент.Проведение = Метаданные.СвойстваОбъектов.Проведение.Разрешить Тогда Сообщить(Символы.Таб + "Документ можно проводить"); ИначеЕсли СтрДокумент.Проведение = Метаданные.СвойстваОбъектов.Проведение.Запретить Тогда Сообщить(Символы.Таб + "Документ нельзя проводить"); КонецЕсли; КонецЦикла;
Как вы видите, при помощи свойства глобального контекста Метаданные можно получать очень подробную информацию об объектах конфигурации, эта информация может вам пригодиться при написании различных алгоритмов.
Читайте также по теме:
Объект в 1С
Ссылка в 1С
Более подробно и основательно начальные вопросы программирования в 1С есть вы можете изучить в
Книга «Программировать в 1С за 11 шагов»
Изучайте программирование в 1С в месте с моей книгой «Программировать в 1С за 11 шагов»
Книга написана понятным и простым языком — для новичка.
- Книга посылается на электронную почту в формате PDF. Можно открыть на любом устройстве!
- Научитесь понимать архитектуру 1С;
- Станете писать код на языке 1С;
- Освоите основные приемы программирования;
- Закрепите полученные знания при помощи задачника
О том как разрабатывать под управляемым приложением 1С, читайте в книге Книга «Основы разработки в 1С: Такси»
Отличное пособие по разработке в управляемом приложении 1С, как для начинающих разработчиков, так и для опытных программистов.
- Очень доступный и понятный язык изложения
- Книга посылается на электронную почту в формате PDF. Можно открыть на любом устройстве!
- Поймете идеологию управляемого приложения 1С
- Узнаете, как разрабатывать управляемое приложение;
- Научитесь разрабатывать управляемые формы 1С;
- Сможете работать с основными и нужными элементами управляемых форм
- Программирование под управляемым приложением станет понятным
Промо-код на скидку в 15% — 48PVXHeYu
Эти книги, плюс книга по программированию оперативного учета имеются в едином комплекте: комплект книг по разработке в 1С.
Только для читателей моего блога,
промо-код на скидку в 300 рублей на весь комплект: blog
Если Вам понравился этот урок, был полезен или помог решить какую-нибудь проблему, то Вы можете поддержать мой проект, перечислив любую сумму.
можно оплатить вручную:
Яндекс.Деньги — 410012882996301
Web Money — R955262494655
Вступайте в мои группы:
Вконтакте: https://vk.com/1c_prosto
Фейсбуке: https://www.facebook.com/groups/922972144448119/
ОК: http://ok.ru/group/52970839015518
Твиттер: https://twitter.com/signum2009
0
Функция возвращает ссылку на заданный реквизит объекта метаданных Документ
// Документ - ссылка на документ, Реквизит - название реквизита, например "Контрагент"
Функция гРеквизитДокумента(Документ,Реквизит) Экспорт
Если Метаданные.Документ(Документ).РеквизитШапки(Реквизит).Выбран()=1 Тогда
Возврат Метаданные.Документ(Документ).РеквизитШапки(Реквизит);
ИначеЕсли Метаданные.Документ(Документ).РеквизитТабличнойЧасти(Реквизит).Выбран()=1 Тогда
Возврат Метаданные.Документ(Документ).РеквизитТабличнойЧасти(Реквизит);
ИначеЕсли Метаданные.ОбщийРеквизитДокумента(Реквизит).Выбран()=1 Тогда
Возврат Метаданные.ОбщийРеквизитДокумента(Реквизит);
КонецЕсли;
КонецФункции Не так давно пришлось приводить конфигурацию заказчика в соответствие с законом «О защите персональных данных», который гласит, что при отказе клиенту в одобрении заявки все личные данные о нем должны удаляться из информационной системы обработки персональных данных, которой является 1С. Реквизитов и таблиц с личными данными было достаточно много, поэтому вручную прописывать очистку было нецелесообразно. А удалять сам элемент справочника было нельзя, потому что к нему был привязан документ рассмотрения заявки, и удаление нарушило бы логическую целостность информационной базы.
Поэтому необходим был механизм, который позволил бы получить полный список реквизитов и табличных частей. Для этого у объектов 1С существует встроенная функция Метаданные().
Эта функция возвращает значение особого типа — ОбъектМетаданных. В нем содержатся практически все свойства объекта. Например для элемента справочника это будут: длина наименования и кода, автонумерация, основные формы, вообще все существующие формы, представление объекта, иерархичность, макеты и многое другое.
В нашем случае потребуются Реквизиты и Табличные части. Эти компоненты метаданных содержат значение КоллекцияОбъектовМетаданных, которую можно обойти в цикле Для каждого.
У каждого из элементов коллекции тоже много свойств, в частности есть очень полезное свойство Тип, через которое можно получить тип того или иного реквизита. Полный список свойств можно узнать, например, в режиме отладки через команду Вычислить выражение. Мне же для обращения к реквизиту или табличной части потребуется свойство Имя.
В итоге модуль, очищающий реквизиты и табличные части, выглядит так:
Контрагент=КонтрагентСсылка.ПолучитьОбъект();
//Переменная КонтрагентСсылка должна содержать ссылку на элемент</p>
Для Каждого Реквизит Из Контрагент.Метаданные().Реквизиты Цикл
Контрагент[Реквизит.Имя] = Неопределено;
КонецЦикла;
Для Каждого ТаблЧасть Из Контрагент.Метаданные().ТабличныеЧасти Цикл
Контрагент[ТаблЧасть.Имя].Очистить();
КонецЦикла;
Контрагент.Записать();
Функция Метаданные() применяется как для самого объекта, так и для ссылки на него. В нашем случае необходимо было изменить значения реквизитов, поэтому объект нужно было получить. Данная функция работает не только для справочников, но и для других объектов конфигурации 1С, но состав свойств будет иным.
Приведенный в заметке пример — это только один из многочисленных способов применения функции Метаданные(). Другие варианты и проблемы с использованием метаданных готов обсудить в комментариях.
Довольно часто в алгоритмах приходится обращаться к значениям реквизитов различных объектов «через точку». При этом, если объект ссылочного типа, то возможно многократное обращение к БД. В данной статье попробуем унифицировать и оптимизировать этот процесс.
Общий принцип оптимизации заключается в сокрашении количества обращений к базе данных. Для этого в линейном алгоритме анализируем, что за объект перед нами, если это ссылка, то описываем запрос, с помощью которого получаем все данные и в дальнейшем работаем с результатом запроса.
Задача: Описать функции позволяющие получить значения реквизитов различных объектов (независимо от типа объекта). Но ограничимся объектами метаданных конфигурации, которые могут иметь ссылочный тип данных: Справочники, Документы и т.п.
Описанные далее функции желательно располагать в общем серверном модуле без возможности вызова сервера. Если будет возможность вызывать данные функции с клиента, то злоумышленник сможет получить любые данные из базы без особого труда.
Определимся с параметрами:
- Объект — объект, данные которого необходимо получить;
- ИменаРеквизитов — Список имен реквизитов, данные которых необходимо получить. Если спиок не указан, то предполагаем, что нужно получить данные всех реквизитов;
- ДополнительныеРеквизиты — Структура, с помошью которой можно было бы описать дополнительные данные, которые нужно получить вместе с реквизитами объекта (без использования явных соединений с другими таблицами) или выполнение каких-то действий с полями выборки на языке запросов. В ключе элемента структуры описываем имя реквизита в общем списке реквизитов объекта, в значении — поле выборки или алгоритм обработки полей выборки на языке запросов.
Функция ДанныеРеквизитовОбъекта(Объект, ИменаРеквизитов = Неопределено,
ДополнительныеРеквизиты = Неопределено) Экспорт
Разберем, значения каких реквизитов необходимо получить из базы и приведем список имен к типу данных Массив.
СтруктураОбъекта = Новый Структура;
МетаданныеОбъекта = Объект.Метаданные();
Если ИменаРеквизитов = Неопределено тогда
МассивИменРеквизитов = МассивИменРеквизитовОбъекта(Объект);
иначе
Если ТипЗнч(ИменаРеквизитов) = Тип(«Массив») тогда
МассивИменРеквизитов = ИменаРеквизитов;
иначеЕсли ТипЗнч(ИменаРеквизитов) = Тип(«Строка») тогда
МассивИменРеквизитов = МассивПодстрокИзСтроки(ИменаРеквизитов);
КонецЕсли;
КонецЕсли;
Если список имен не задан, то с помощью функции МассивИменРеквизитовОбъекта() получим массив имен всех реквизитов объекта (алгоритм этой функции смотри ниже).
Если список имен задан в виде строки разделенной запятыми, то разложим ее на подстроки с помошью функции МассивПодстрокИзСтроки(). Это не сложная задача, алгоритм этой функции разбирать не будем.
Далее с помошью функции ЭтоСсылка() определим, является ли объект ссылочным типом. Для ссылочных типов значения необходимо получить из БД, в противном случае значения реквизитов хранятся в памяти.
ЭтоСсылка = ЭтоСсылка(Объект);
СсылкаОбъекта = ?(ЭтоСсылка, Объект, Объект.Ссылка);
ПолучитьДанныеИзОбъекта = НЕ ЭтоСсылка;
Если ЭтоСсылка И СсылкаОбъекта.Пустая() тогда
// это пустая ссылка (данных в базе нет)
ПолучитьДанныеИзОбъекта = Истина;
КонецЕсли;
Теперь, если данные объекта хранятся в памяти — мы можем их сразу получить, в противном случае необходио подготовиться для составления запроса к БД (переведем список имен реквизитов из типа данных Массив в тип Структура).
ОсновныеРеквизиты = Новый Структура;
Для каждого ИмяРеквизита Из МассивИменРеквизитов Цикл
Если ПолучитьДанныеИзОбъекта тогда
СтруктураОбъекта.Вставить(ИмяРеквизита, Объект[ИмяРеквизита]);
иначе
ОсновныеРеквизиты.Вставить(ИмяРеквизита);
КонецЕсли;
КонецЦикла;
Все готово к составлению запроса чтобы получить значения реквизитов если перед нами объект ссылочного типа, а так же для получения дополнительных реквизитов, описанных в 3-ем параметре функции. Но смысл всех этих действий есть, только если данный объект существует в БД (на него есть ссылка).
Для начала составим текст запроса для полей выборки поочередно обходя структуры Основных и Дополнительных реквизитов
Если НЕ СсылкаОбъекта.Пустая() тогда
// сформируем текст выборки по реквизитам
ТекстВыборкиРеквизиты = «»;
Для индекс = 0 по 1 Цикл
СтруктураРеквизитов = ?(индекс = 0, ОсновныеРеквизиты, ДополнительныеРеквизиты);
Если СтруктураРеквизитов = Неопределено тогда
Продолжить;
КонецЕсли;
Для каждого ЭлементСтруктуры из СтруктураРеквизитов Цикл
Если НЕ МетаданныеОбъекта.ТабличныеЧасти.Найти(ЭлементСтруктуры.Ключ) = Неопределено тогда
// это имя табличной части
Продолжить;
КонецЕсли;
ТекстВыборкиРеквизиты = ТекстВыборкиРеквизиты
+ ?(ПустаяСтрока(ТекстВыборкиРеквизиты), «», «,» + Символы.ПС)
+ ?(ЗначениеЗаполнено(ЭлементСтруктуры.Значение), ЭлементСтруктуры.Значение, ЭлементСтруктуры.Ключ)
+ » КАК » + ЭлементСтруктуры.Ключ;
КонецЦикла;
КонецЦикла;
Теперь соберем текст запроса и выполним его. Результат запроса добавим в общую структуру данных объекта
// получим реквизиты одним запросом
Если НЕ ПустаяСтрока(ТекстВыборкиРеквизиты) тогда
Запрос = Новый Запрос;
Запрос.Текст = «ВЫБРАТЬ
|» + ТекстВыборкиРеквизиты + «
|ИЗ
| » + МетаданныеОбъекта.ПолноеИмя() + «
|ГДЕ
| Ссылка = &Ссылка»;
Запрос.УстановитьПараметр(«Ссылка», СсылкаОбъекта);
РезультатЗапроса = Запрос.Выполнить();
Выборка = РезультатЗапроса.Выбрать();
Если Выборка.Следующий() тогда
Для каждого Колонка из РезультатЗапроса.Колонки Цикл
СтруктураОбъекта.Вставить(Колонка.Имя, Выборка[Колонка.Имя]);
КонецЦикла;
КонецЕсли;
КонецЕсли;
КонецЕсли;
Все данные получены, можно завершать функцию
Возврат СтруктураОбъекта;
КонецФункции // ДанныеРеквизитовОбъекта()
Достоинства алгоритма:
- Может работать с различными типами объектов конфигурации (которые могут иметь ссылки: Справочники, Документы, ПВХ и т.п.);
- Получение всех реквизитов за одно обращение к БД;
- Данные возвращаются в виде структуры, что позволяет их передать далее на клиент без преобразования;
- С помошью Дополнительных реквизитов можно получить вспомогательные данные (обращение к полям выборки через несколько точек) или на уровне запроса выполнить какие-то действия с данными.
- Наглядность кода, данные получаются одной функцией, без надобности каждый раз писать запрос к БД с обработкой результата.
Недостатки:
- Не реализована возможность получения табличных частей объектов
Дополнительные функции использованные в алгоритме:
// Возвращает массив имен всех реквизитов переданного объекта
//
Функция МассивИменРеквизитовОбъекта(Объект) Экспорт
МассивИменРеквизитов = Новый Массив;
Если ТипЗнч(Объект) = Тип(«ОбъектМетаданных») тогда
МетаданныеОбъекта = Объект;
иначе
МетаданныеОбъекта = Метаданные.НайтиПоТипу(ТипЗнч(Объект));
Если МетаданныеОбъекта = Неопределено тогда
Возврат МассивИменРеквизитов;
КонецЕсли;
КонецЕсли;
Для индекс = 0 по 1 Цикл
КоллекцияРеквизитов = ?(индекс = 0, МетаданныеОбъекта.СтандартныеРеквизиты, МетаданныеОбъекта.Реквизиты);
Для Каждого Реквизит Из КоллекцияРеквизитов Цикл
МассивИменРеквизитов.Добавить(Реквизит.Имя);
КонецЦикла;
КонецЦикла;
Для каждого ОбщийРеквизит Из Метаданные.ОбщиеРеквизиты Цикл
Если ИспользуетсяОбщийРеквизит(ОбщийРеквизит, МетаданныеОбъекта) тогда
МассивИменРеквизитов.Добавить(ОбщийРеквизит.Имя);
КонецЕсли;
КонецЦикла;
Возврат МассивИменРеквизитов;
КонецФункции
// Проверяет используется ли в Объекте указанный общий реквизит
//
Функция ИспользуетсяОбщийРеквизит(ОбщийРеквизит, Объект) Экспорт
Если ТипЗнч(Объект) = Тип(«ОбъектМетаданных») тогда
МетаданныеОбъекта = Объект;
иначе
МетаданныеОбъекта = Метаданные.НайтиПоТипу(ТипЗнч(Объект));
Если МетаданныеОбъекта = Неопределено тогда
Возврат Ложь;
КонецЕсли;
КонецЕсли;
Если ТипЗнч(ОбщийРеквизит) = Тип(«ОбъектМетаданных») тогда
МетаданныеОбщегоРеквизита = ОбщийРеквизит;
иначе
МетаданныеОбщегоРеквизита = Метаданные.ОбщиеРеквизиты.Найти(ОбщийРеквизит);
Если МетаданныеОбщегоРеквизита = Неопределено тогда
Возврат Ложь;
КонецЕсли;
КонецЕсли;
ЭлементСостава = МетаданныеОбщегоРеквизита.Состав.Найти(МетаданныеОбъекта);
Если ЭлементСостава = Неопределено тогда
Возврат Ложь;
КонецЕсли;
пИспользованиеОбщегоРеквизита = Метаданные.СвойстваОбъектов.ИспользованиеОбщегоРеквизита;
Если ЭлементСостава.Использование = пИспользованиеОбщегоРеквизита.Использовать тогда
Возврат Истина;
иначеЕсли ЭлементСостава.Использование = пИспользованиеОбщегоРеквизита.НеИспользовать тогда
Возврат Ложь;
иначе
пАвтоИспользованиеОбщегоРеквизита = Метаданные.СвойстваОбъектов.АвтоИспользованиеОбщегоРеквизита;
Если МетаданныеОбщегоРеквизита.АвтоИспользование = пАвтоИспользованиеОбщегоРеквизита.Использовать тогда
Возврат Истина;
иначе
Возврат Ложь;
КонецЕсли;
КонецЕсли;
КонецФункции
Универсальные процедуры и функции (метаданные)¶
Возвращает полное имя объекта метаданных по переданному значению ссылки¶
// Возвращает полное имя объекта метаданных по переданному значению ссылки
// Например,
// "Справочник.Номенклатура";
// "Документ.ПриходнаяНакладная"
//
// Параметры:
// Ссылка - ЛюбаяСсылка - значение ссылки, для которого необходимо получить имя таблицы ИБ
//
// Возвращаемое значение:
// Строка - полное имя объекта метаданных для указанного значения ссылки
//
Функция ИмяТаблицыПоСсылке(Ссылка) Экспорт
Возврат Метаданные.НайтиПоТипу(ТипЗнч(Ссылка)).ПолноеИмя();
КонецФункции
Получение реквизитов объектов (справочников и документов)¶
Получения реквизитов документа:
Для Каждого Реквизит Из Документ.Метаданные().Реквизиты Цикл
НоваяСтрока = РеквизитыДокумента.Добавить();
НоваяСтрока.Реквизит = Реквизит.Имя;
НоваяСтрока.Значение = Документ[Реквизит.Имя];
КонецЦикла;
РеквизитыДокумента — таблица значений с двумя полями «Реквизит» и «Значение».
Получение табличных частей документа и их реквизитов:
Для Каждого ТабличнаяЧасть Из Документ.Метаданные().ТабличныеЧасти Цикл
Сообщить(ТабличнаяЧасть);
Для Каждого РеквизитТЧ Из ТабличнаяЧасть.Реквизиты Цикл
Сообщить(" - " + РеквизитТЧ);
КонецЦикла
КонецЦикла;