Как работать с реквизитом таблица значений

&НаСервере
Процедура ВыполнитьКодНаСервере()
 
    /// Как создать таблицу значений в 1с 8.3, 8.2
 
    // с таблицей значений можно работать только на сервере 
    Таб = Новый ТаблицаЗначений;    
 
    /// Как добавить колонки в таблицу значений в 1с 8.3, 8.2
 
    Таб.Колонки.Добавить("Фрукт");
    Таб.Колонки.Добавить("Цвет");
    Таб.Колонки.Добавить("Вкус");
 
    /// Как добавить строки в таблицу значений в 1с 8.3, 8.2
 
    Стр = Таб.Добавить();
    Стр.Фрукт = "Яблоко";
    Стр.Цвет = "Зелёный";
    Стр.Вкус = "Кислый";
 
    Стр = Таб.Добавить();
    Стр.Фрукт = "Банан";
    Стр.Цвет = "Желтый";
    Стр.Вкус = "Сладкий";
 
    Стр = Таб.Добавить();
    Стр.Фрукт = "Слива";
    Стр.Цвет = "Синий";
    Стр.Вкус = "Терпкий"; 
 
    /// Как добавить в таблицу значений колонку с
    /// описанием типа и заголовка в 1с 8.3, 8.2
 
    ОписаниеВеса = Новый ОписаниеТипов("Число",
        Новый КвалификаторыЧисла(12, 3));
 
    Таб.Колонки.Добавить("ВесФрукта", ОписаниеВеса, "Вес фрукта");
    Таб[0].ВесФрукта = 100.005;
    Таб[1].ВесФрукта = 60.010;
    Таб[2].ВесФрукта = 25.000;
 
    /// Как перечислить все строки в таблице значений в 1с 8.3, 8.2
 
    Для Каждого Стр Из Таб Цикл
        Сообщить(Стр.Фрукт + " " + Стр.Цвет + " " + Стр.Вкус +
            " " + Стр.ВесФрукта);
    КонецЦикла;
 
    /// Как перечислить все колонки в таблице значений
    /// в 1с 8.3, 8.2
 
    Для Каждого Колонка Из Таб.Колонки Цикл
        Сообщить(Колонка.Имя);
    КонецЦикла; 
 
    /// Как выгрузить колонку таблицы значений в массив в 1с 8.3, 8.2
 
    // выгрузка названий фруктов в массив
    МассивФруктов = Таб.ВыгрузитьКолонку("Фрукт");
 
    // ничего не измениться, так как массив не менялся
    Таб.ЗагрузитьКолонку(МассивФруктов, "Фрукт");
 
    /// Как заполнить значения в колонке для всех строк таблицы 
    /// значений в 1с 8.3, 8.2
 
    // обнулим вес во всех строках
    Таб.ЗаполнитьЗначения(0, "ВесФрукта");
 
    // выставим новые веса
    Таб[0].ВесФрукта = 100;
    Таб[1].ВесФрукта = 60;
    Таб[2].ВесФрукта = 25;
 
    /// Как в таблице значений посчитать итог по колонке в 1с 8.3, 8.2
 
    Сообщить(Таб.Итог("ВесФрукта")); // 185
 
    /// Как найти строку в таблице значений по значению в 1с 8.3, 8.2
 
    // найдём строчку с яблоком и покажем его цвет
    НайденнаяСтрока = Таб.Найти( "Яблоко" );
    Если НайденнаяСтрока <> Неопределено Тогда
        Сообщить(НайденнаяСтрока.Цвет); // Зелёный
    КонецЕсли;
 
    /// Как найти строку в таблице значений поиском значения
    /// в определенных колонках в 1с 8.3, 8.2
 
    // будем искать по слову "Кислый" в колонках вкус и цвет
    НайденнаяСтрока = Таб.Найти("Кислый", "Вкус, Цвет");
    Если НайденнаяСтрока <> Неопределено Тогда
        Сообщить(НайденнаяСтрока.Фрукт); // Яблоко
    КонецЕсли;
 
    // добавим ещё один зелёный фрукт
    Стр = Таб.Добавить();
    Стр.Фрукт = "Киви";
    Стр.Цвет = "Зелёный";
    Стр.Вкус = "Сладкий";
    Стр.ВесФрукта = 30;
 
    /// Как искать в таблице значений неуникальные значения
    /// в 1с 8.3, 8.2
 
    Отбор = Новый Структура;
    Отбор.Вставить("Цвет", "Зелёный");
    Строки = Таб.НайтиСтроки(Отбор);
    Для Каждого Стр Из Строки Цикл
        Сообщить(Стр.Фрукт); // Яблоко Киви
    КонецЦикла;
 
    /// Как сдвинуть строку таблицы значений в 1с 8.3, 8.2
 
    // сдвигаем первую строку на одну позицию вперёд
    Таб.Сдвинуть(0, 1);
 
    // и возвращаем обратно
    Таб.Сдвинуть(1, -1);
 
    /// Как создать копию таблицы значений в 1с 8.3, 8.2
 
    // полная копия
    КопияТаб = Таб.Скопировать();
 
    /// Как создать копию таблицы значений по нужным колонкам
    /// в 1с 8.3, 8.2
 
    // только две колонки будет Фрукт и Цвет
    КопияТаб = Таб.СкопироватьКолонки("Фрукт, Цвет");
 
    /// Как создать копию таблицы значений по отбору в 1с 8.3, 8.2
 
    Отбор = Новый Структура;
    Отбор.Вставить("Фрукт", "Яблоко");
 
    // таблица будет содержать только строчку с яблоком
    КопияТаб = Таб.Скопировать(Отбор);
 
    // таблица будет содержать цвет и вес яблока
    КопияТаб = Таб.Скопировать(Отбор, "Цвет, ВесФрукта");
 
    /// Как свернуть таблицу значений по колонке в 1с 8.3, 8.2
 
    // свернём по вкусу, просуммируем по весу
    Таб.Свернуть("Вкус", "ВесФрукта");
 
    /// Как отсортировать таблицу значений по колонке в 1с 8.3, 8.2
 
    Таб.Сортировать("ВесФрукта Возр");
 
    /// Как отсортировать таблицу значений по нескольким колонкам
    /// в 1с 8.3, 8.2
 
    Таб.Сортировать("ВесФрукта Возр, Вкус Убыв");
 
    /// Как удалить строку из таблицы значений в 1с 8.3, 8.2
 
    // по индексу или по значению
    Таб.Удалить(0);
 
КонецПроцедуры
 
/// Как программно вывести таблицу значений на
/// форму в 1с 8.3, 8.2 
 
// см. примеры использования этой функции ниже
 
// ТабВКоде - таблица значений, созданная программно
// ТабРеквизит - имя реквизита формы типа ТаблицаЗначений
// ТабНаФорме - имя элемента формы, связанного с ТабРеквизит 
 
&НаСервере
Процедура ВывестиТаблицуЗначенияВКодеВТаблицуНаФорме(ТабВКоде, ТабРеквизит, ТабНаФорме)
 
    // реквизит ТабРеквизит и соответствующий
    // ему элемент формы ТабНаФорме уже созданы
    // нами в визуальном режиме
 
    // 1. добавляем колонки из ТабВкоде в реквизит ТабРеквизит
 
    НовыеРеквизиты = Новый Массив;
 
    Для Каждого Колонка Из ТабВКоде.Колонки Цикл
         НовыеРеквизиты.Добавить(
            Новый РеквизитФормы(
                Колонка.Имя, Колонка.ТипЗначения,
                ТабРеквизит
            )
         );
    КонецЦикла;
 
    ИзменитьРеквизиты(НовыеРеквизиты);
 
    // 2. добавляем колонки из ТабВКоде в элемент ТабНаФорме
 
    Для Каждого Колонка Из ТабВКоде.Колонки Цикл
 
        НовыйЭлемент = Элементы.Добавить(
            ТабРеквизит + "_" + Колонка.Имя, Тип("ПолеФормы"), Элементы[ТабНаФорме]
        );
        НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;
        НовыйЭлемент.ПутьКДанным = ТабРеквизит + "." + Колонка.Имя;
    КонецЦикла;
 
    // 3. наконец, передаём данные из ТабВКоде в ТабРеквизит
 
    ЗначениеВРеквизитФормы(ТабВКоде, ТабРеквизит);
 
    // готово!    
 
КонецПроцедуры
 
&НаСервере
Процедура СоздатьТаблицуНаФормеНаСервере()
 
    // программно создаём таблицу значений ТабВКоде
 
    ТабВКоде = Новый ТаблицаЗначений;
 
    ОписаниеСтроки = Новый ОписаниеТипов("Строка");
    ОписаниеВеса = Новый ОписаниеТипов("Число",
        Новый КвалификаторыЧисла(12, 3));
 
    ТабВКоде.Колонки.Добавить("Фрукт", ОписаниеСтроки, "Имя фрукта");
    ТабВКоде.Колонки.Добавить("Цвет", ОписаниеСтроки, "Цвет фрукта");
    ТабВКоде.Колонки.Добавить("Вес", ОписаниеВеса, "Вес фрукта");
 
    Стр = ТабВКоде.Добавить();
    Стр.Фрукт = "Яблоко";
    Стр.Цвет = "Зелёный";
    Стр.Вес = 200;
 
    Стр = ТабВКоде.Добавить();
    Стр.Фрукт = "Банан";
    Стр.Цвет = "Желтый";
    Стр.Вес = 150;
 
    ВывестиТаблицуЗначенияВКодеВТаблицуНаФорме(ТабВКоде, "ТабРеквизит1", "ТабНаФорме1");
 
КонецПроцедуры
 
/// Как программно вывести на форму результат запроса
/// в виде таблицы значений в 1с 8.3, 8.2
 
&НаСервере
Процедура ВывестиНаФормуРезультатЗапросаНаСервере()        
 
    Запрос = Новый Запрос;
    Запрос.Текст = 
        "ВЫБРАТЬ
        |   Товары.Ссылка,
        |   Товары.ВерсияДанных,
        |   Товары.ПометкаУдаления,
        |   Товары.Код,
        |   Товары.Наименование,
        |   Товары.Цвет,
        |   Товары.ЕдиницаИзмерений,
        |   Товары.Предопределенный,
        |   Товары.ИмяПредопределенныхДанных
        |ИЗ
        |   Справочник.Товары КАК Товары";
 
    РезультатЗапроса = Запрос.Выполнить();
 
    ТабВКоде = РезультатЗапроса.Выгрузить(ОбходРезультатаЗапроса.Прямой);   
 
    // функция ВывестиТаблицуЗначенияВКодеВТаблицуНаФорме определена выше
    ВывестиТаблицуЗначенияВКодеВТаблицуНаФорме(ТабВКоде, "ТабРеквизит2", "ТабНаФорме2");
 
КонецПроцедуры
 
/// Скачать и выполнить эти примеры на компьютере

ТаблицаЗначений — это программный объект встроенного языка, позволяющий строить произвольные наборы данных в памяти компьютера, отображать их в табличном виде, а также программно и интерактивно манипулировать ими (добавлять, редактировать, удалять и сортировать). 

Таблицы состоят из строк и колонок. Строки располагаются вниз по вертикали, а колонки — вправо по горизонтали. Строки и колонки имеют индексы, по которым к ним можно обращаться напрямую (начинаются с 0). Кроме этого, к колонкам можно обращаться по идентификатору.

Пересечения строк и колонок образуют ячейки, в которых содержатся значения. Тип значения определяется типом значения колонки.

Таблица значений является полностью динамическим объектом, т.е. Вы можете манипулировать не только строками таблицы, добавляя и удаляя их, но и колонками.

Таблица значений может использоваться явно при создании в коде необходимого количества переменных типа ТаблицаЗначений, либо неявно: при добавлении элемента управления ТабличноеПоле на обычную форму, и ТаблицаФормы — на управляемую. Здесь мы рассмотрим только программную работу с таблицей значений.

Создание таблицы значений

Как и большинство объектов встроенного языка, новая таблица значений может быть создана с помощью оператора Новый:

тз = Новый ТаблицаЗначений;

Колонки таблицы значений

Прежде чем начать работу с таблицей значений, необходимо создать структуру колонок. Каждая колонка характеризуется следующими свойствами:

1. Имя — идентификатор колонки (может содержать только алфавитные символы, цифры и знаки подчеркивания. Причем, начинаться имя колонки может только с буквы или символа подчеркивания);
2. Заголовок — представление колонки в диалогах (может содержать произвольные символы);
3. ТипЗначения — тип значения содержимого ячеек в этой колонке. Если тип не задан, в ячейке можно хранить значения произвольного типа;
4. Ширина — ширина колонки в диалогах;

Доступ к колонкам производится через свойство Колонки объекта ТаблицаЗначений. Для добавления новой колонки используется метод Добавить():

тз.Колонки.Добавить("Наименование", Новый ОписаниеТипов("Строка"));
тз.Колонки.Добавить("Количество", Новый ОписаниеТипов("Число"));
тз.Колонки.Добавить("Свойство");//можно хранить произвольные данные

Для того, чтобы определить наличие колонки с нужным именем используется метод Найти():

найдКолонка = тз.Колонки.Найти("Наименование");
Если найдКолонка = Неопределено Тогда
	Сообщить("Колонка не найдена!");
КонецЕсли;

Перебор колонок выполняется следующим образом:

Для каждого Колонка Из тз.Колонки Цикл 
    Сообщить(Колонка.Имя); 
КонецЦикла;

Для удаления колонки используется метод Удалить():

найдКолонка = тз.Колонки.Найти("Свойство");
Если НЕ найдКолонка = Неопределено Тогда
	тз.Колонки.Удалить(найдКолонка);
КонецЕсли;

Свойства колонки таблицы значений

Методы коллекции колонок таблицы значений

Строки таблицы значений

С колонками разобрались. Давайте теперь разберемся со строками. Строки таблицы значений можно программно добавлять и удалять, перемещать и сортировать, а также выполнять операции поиска и отбора.

Добавление и удаление строк

Для добавления новой строки используется метод Добавить() объекта ТаблицаЗначений. Метод возвращает объект СтрокаТаблицыЗначений, с которым доступны дальнейшие манипуляции:

СтрокаТЧ = тз.Добавить();

И только теперь мы можем заполнить строку данными. Для этого обращаемся к ячейкам строки, указывая идентификаторы колонок через точку:

СтрокаТЧ.Наименование = "Стул деревянный";
СтрокаТЧ.Количество = 1;
СтрокаТЧ.Свойство = ТекущаяДата();

Обратите внимание, что каждая СтрокаТаблицыЗначений ссылается на таблицу значений с помощью метода Владелец():

тз = СтрокаТЧ.Владелец();

Для удаления строки используется метод Удалить() объекта ТаблицаЗначений. Строку можно удалить либо передав методу непосредственно строку, либо ее индекс:

//непосредственное удаление строки
тз.Удалить(СтрокаТЧ);
//удаление строки по индексу
тз.Удалить(тз.Индекс(СтрокаТЧ));

Перебор строк таблицы значений

Для перебора строк удобнее всего использовать оператор цикла Для Каждого. В редких случаях оправдано применение цикла Для:

Для Каждого СтрокаТЧ Из тз Цикл
	ИндСтроки = тз.Индекс(СтрокаТЧ);
КонецЦикла;
//в редких случаях
Для ИндСтроки = 0 По тз.Количество() - 1 Цикл
	СтрокаТЧ = тз.Получить(ИндСТроки);
КонецЦикла;

Поиск строк

В отличие от платформы 1С:Предприятие 7.7 в 8-ке расширен функционал работы с таблицей значений. Поиск можно выполнять не только по значению в колонке (в этом случае будет возвращена первая найденная строка), но и по набору свойств (в этом случае возвращается массив строк):

//поиск первой строки
НайдСтрока = тз.Найти(Номенклатура, "Номенклатура");
//поиск набора строк
ПараметрыПоиска = Новый Структура("Номенклатура", Номенклатура);
мНайдСтроки = тз.НайтиСтроки(ПараметрыПоиска);

Все методы таблицы значений:

Иерархию свойств и типов значений, связанных с таблицей значений, схематически можно представить в виде дерева:

Читайте также:

1. Как объединить таблицы значений
2. Как программно выгрузить таблицу значений
3. Как правильно загрузить значений в колонку таблицы значений из массива

Поделиться страницей в соц.сетях

Таблица значений

Создание таблицы значений

Добавление строк

Перебор строк

Сортировка

Поиск значения

Итоги и группировка

Удаление строк и колонок

Таблица значений в диалоге

Специальные методы

Выгрузка таблицы значений

Создание таблицы значений

Таблица значений часто применяется при программировании на 1С, потому что имеет множество полезных возможностей и работает очень быстро. Таблица значений создается в памяти и не сохраняется в базе данных, т.е. это временный набор данных.

ТабЗнач = СоздатьОбъект("ТаблицаЗначений");

ТабЗнач.НоваяКолонка("Номер");
ТабЗнач.НоваяКолонка("Сотрудник");
ТабЗнач.НоваяКолонка("Должность");
ТабЗнач.НоваяКолонка("Оклад");

//можно указать тип данных каждой колонки

//если тип данных колонки не указан, то можно хранить данные любого типа

Синтаксис: НоваяКолонка(<Идентификатор>, <Тип>, <Длина>, <Точность>, <Заголовок>, <Ширина>, <Формат>, <Положение>)

ТабЗнач.НоваяКолонка("Номер","Число",10,0);
ТабЗнач.НоваяКолонка("Сотрудник","Справочник.Сотрудники");
ТабЗнач.НоваяКолонка("Должность","Справочник.Должности");
ТабЗнач.НоваяКолонка("Оклад","Число",10,2);

Добавление строк в таблицу значений

ТабЗнач.НоваяСтрока();
ТабЗнач.Номер = 1;
ТабЗнач.Сотрудник = "Иванов Иван Иванович"; //следите за типом колонки!
ТабЗнач.Должность = "Программист";
ТабЗнач.Оклад = 20000;

ТабЗнач.НоваяСтрока();
ТабЗнач.Номер = 2;
ТабЗнач.Сотрудник = "Петров Петр Петрович";
ТабЗнач.Должность = "Бухгалтер";
ТабЗнач.Оклад = 10000;

//обычно строки добавляются в цикле
СпрСотр = СоздатьОбъект("Справочник.Сотрудники");
СпрСотр.ВыбратьЭлементы();
Пока СпрСотр.ПолучитьЭлемент()=1 Цикл
     ТабЗнач.НоваяСтрока();
     ТабЗнач.Номер = СпрСотр.Код;
     ТабЗнач.Сотрудник = СпрСотр.ТекущийЭлемент(); //следите за типом колонки!
     ТабЗнач.Должность = СпрСотр.Должность;
     ТабЗнач.Оклад = СпрСотр.Оклад;
КонецЦикла;

Перебор строк таблицы значений

1-й способ.

ТабЗнач.ВыбратьСтроки();
Пока ТабЗнач.ПолучитьСтроку()=1 Цикл
     Сообщить(ТабЗнач.Сотрудник);
КонецЦикла;

2-й способ.

Для НомерСтроки = 1 По ТабЗнач.КоличествоСтрок() Цикл
     ТабЗнач.ПолучитьСтрокуПоНомеру(НомерСтроки);
     Сообщить(ТабЗнач.Сотрудник);
КонецЦикла;

Сортировка таблицы значений

//сортировать по должности по возрастанию
ТабЗнач.Сортировать("Должность+");

//сортировать по должности по возрастанию, а внутри должности по убыванию оклада
ТабЗнач.Сортировать("Должность+,Оклад-");

Поиск в таблице значений

Синтаксис: НайтиЗначение(<Знач>,<Строка>,<Колонка>)

Возвращает число: 0 — значение не найдено; 1 — значение найдено

Если указан параметр <Строка>, то поиск производится только по заданной строке

Если указан параметр <Колонка>, то поиск производится только по заданной колонке

номстр = 0;
Если ТабЗнач.НайтиЗначение (10000, номстр, "Оклад") = 1 Тогда
     ТабЗнач.ПолучитьСтрокуПоНомеру(номстр);
     Сообщить(ТабЗнач.Сотрудник);
КонецЕсли;

Итоги и группировка таблицы значений

//получить итог по колонке можно методом Итог
ВсеОклады = ТабЗнач.Итог("Оклад")

//часто требуется группировать строки и подсчитывать итоги по группам,

//в этом случае применяется метод Свернуть

Синтаксис: Свернуть(<ГруппКолонки>,<СуммКолонки>)

//просуммировать оклады по каждой должности
ТабЗнач.Свернуть("Должность","Оклад");

//Можно группировать и суммировать сразу по нескольким колонкам
ТабЗнач.Свернуть("Категория, Должность","Оклад,Налог");

Удаление строк и колонок из таблицы значений

ТабЗнач.Очистить(); //очистить таблицу значений и удалить колонки

ТабЗнач.УдалитьСтроки(); //удаляет все строки (колонки сохраняются)

ТабЗнач.УдалитьСтроку(); //удаляет текущую строку
ТабЗнач.УдалитьСтроку(3); //удаляет 3-ю строку

ТабЗнач.УдалитьКолонку("Оклад"); //удаляет колонку Оклад
ТабЗнач.УдалитьКолонку(2); //удаляет 2-ю колонку

ВНИМАНИЕ

Часто требуется удалить строки, удовлетворяющие определенному условию.

Так как при удалении строки из таблицы значений следующая строка становится текущей,

то указанная ниже программа может удалить НЕ ВСЕ необходимые строки.

//ЭТА ПРОГРАММА НЕПРАВИЛЬНАЯ !!!
ТабЗнач.ВыбратьСтроки();
Пока ТабЗнач.ПолучитьСтроку()=1 Цикл
    Если <условие> Тогда
       ТабЗнач.УдалитьСтроку(); //следующая строка стала текущей,
    КонецЕсли;
КонецЦикла;

В этом случае я рекомендую использовать следующий прием:

ТабЗнач.ВыбратьСтроки();
Пока ТабЗнач.ПолучитьСтроку()=1 Цикл
~начало:
   Если <условие> Тогда
      ТабЗнач.УдалитьСтроку(); //следующая строка стала текущей
      Если ТабЗнач.НомерСтроки<>0 Тогда
         Перейти ~начало;
      КонецЕсли;
   КонецЕсли;
КонецЦикла;

А вот еще один правильный алгоритм, предложенный Wlad:

ТабЗнач.выбратьстроки();
Пока ТабЗнач.ПолучитьСтроку()=1 Цикл
    Пока (<условие>) и (ТабЗнач.НомерСтроки<>0) Цикл
         ТабЗнач.УдалитьСтроку(); //следующая строка стала текущей
    КонецЦикла;
КонецЦикла;

Замечание(Туц). Предыдущий вариант не совсем правильный. Случай, когда последняя строка попадает под условие и в условии идёт обращение к строке таблицы, приводит к ошибке. Т.е. происходит попытка чтения для строки 0.

И ещё вариант, предложенный Туц:

Сч = ТабЗнач.КоличествоСтрок();
Пока Сч > 0 Цикл
    ТабЗнач.ПолучитьСтрокуПоНомеру(Сч);
    Если <условие> Тогда
        ТабЗнач.УдалитьСтроку(); 
    КонецЕсли;
    Сч = Сч - 1;
КонецЦикла;

Замечание (vligm). А я использую такой алгоритм (это, собственно говоря, шаблон):

Для Сч = -<?Таблица>.КоличествоСтрок() По -1 Цикл
    <?Таблица>.ПолучитьСтрокуПоНомеру(-Сч);
    Если <?Условие> Тогда
        <?Таблица>.УдалитьСтроку(-Сч);
    КонецЕсли;// Если <?Условие>
КонецЦикла;// Для Сч = -<?Таблица>КС По -1

Таблица значений как элемент диалога

Таблица значений может использоваться в экранных формах как элемент диалога с пользователем.

//установить курсор на указанную колонку или можно узнать, где находится курсор
ТабЗнач.ТекущаяКолонка(НоваяКолонка,ТекКолонка);

//установить курсор на указанную строку или можно узнать, где находится курсор.
ТекСтрока = ТабЗнач.ТекущаяСтрока(НовСтрока);

ТабЗнач.ВидимостьКолонки("Оклад",0); //скрыть колонку Оклад
ТабЗнач.ВидимостьКолонки("Должность, Сотрудник",1); //показать колонки Должность и Сотрудник
ТабЗнач.ВидимостьКолонки("Оклад",1,1); //показать колонку Оклад в 1-й позиции

//можно зафиксировать верхние строки и левые колонки для удобства прокрутки таблицы значений в диалоге
ТабЗнач.Фиксировать(КолСтрок,КолКолонок);

Методы УстановитьЗначение и ПолучитьЗначение

Эти методы позволяют обращаться к данным в таблице значений для чтения и записи.

Они могут пригодиться в особых случаях при написании универсальных программ (мастеры отчетов и т.д.).

Синтаксис: УстановитьЗначение(<Строка>,<Колонка>,<Знач>)

Синтаксис: ПолучитьЗначение(<Строка>,<Колонка>)

ТабЗнач.НоваяСтрока();
ТабЗнач.УстановитьЗначение(1,"Номер",100);
ТабЗнач.УстановитьЗначение(1,"Сотрудник","Иванов Иван Иванович");
ТабЗнач.УстановитьЗначение(1,3,10000); //обращение к 1-й строке и 3-й колонке ("Оклад")

Номер = ТабЗнач.ПолучитьЗначение(1,"Номер");
ФИО = ТабЗнач.ПолучитьЗначение(1,"Сотрудник");
Оклад = ТабЗнач.ПолучитьЗначение(1,3); //обращение к 1-й строке и 3-й колонке "Оклад"

Выгрузка таблицы значений

Синтаксис: Выгрузить(<Знач>,<НачСтрока>,<КонСтрока>,<Колонки>)

//выгрузить 10 сотрудников с наибольшими окладами в новую таблицу значений
ТабЗнач.Сортировать("Оклад-");
ТабЗнач.Выгрузить(НоваяТабЗнач,1,10,"Сотрудник,Оклад");

Таблица значений

Описание

Создание и использование

НоваяТаблица = Новый ТаблицаЗначений;
//После создания таблицы значений необходимо определить колонки таблицы значений:
НоваяТаблица.Колонки.Добавить(«Колонка1»);

ТипНоменклатура = Новый ОписаниеТипов(«СправочникСсылка.Номенклатура»);
МояТаблица.Колонки.Добавить("Номенклатура", ТипНоменклатура);

НоваяСтрокаТаблицы = НоваяТаблица.Добавить();
//Далее следует заполнение колонок таблицы
НоваяСтрокаТаблицы.Колонка1 = ЗначениеДляЗаполнения

Другие часто используемые операторы при работе с таблицей значений

Только авторизованные участники могут оставлять комментарии.

Таблица значений в 1С 8.3 позволяет строить динамические наборы значений. При этом каких-либо жестких ограничений на тип данных не накладывается. Таблица значений создается в памяти и не сохраняется в базе данных, имеет множество полезных возможностей и работает очень быстро.

Свойствами таблиц значений являются:

• индексы (коллекция индексов таблицы значений)
• колонки (коллекция колонок таблицы значений).

Элементом коллекции является строка таблицы значений. Но необходимо учитывать тот факт, что с таблицей значений можно работать только на сервере.

Работа с таблицей значений в 1С 8.3 на примерах

Создать новую таблицу значений

ТЗ = Новый ТаблицаЗначений;

Добавить колонку в таблицу значений

ТЗ.Колонки.Добавить("Автомобиль");
ТЗ.Колонки.Добавить("Цвет");
ТЗ.Колонки.Добавить("Класс");

Добавить колонку с описанием типа

// Необходимо, чтобы колонка таблицы значения была строго типизировано
ОписаниеВеса = Новый ОписаниеТипов("Число", Новый КвалификаторыЧисла(10, 0));
ТЗ.Колонки.Добавить("ВесАвтомобиля", ОписаниеВеса, "Вес Автомобиля");

Добавить строку в таблицу значений

НоваяСтрока = ТЗ.Добавить();
НоваяСтрока.Автомобиль = "Mitsubishi ";
НоваяСтрока.Цвет = "Синий";
НоваяСтрока.Класс = "C класс";
НоваяСтрока.Вес = 1500;

НоваяСтрока = ТЗ.Добавить();
НоваяСтрока.Автомобиль = "KIA";
НоваяСтрока.Цвет = "Зелёный";
НоваяСтрока.Класс = "A класс";
НоваяСтрока.Вес = 1800;

НоваяСтрока = ТЗ.Добавить();
НоваяСтрока.Автомобиль = "BMW";
НоваяСтрока.Цвет = "Зелёный";
НоваяСтрока.Класс = "E класс";
НоваяСтрока.Вес = 2100;

Заполнить строку значениями

//ДанныеДляЗаполнения - структура, стройка другой таблицы и т.п.
//Метод сопоставляет имена свойств и заполнят по ним значение
ЗаполнитьЗначенияСвойств(ТЗ.Добавить(), ДанныеДляЗаполнения);

Вставить строку

//Метод вставляет в таблицу значения новую строку 
НоваяСтрока = ТЗ.Вставить(0);  
// Если нужно изменить значения не всех колонок, то можно использовать НоваяСтрока = ТЗ[0]
НоваяСтрока.Автомобиль = "Mitsubishi ";
НоваяСтрока.Цвет = "Белый";
НоваяСтрока.Класс = "C класс";
НоваяСтрока.Вес = 1500;

Сортировка

//Сортирует таблицу значение по нужным колонкам и направлению сортировки
ТЗ.Сортировать(«Цвет Убыв, Вес Возр»);

Получить значение

//Предположим что в строке №1 хранится информация об автомобиле БМВ.
//А цвет храниться в колонке №2 с именем "Цвет" 
//Задача - получить значение цвета из таблицы значений
//
//Если мы знаем номер строки и название свойства:
ЦветБМВ = ТЗ[0].Цвет;
//Если мы значем номер строки и колонки
ЦветБМВ = ТЗ[0][1];
// * отсчет номера строк и колонок начинается с 0

Удалить строку

//Удаляем строку №1 из таблицы значений
ТЗ.Удалить(ТЗ[0]);
//Удалить строки по условию можно с помощью перебора (см. Обход таблицы значений)

Найти одну строку

//Позволяет найти одну строку в таблице значений.
//Искать можно как по всем колонкам таблице
ИскомаяСтрока = ТЗ.Найти("Синий");
//Так и по определенной колонке:
ИскомаяСтрока = ТЗ.Найти("Синий", "Цвет");
//*Метод находит первую попавшуюся строку, если их несколько
//Если строка не найдена, то вернет "Неопределено"

Найти несколько строк

// Позволяет найти сразу несколько строк в таблице значений
//Создаем структуру для отбора
ОтборПоЗеленомуЦвету = Новый Структура();
ОтборПоЗеленомуЦвету.Вставить("Цвет","Зеленый");
//Получаем массив строк с зелеными машинами
МассивСоСтроками = ТЗ.НайтиСтроки(ОтборПоЗеленомуЦвету);

Свернуть таблицу значений

//Позволяет "свернуть" таблицу значений:
//1С оставляет указанные колонки в первом параметре и суммирует по колонкам из второго параметра
ТЗ.Свернуть("Товар", "Вес"); 

Скопировать таблицу

//Позволяет получить копию таблицы значений. 
НоваяТЗ = ТЗ.Скопировать();
//Если нужны только некоторые строки - нужно вставить массив таких строк в 1-ый параметр
//Если нужны только некоторые колонки - нужно вставить их имена через запятую в 2-ый параметр

Скопировать таблицу без данных

//Делает копию таблицы, но без строк. Только колонки
НоваяТЗ = ТЗ.СкопироватьКолонки();

Узнать количество строк

КоличествоСтрокТЗ = ТЗ.Количество();

Очистить

//Очищает таблицу значений от строк
ТЗ.Очистить();

Обход таблицы значения

Обход коллекции с выбором элемента осуществляется с помощью цикла <<Для>>, где оператор цикла Для предназначен для циклического повторения операторов, находящихся внутри конструкции, в данном случае таблицы значений. Так же можно обращаться к элементу коллекции посредством оператора [ ] ([аргумент]), где аргументом является индекс строки. Нумерация индексов строк начинается с нуля [0].

Прямой обход

Для Каждого Стр Из ТаблицаЗначений Цикл

Сообщить(Стр.Номенклатура); 

КонецЦикла;

Обратный обход таблицы (снизу вверх)

Чаще всего применяется для удаления строк в таблице.

//Товары - таблица значений, где необходимо удалить строки с "Сумма = 0"
Сч=0;
Пока Сч<Товары.Количество() Цикл
       ТекущаяСтрока=Товары[Сч];
       Если ТекущаяСтрока.Сумма=0 Тогда
              Товары.Удалить(ТекущаяСтрока);
              Сч=Сч-1;  
       КонецЕсли;
       Сч=Сч+1;
КонецЦикла;

Обход колонок

Можно перечислить все колонки в таблице значений в 1с 8.3 с помощю цикла <<Для>>:

Для Каждого Колонка Из ТаблицаЗначений.Колонки Цикл

Сообщить(Колонка.Имя);

КонецЦикла;

Превратить структуру в таблицу значений

//Есть структура:
СтруктураЛогинПароль = Новый Структура;
СтруктураЛогинПароль.Вставить("Логин", "root");
СтруктураЛогинПароль.Вставить("Пароль", "1s83.info");

//Создаем таблицу значений:
ТЗ = Новый ТаблицаЗначений;
ТЗ.Колонки.Добавить("Логин");
ТЗ.Колонки.Добавить("Пароль");

//"Превращаем" структуру в таблицу значений:
Для Каждого ТекущийЭлемент из СтруктураЛогинПароль Цикл
	НовСтр=ТЗ.Добавить();
	НовСтр.Логин = ТекущийЭлемент.Ключ;
	НовСтр.Пароль = ТекущийЭлемент.Значение;                          
КонецЦикла;