Как программно заполнить реквизиты строки табличной части

Табличные части существуют у многих объектов в 1С:

  • Справочники
  • Документы
  • Отчеты и обработки
  • Планы счетов
  • Планы видов характеристик
  • Планы видов расчета
  • Бизнес-процессы и задачи

Табличные части позволяют хранить неограниченное количество структурированной информации, принадлежащей одному объекту.

Рассмотрим некоторые приемы работы с табличными частями.

Как обойти табличную часть

Для обхода табличной части можно использовать цикл Для каждого

Для каждого Строка из ТабличнаяЧасть Цикл

Сообщить(Строка.РеквизитТабличнойЧасти);

КонецЦикла;

На каждой итерации в переменную Строка передается очередная строка табличной части. Значения реквизитов строки можно получить выражением Строка.ИмяРеквизита.

Как получить и обойти выделенные строки табличной части

Для вывода информации из табличной части объекта служит элемент формы Табличное поле. Для включения возможности выделения нескольких строк на табличном поле нужно установить значение Множественный у его свойства Режим выделения.

Работа с табличной частью объектов в 1СДля получения перечня выделенных строк используется следующий код:

ВыделенныеСтроки=ЭлементыФормы.ИмяТабличногоПоля.ВыделенныеСтроки;

Для того чтобы обойти выделенные строки используется цикл Для каждого:

ВыделенныеСтроки=ЭлементыФормы.ИмяТабличногоПоля.ВыделенныеСтроки;

Для каждого Строка из ВыделенныеСтроки Цикл

//содержимое цикла

КонецЦикла;

Как программно выделить строки табличной части (табличного поля) и снять выделение

Чтобы программно снять выделение строк табличного поля:

ЭлементыФормы.ИмяТабличногоПоля.ВыделенныйСтроки.Очистить();

Чтобы программно выделить все строки табличного поля:

Для каждого ТекущаяСтрока Из ТабличнаяЧасть Цикл
ЭлементыФормы.ИмяТабличногоПоля.ВыделенныеСтроки.Добавить(ТекущаяСтрока);
КонецЦикла;

Как очистить табличную часть

ТабличнаяЧасть.Очистить();

Как получить текущую строку табличной части

Текущая строка — это срока, в которой у пользователя в данный момент находится курсор. Чтобы ее получить, нужно обратиться к элементу управления на форме, который связан с табличной частью.

Для обычных форм код будет выглядеть так:

ЭлементыФормы.ИмяТабличногоПоля.ТекущиеДанные;

Для управляемых форм:

Элементы.ИмяТабличногоПоля.ТекущиеДанные;

Как добавить новую строку в табличную часть

Добавление новой строки в конец табличной части:

НоваяСтрока=ТабличнаяЧасть.Добавить();
НоваяСтрока.Реквизит1=«Значение»;

Добавление новой строки в любое место табличной части (последующие строки будут сдвинуты):

НоваяСтрока=ТабличнаяЧасть.Вставить(Индекс)
//Индекс — номер добавляемой строки. Нумерация строк начинается с нуля.

НоваяСтрока.Реквизит1=«Значение»;

Как программно заполнить реквизиты строки табличной части

Если нужно программно заполнить реквизиты строки табличной части, которую добавляет пользователь, необходимо использовать обработчик события табличной части ПриНачалеРедактирования.

Создаваемая обработчиком процедура имеет три параметра:

  • Элемент — содержит элемент управления ТабличноеПоле.
  • НоваяСтрока — булево. Содержит значение Истина, если добавляется новая строка табличной части, и Ложь, если пользователь начал редактировать уже существующую строку.
  • Копирование — булево. Содержит значение Истина, если пользователь копирует строку, и Ложь в остальных случаях.

Рассмотрим пример. Допустим, нам нужно заполнить реквизит табличной части СчетУчета, в случае, когда добавляется новая строка. При редактировании существующей строки изменять счет учета не нужно.

Процедура ТабличнаяЧастьПриНачалеРедактирования(Элемент, НоваяСтрока, Копирование)

//Если пользователь редактирует существующую строку, то ничего не делаем
Если НЕ НоваяСтрока Тогда
Возврат;
КонецЕсли;

//Если же строка новая, устанавливаем счет учета
ТекСтрока = Элемент.ТекущиеДанные; //Получили текущую строку табличной части
ТекСтрока.СчетУчета = ПланыСчетов.Хозрасчетый.НужныйСчетУчета;
КонецПроцедуры

Источник

В предыдущей статье мы узнали, как настраивать и конфигурировать табличные части объектов 1С 8.3. В этой статье мы изучим некоторые вопросы программной работы с табличными частями 1С.

Заполнение табличной части 1С 8.3

Очень часто встречается задача заполнить табличную часть какими-нибудь  значениями, например результатом выполнения запроса.  Для демонстрации реализуем пример, в котором выполняется заполнение табличной части. Сделаем небольшую учебную задачу: будем заполнять табличную часть документа всей номенклатурой, которая не помечена на удаление. Количество при этом будет равно 1. Для заполнения табличной части документа нам необходимо работать с  одноименной таблицей реквизита Объект, который является основным реквизитом управляемой формы.

Табличная часть реквизита Объект

Поскольку по условиям задачи, необходимо отобрать всю не помеченную на удаление номенклатуру, то оптимально это сделать при помощи запроса, в котором я буду получать все не помеченные элементы справочника номенклатура. Я создал команду, при выполнении которой будет заполняться табличная часть, и разместил её на форме.

Команда 1С и размещение её на форме

Исполнение команды будет выполняться в серверном контексте, поскольку объект Запрос не работает в клиентском контексте на тонком клиенте.

&НаСервере
Процедура ЗаполнитьТоварамиНаСервере()

    Запрос = Новый Запрос;
    Запрос.Текст = "ВЫБРАТЬ
                   |    Товары.Ссылка КАК Товар,
                   |    1 КАК Количество
                   |ИЗ
                   |    Справочник.Товары КАК Товары
                   |ГДЕ
                   |    НЕ Товары.ПометкаУдаления";
    Выборка = Запрос.Выполнить().Выбрать();
    Пока Выборка.Следующий() Цикл
        НовСтр = Объект.СписокТоваров.Добавить();
        ЗаполнитьЗначенияСвойств(НовСтр,Выборка);
    КонецЦикла;

КонецПроцедуры

&НаКлиенте
Процедура ЗаполнитьТоварами(Команда)
    ЗаполнитьТоварамиНаСервере();
КонецПроцедуры

При обходе запроса, я использую метод Добавить табличной части объекта (вообще это метод объекта, который имеет тип ДанныйФормыКоллекция, именно в этот тип преобразуется табличная часть документа-объекта, при создании на сервере). Данный метод является функцией, которая создаёт и возвращает новую строку.

Обратите внимание, поскольку при обходе запроса и заполнения новой строки, я использую метод ЗаполнитьЗначенияСвойств, то поля в запросе должны называться так же, как и поля табличной части.

Очистка табличной части документа 1С 8.3

Если  мы реализуем данный код, то он будет не совсем корректен: каждый раз при выполнении этого кода будут добавляться новые строки, а вполне возможно, что пользователю старые строки не нужны. Поэтому, будем очищать имеющиеся строки,  перед добавлением новых строк. Для этого воспользуемся методом Очистить объекта СписокТоваров, который имеет тип  ДанныйФормыКоллекция.

Объект.СписокТоваров.Очистить();

После выполнения этого метода вся табличная часть будет очищена.

Текущая строка табличной части 1С 8.3

В процессе работы может возникнуть необходимость отработать текущую строку табличной части, т.е. ту строку, которая в данный момент выделена.

Текущая строка табличной части 1С 8.3

Например, может возникать ситуация, что мы редактируем какое-нибудь поле текущей строки таблицы на форме, и нам нужно, чтобы было пересчитано другое поле  (или несколько полей) этой текущей строки. Например, мы изменяем цену (или количество) нашей табличной части, и необходимо, чтобы сумма автоматически была пересчитана.

Для решения данной задачи нужно воспользоваться свойством ТекущиеДанные элемента с типом ТаблицаФормы, который соответствует нужной табличной части. Свойство ТекущиеДанные возвращает значение полей текущей строки.

Возврат полей свойством ТекущиеДанные

Для того, чтобы отработать изменение текущего поля цены, создадим обработчик события ПриИзменении этого поля.

Обработчик ПриИзменении поля таблицы формы

В этом обработчике напишем код, который будет пересчитывать значения полей текущей строки табличной части.

&НаКлиенте
Процедура СписокТоваровЦенаПриИзменении(Элемент)
	ТекДанные = Элементы.СписокТоваров.ТекущиеДанные;
	Если ТекДанные = Неопределено Тогда
		Возврат; //если пустая таблица
	КонецЕсли;
	ТекДанные.Сумма = ТекДанные.Количество * ТекДанные.Цена;
КонецПроцедуры

Ещё пример: я создал команду, которая должна увеличивать количество в текущий строке табличной части в два раза и пересчитывать сумму. Эта команда размещена в командной панели таблицы и имеет следующий код:

&НаКлиенте
Процедура УмножитьНа2(Команда)
    ТекДанные = Элементы.СписокТоваров.ТекущиеДанные;
    Если ТекДанные = Неопределено Тогда
        Возврат; //если пустая таблица
    КонецЕсли;
    ТекДанные.Количество = ТекДанные.Количество * 2;
    ТекДанные.Сумма = ТекДанные.Количество * ТекДанные.Цена;
КонецПроцедуры

Теперь доработаем этот пример: после увеличения текущей строки будем сдвигать текущую строку на строку вниз. Для этого допишем предыдущий код:

Идентификтор = Элементы.СписокТоваров.ТекущаяСтрока;
ИдентификторСлед = Идентификтор + 1;

Если ИдентификторСлед < Объект.СписокТоваров.Количество() Тогда
    Элементы.СписокТоваров.ТекущаяСтрока = ИдентификторСлед;
КонецЕсли;

В этом коде мы получаем идентификатор текущий строки при помощи свойства таблицы управляемой формы ТекущаяСтрока, и если мы не выходим за приделы таблицы, то сдвигаем нашу текущую строку на один шаг вниз.

Также при помощи текущей строки можно находить аналогичную строку в соответствующей табличной части основного реквизита формы Объект, которую также можно изменять (строка на форме тоже изменится автоматически). Мы ранее сделали пересчет суммы при изменении цены, теперь сделаем пересчет суммы при изменении количества, но напрямую через реквизит Объект.

&НаКлиенте
Процедура СписокТоваровКоличествоПриИзменении(Элемент)
    Идентификтор = Элементы.СписокТоваров.ТекущаяСтрока;
    Если Идентификтор = Неопределено Тогда
        Возврат;
    КонецЕсли;
    ТекСтрока = Объект.СписокТоваров.НайтиПоИдентификатору(Идентификтор);
    Если ТекСтрока = Неопределено Тогда
        Возврат;
    КонецЕсли;
    ТекСтрока.Сумма = ТекСтрока.Цена * ТекСтрока.Количество;
КонецПроцедуры

В этом коде мы используем метод НайтиПоИдентификатору переменной Объект.СписокТоваров, которая имеет типа ДанныйФормыКоллекция, этот метод получает элемент коллекции по указанному идентификатору. Если этот элемент найден, то мы можем с ними работать, причем данные на форме изменяться автоматически.

Обход табличной части 1С

Часто возникают задачи обойти табличную часть и изменить какие-либо значения в столбцах. В предыдущих примерах мы изменяли текущую стоку таблицы, теперь реализуем пример, когда нужно изменить все строки. В этом случае нет необходимости обращаться к элементам формы, можно работать напрямую с основным реквизитом Объект.

&НаКлиенте
Процедура УмножитьВсеНа2(Команда)

    ТабОбх = Объект.СписокТоваров;
    Для Каждого стрТабл из ТабОбх Цикл
        стрТабл.Количество = стрТабл.Количество * 2;
        стрТабл.Сумма = стрТабл.Цена * стрТабл.Количество;
    КонецЦикла;

КонецПроцедуры

Остальные статьи по теме конфигурирования в 1С:

Конфигурирование табличный частей объектов 1С

Справочники в 1С 8.3

Документы в 1С 8.3

Предопределенные элементы справочников 1С

Формы справочников в 1С 8.3

Более подробно и основательно конфигурирование в 1С дается в моей книге:

Книга «Программировать в 1С за 11 шагов»

Изучайте программирование в 1С в месте с моей книги «Программировать в 1С за 11 шагов»

  1. Книга написана понятным и простым языком — для новичка.
  2. Книга посылается на электронную почту в формате PDF. Можно открыть на любом устройстве!
  3. Научитесь понимать архитектуру 1С;
  4. Станете писать код на языке 1С;
  5. Освоите основные приемы программирования;
  6. Закрепите полученные знания при помощи задачника;

О том как разрабатывать под управляемым приложением 1С, читайте в книге Книга «Основы разработки в 1С: Такси»

Отличное пособие по разработке в управляемом приложении 1С, как для начинающих разработчиков, так и для опытных программистов.

  1. Очень доступный и понятный язык изложения
  2. Книга посылается на электронную почту в формате PDF. Можно открыть на любом устройстве!
  3. Поймете идеологию управляемого приложения 1С
  4. Узнаете, как разрабатывать управляемое приложение;
  5. Научитесь разрабатывать управляемые формы 1С;
  6. Сможете работать с основными и нужными элементами управляемых форм
  7. Программирование под управляемым приложением станет понятным

Промо-код на скидку в 15% — 48PVXHeYu

Вступайте в мои группы:

Вконтакте: https://vk.com/1c_prosto
Фейсбуке: https://www.facebook.com/groups/922972144448119/
ОК: http://ok.ru/group/52970839015518
Твиттер: https://twitter.com/signum2009

Источник

Эту и другие технические статьи написали наши программисты 1С и получили за них премии. Если вы тоже работаете с 1С и любите делиться опытом, приходите разработчиком в Neti

Цель данной статьи показать, как работать со строкой табличной части на сервере без контекста.

Все знают, что серверные без контекстные вызовы намного «легче» серверных вызовов и их использование является оптимальным решением задач. Но иногда программист, не задумываясь о последствиях использует серверный вызов в тех случаях, когда можно было использовать серверный без контекстный вызов, уменьшив тем самым нагрузку на сервер и увеличив производительность системы. Если на форме содержится мало данных, то разница будет почти не заметна и в таком случае неверное нет смысла усложнять код. Но в случае, когда данных много, разница будет очевидна и написанный серверный код нужно будет переделывать.

Разберем случай, когда для решения поставленной задачи нам нужно на сервере обратиться к данным текущей строки. При этом мы будем использовать серверный без контекстный вызов, а потом результаты сравним с серверным вызовом. В качестве демонстрации возьмем простой пример: при изменении номенклатуры получим ее единицу измерения.

Передача типа ДанныеФормыЭлементКоллекции на сервер невозможна:

Как заполнить строку табличной части на сервере без контекста в 1С

Оптимальным решением передать текущую строку на сервер будет преобразовать ее в структуру и уже структуру передать на сервер, а уже после выполнения действий со структурой перезаполнить данные текущей строки. Программный код будет выглядеть так:

////////
&НаКлиенте
Процедура ТоварыНоменклатураПриИзменении(Элемент)
	
	ИндексСтроки = Элементы.Товары.ТекущаяСтрока;
// Преобразуем данные текущей строки в структуру
	ДанныеТекущейСтроки = ПреобразоватьДанныеТекущейСтрокиВСтруктуру();
// Получим интересующее нас значение
	ЗаполнитьЕдиницуИзмеренияНоменклатуры(ДанныеТекущейСтроки);
// Изменим значения реквизитов текущей строки
	ЗаполнитьЗначенияСвойств(Объект.Товары[ИндексСтроки], ДанныеТекущейСтроки, "Упаковка");
КонецПроцедуры
&НаКлиенте
Функция ПреобразоватьДанныеТекущейСтрокиВСтруктуру() Экспорт
	
	Результат = Новый Структура("Номенклатура, Упаковка");
	
	ТекущиеДанные = Элементы.Товары.ТекущиеДанные;
Если НЕ ТекущиеДанные = Неопределено Тогда
		
		ЗаполнитьЗначенияСвойств(Результат, ТекущиеДанные);
КонецЕсли;
Возврат Результат;
КонецФункции
&НаСервереБезКонтекста
Процедура ЗаполнитьЕдиницуИзмеренияНоменклатуры(ДанныеТекущейСтроки)

	ДанныеТекущейСтроки.Упаковка = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ДанныеТекущейСтроки.Номенклатура, "ЕдиницаИзмерения");	

КонецПроцедуры
////////

• ПреобразоватьДанныеТекущейСтрокиВСтруктуру() – на основании данных текущей строки создается и заполняется структура с теми реквизитами табличной части, которые нам понадобятся для решения задачи.

• ИндексСтроки = Элементы.Товары.ТекущаяСтрока; – получаем идентификатор текущей строки таблицы

• ЗаполнитьЕдиницуИзмеренияНоменклатуры(ДанныеТекущейСтроки); — серверный без контекстный вызов, обращение к БД, поиск единицы измерения номенклатуры. Найденное значение помещается в структуру.

• ЗаполнитьЗначенияСвойств(Объект.Товары[ИндексСтроки], ДанныеТекущейСтроки, «Упаковка»); — изменяем значение «Упаковка» в текущей строке табличной части

А теперь с помощью замера производительности сравним время выполнения данной задачи и сравним время выполнения через серверный вызов. Чтобы увидеть разницу заполняем табличную часть формы данными.

Первый замер — серверный без контекстный вызов: 0,013694, второй замер – серверный вызов: 0,047071.

Источник

 +8 

   

Распечатать

1С 8.3 : Как заполнить табличную часть формы программно?

Нужно по кнопке Заполнить  — сформировать данные для заполнения табличных частей и заполнить их.

Форма имеет вид:

Рядом с кнопкой Записать и закрыть добавлена кнопка Заполнить документ, код ее команды:

Код 1C v 8.2 УП

 // Код заполнения ТЧ

&НаСервере

Процедура ЗаполнитьДокументНаСервере()

	ДокОбъект = РеквизитФормыВЗначение("Объект");

	Запрос = Новый Запрос;

	Запрос.Текст = 

		"ВЫБРАТЬ РАЗЛИЧНЫЕ

		|	ЗаказНаПроизводствоПродукция.Ссылка КАК ЗаказНаПроизводство,

		|	СпецификацииОперации.Операция,

		|	СпецификацииОперации.W1C_КоличествоОпераций,

		|	СпецификацииОперации.W1C_СтоимостьОднойОперации

		|ПОМЕСТИТЬ втЗаказОперацияСумма

		|ИЗ

		|	Документ.ЗаказНаПроизводство.Продукция КАК ЗаказНаПроизводствоПродукция

		|		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Спецификации.Операции КАК СпецификацииОперации

		|		ПО ЗаказНаПроизводствоПродукция.Спецификация = СпецификацииОперации.Ссылка

		|ГДЕ

		|	ЗаказНаПроизводствоПродукция.Ссылка В

		|			(ВЫБРАТЬ РАЗЛИЧНЫЕ

		|				W1C_ОтчетПоВыработкеНачисления.ЗаказПроизводство

		|			ИЗ

		|				Документ.W1C_ОтчетПоВыработке.Начисления КАК W1C_ОтчетПоВыработкеНачисления

		|			ГДЕ

		|				W1C_ОтчетПоВыработкеНачисления.Ссылка.Дата МЕЖДУ &ДатаН И &ДатаК)

		|;

		|

		|////////////////////////////////////////////////////////////////////////////////

		|ВЫБРАТЬ

		|	W1C_ОтчетПоВыработкеНачисления.Ссылка.Организация,

		|	W1C_ОтчетПоВыработкеНачисления.Ссылка.Сотрудник,

		|	W1C_ОтчетПоВыработкеНачисления.ЗаказПроизводство,

		|	W1C_ОтчетПоВыработкеНачисления.Операция,

		|	W1C_ОтчетПоВыработкеНачисления.КоличествоПродукции КАК Количество,

		|	втЗаказОперацияСумма.W1C_СтоимостьОднойОперации КАК Цена,

		|	W1C_ОтчетПоВыработкеНачисления.Ссылка КАК ОтчетПоВыработке,

		|	втЗаказОперацияСумма.W1C_СтоимостьОднойОперации * W1C_ОтчетПоВыработкеНачисления.КоличествоПродукции КАК Сумма

		|ИЗ

		|	Документ.W1C_ОтчетПоВыработке.Начисления КАК W1C_ОтчетПоВыработкеНачисления

		|		ЛЕВОЕ СОЕДИНЕНИЕ втЗаказОперацияСумма КАК втЗаказОперацияСумма

		|		ПО W1C_ОтчетПоВыработкеНачисления.ЗаказПроизводство = втЗаказОперацияСумма.ЗаказНаПроизводство

		|			И W1C_ОтчетПоВыработкеНачисления.Операция = втЗаказОперацияСумма.Операция

		|ГДЕ

		|	W1C_ОтчетПоВыработкеНачисления.Ссылка.Дата МЕЖДУ &ДатаН И &ДатаК

		|	И W1C_ОтчетПоВыработкеНачисления.Ссылка.Организация = &Организация";



	Запрос.УстановитьПараметр("ДатаК", КонецМесяца(ДокОбъект.ПериодРегистрации));

	Запрос.УстановитьПараметр("ДатаН", НачалоМесяца(ДокОбъект.ПериодРегистрации));

	Запрос.УстановитьПараметр("Организация", ДокОбъект.Организация);





  



                       
  








	РезультатЗапроса = Запрос.Выполнить();

	ДокОбъект.Рассчет.Загрузить(Запрос.Выполнить().Выгрузить());

	ОбновитьВыплату(ДокОбъект); //заполним данными вторую ТЧ

	ЗначениеВРеквизитФормы(ДокОбъект, "Объект");


КонецПроцедуры


&НаСервере

Процедура ОбновитьВыплату(ДокОбъект)

врТЗ = ДокОбъект.Рассчет.Выгрузить();

врТЗ.свернуть("Сотрудник","Сумма");

ДокОбъект.Начисления.Загрузить(врТЗ);

КонецПроцедуры

Второй вариант заполнения: Имеем ТЧ на форме, которую необходимо программно заполнить

и код в модуле документа:

Код 1C v 8.2 УП

 &НаСервере

 Процедура НайтиТопливоф()

    Запрос = Новый Запрос;

    Запрос.Текст = 

        "ВЫБРАТЬ

        |   СУММА(ПродажаТоплива.Номер) КАК Номер,

        |   ПродажаТоплива.ТипТоплива,

        |   СУММА(ПродажаТоплива.Количество) КАК Количество,

        |   СУММА(ПродажаТоплива.СуммаСНДС) КАК СуммаСНДС

        |ИЗ

        |   Документ.ПродажаТоплива КАК ПродажаТоплива

        |ГДЕ

        |   ПродажаТоплива.Цена <= &Цена

        |

        |СГРУППИРОВАТЬ ПО

        |   ПродажаТоплива.ТипТоплива";

 
    Запрос.УстановитьПараметр("Цена", Объект.Цена);

 
    Результат = Запрос.Выполнить();

     ВыборкаДетальныеЗаписи = Результат.Выбрать();

    Объект.ТЧ.Очистить();

    Пока ВыборкаДетальныеЗаписи.Следующий() Цикл  

 	 НовСтр = Объект.ТЧ.Добавить();

         ЗаполнитьЗначенияСвойств(НовСтр, ВыборкаДетальныеЗаписи); //при условии что имена полей ТЧ и выборки совпадают

    КонецЦикла;

КонецПроцедуры
Источник

Многие объекты метаданных в 1С могут иметь табличную часть. У одного объекта может быть создано неограниченное количество табличных частей.

Табличная часть может быть создана только как подчиненный объект у какого-либо объекта метаданных, например у справочника или у документа.

Строка табличной части не является отдельным объектом. К строке можно обратиться только по индексу строки в табличной части.

Программно нельзя создать табличную часть через конструктор. Можно только получить к ней доступ через основной объект:

//создаем объект
НовыйДок = Документы.РасходТовара.СоздатьДокумент();
//через объект получаем доступ к табличной части СписокУслуг
ТабЧастьДока = НовыйДок.СписокУслуг;

Строка табличной части

Добавить новую строку табличной части можно с помощью методов Добавить и Вставить. Через точку от строки табличной части можно обращаться к реквизитам строки:

//добавление строки табличной части
СтрокаТабличнойЧасти = НовыйДок.СписокУслуг.Добавить();
СтрокаТабличнойЧасти.Услуга = СсылкаНаУслугу;
СтрокаТабличнойЧасти.СуммаУслуги = 900;

//для метода Вставить нужно указать индекс строки
СтрокаТабличнойЧасти = НовыйДок.СписокУслуг.Вставить(1);
СтрокаТабличнойЧасти.Услуга = СсылкаНаУслугу;
СтрокаТабличнойЧасти.СуммаУслуги = 800;

//у строки есть предопределенная колонка НомерСтроки
Сообщить(СтрокаТабличнойЧасти.НомерСтроки); //2
//в отличии от индексов номера строк начинаются с 1

Заполнение табличной части

Заполнить табличную часть можно по одной строке с помощью методов Добавить и Вставить, а также с помощью методов Загрузить и ЗагрузитьКолонку для массового заполнения табличной части:

//создаем таблицу значений
ТЗТаблЧасть = Новый ТаблицаЗначений;
ТЗТаблЧасть.Колонки.Добавить("Услуга");
ТЗТаблЧасть.Колонки.Добавить("СуммаУслуги");

СтрокаТЗ = ТЗТаблЧасть.Вставить(1);
СтрокаТЗ.Услуга = СсылкаНаУслугу;
СтрокаТЗ.СуммаУслуги = 800;

СтрокаТЗ = ТЗТаблЧасть.Вставить(1);
СтрокаТЗ.Услуга = СсылкаНаУслугу;
СтрокаТЗ.СуммаУслуги = 900;

//создаем документ
НовыйДок = Документы.РасходТовара.СоздатьДокумент();

//заполнение табличной части из таблицы значений
//имена колонок должны совпадать
//все прежние строки будут удалены из табличной части
НовыйДок.СписокУслуг.Загрузить(ТЗТаблЧасть);

МассивТаблЧасть = Новый Массив;
МассивТаблЧасть.Добавить(500);
МассивТаблЧасть.Добавить(600);

//заполнение одной колонки табличной части
//все значения из массива будут загружены в колонку СуммаУслуги
НовыйДок.СписокУслуг.ЗагрузитьКолонку(МассивТаблЧасть, "СуммаУслуги");

Перебор табличной части

Перебрать табличную часть можно в цикле:

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//обход табличной части через цикл Для Каждого
Для Каждого СтрокаТабличнойЧасти Из ДокОбъект.СписокУслуг Цикл
	Сообщить(СтрокаТабличнойЧасти.НомерСтроки);
КонецЦикла;	

//количество строк табличной части
КолвоСтрок = ДокОбъект.СписокУслуг.Количество();

//Перебор табличной части через цикл Для
Для ё = 0 По КолвоСтрок Цикл
	//строку можно получить через квадратные скобки
	СтрокаТабличнойЧасти = ДокОбъект.СписокУслуг[ё];
	Сообщить(СтрокаТабличнойЧасти.НомерСтроки);
	
	//или методом Получить
	СтрокаТабличнойЧасти = ДокОбъект.СписокУслуг.Получить(ё);
	Сообщить(СтрокаТабличнойЧасти.НомерСтроки);
КонецЦикла;	

//через цикл Пока можно перебрать табличную часть с конца 
ИндСтр = КолвоСтрок; 
Пока ИндСтр > 0 Цикл
	//строку можно получить через квадратные скобки
	СтрокаТабличнойЧасти = ДокОбъект.СписокУслуг[ИндСтр];
	Сообщить(СтрокаТабличнойЧасти.НомерСтроки);	
	
	ИндСтр = ИндСтр - 1;
КонецЦикла;

Удаление строк табличной части

Удалить одну строку табличной части можно с помощью метода Удалить. Для удаления всех строк применяется метод Очистить.

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//удалить строку табличной части по индексу
//удалит вторую строку
ДокОбъект.СписокУслуг.Удалить(1);

//удалить все строки табличной части
ДокОбъект.СписокУслуг.Очистить();
//можно так
Для Каждого СтрТаблЧасть Из ДокОбъект.СписокУслуг Цикл
	ДокОбъект.СписокУслуг.Удалить(СтрТаблЧасть);	
КонецЦикла;	

//удалить строки табличной части по условию
//строки перебираем с конца
ИндСтр = ДокОбъект.СписокУслуг.Количество() - 1;
Пока ИндСтр >= 0 Цикл
	//по индексу получаем строку
	СтрокаТабличнойЧасти = ДокОбъект.СписокУслуг.Получить(ИндСтр);
	//удаляем все строки, где СуммаУслуги < 500
	Если СтрокаТабличнойЧасти.СуммаУслуги < 500 Тогда
		ДокОбъект.СписокУслуг.Удалить(СтрокаТабличнойЧасти);	
	КонецЕсли;
	
	//уменьшаем индекс
	ИндСтр = ИндСтр - 1;
КонецЦикла;	

//после удаления строк нужно записать объект
ДокОбъект.Записать();

Как выгрузить табличную часть

Табличную часть можно выгрузить в таблицу значений методом Выгрузить. Также можно выгрузить в массив все значения одной колонки методом ВыгрузитьКолонку:

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//выгрузить табличную часть в таблицу значений
//в таблице значений будут такие же колонки, 
//как в табличной части + колонка НомерСтроки
ТЗТаблЧасть = ДокОбъект.СписокУслуг.Выгрузить();

//можно указать какие колонки выгружать
ТЗТаблЧасть = ДокОбъект.СписокУслуг.Выгрузить(, "Услуга");

//можно указать отбор строк табличной части
ОтборСтрокТаблЧасти = Новый Структура;
ОтборСтрокТаблЧасти.Вставить("Услуга", СсылкаНаУслугу);
ТЗТаблЧасть = ДокОбъект.СписокУслуг.Выгрузить(ОтборСтрокТаблЧасти);

//можно выгрузить в массив
МассивУслуг = ДокОбъект.СписокУслуг.ВыгрузитьКолонку("Услуга");

Методом ВыгрузитьКолонки можно создать пустую таблицу значений с такими же колонками, как у табличной части:

//все колонки
ПустаяТЗ = ДокОбъект.СписокУслуг.ВыгрузитьКолонки();

//можно указать список колонок
ПустаяТЗ = ДокОбъект.СписокУслуг.ВыгрузитьКолонки("Услуга");

Итог по табличной части

Для получения итога по числовой колонке табличной части можно воспользоваться методом Итог:

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//параметром указывается имя колонки
СуммаВсего = ДокОбъект.СписокУслуг.Итог("СуммаУслуги");

Свернуть табличную часть

Чтобы свернуть табличную часть можно воспользоваться методом Свернуть. Первым параметром указывается список колонок группировки, вторым колонки суммирования. Все колонки табличной части должны быть указаны или в первом или во втором параметре.

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//сворачиваем табличную часть
ДокОбъект.СписокУслуг.Свернуть("Услуга", "СуммаУслуги");

//записываем
ДокОбъект.Записать();

Сортировка табличной части

Для сортировки табличной части используется метод Сортировать:

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//сортировка табличной части по возрастанию сумму
ДокОбъект.СписокУслуг.Сортировать("СуммаУслуги");

//сортировка табличной части по убыванию сумму
ДокОбъект.СписокУслуг.Сортировать("СуммаУслуги Убыв");

//записываем
ДокОбъект.Записать();

Поиск в табличной части

Чтобы найти строку в табличной части можно воспользоваться методами Найти и НайтиСтроки. Метод Найти позволяет найти одну (первую попавшуюся) строку по значению. Метод НайтиСтроки позволяет найти несколько строк, подходящих под условие:

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//найти строку с суммой равно 500
СтрокаТабличнойЧасти = ДокОбъект.СписокУслуг.Найти(500, "СуммаУслуги");
Если Не СтрокаТабличнойЧасти = Неопределено Тогда
	//нашли
КонецЕсли;

//найти все строки с суммой равной 500
СтрПоискаСтрок = Новый Структура;
СтрПоискаСтрок.Вставить("СуммаУслуги", 500);
МассивСтрокТаблЧасти = ДокОбъект.СписокУслуг.НайтиСтроки(СтрПоискаСтрок);
Для Каждого СтрокаТабличнойЧасти Цикл
	Сообщить(СтрокаТабличнойЧасти.НомерСтроки);
КонецЦикла;

ОЧИСТКА ТАБЛИЧНОЙ ЧАСТИ ДОКУМЕНТА

Каждый раз при выполнении кода могут добавляться новые строки, а вполне возможно, что пользователю старые строки не нужны. Поэтому, чтобы очищать имеющиеся строки, перед добавлением новых строк можно воспользоваться методом Очистить объекта СписокТоваров, который имеет тип ДанныйФормыКоллекция.

Объект.СписокТоваров.Очистить();

После выполнения этого метода вся табличная часть будет очищена.

ТЕКУЩАЯ СТРОКА ТАБЛИЧНОЙ ЧАСТИ

В процессе работы может возникнуть необходимость отработать текущую строку табличной части, т.е. ту строку, которая в данный момент выделена.

Например, может возникать ситуация, что мы редактируем какое-нибудь поле текущей строки таблицы на форме, и нам нужно, чтобы было пересчитано другое поле (или несколько полей) этой текущей строки. Например, мы изменяем цену (или количество) нашей табличной части, и необходимо, чтобы сумма автоматически была пересчитана.

Для решения данной задачи нужно воспользоваться свойством ТекущиеДанные элемента с типом ТаблицаФормы, который соответствует нужной табличной части. Свойство ТекущиеДанные возвращает значение полей текущей строки.

Для того, чтобы отработать изменение текущего поля цены, создадим обработчик события ПриИзменении этого поля.

В этом обработчике напишем код, который будет пересчитывать значения полей текущей строки табличной части.

&НаКлиенте
Процедура СписокТоваровЦенаПриИзменении(Элемент)
	ТекДанные = Элементы.СписокТоваров.ТекущиеДанные;
	Если ТекДанные = Неопределено Тогда
		Возврат; //если пустая таблица
	КонецЕсли;
	ТекДанные.Сумма = ТекДанные.Количество * ТекДанные.Цена;
КонецПроцедуры

Ещё пример: я создал команду, которая должна увеличивать количество в текущий строке табличной части в два раза и пересчитывать сумму. Эта команда размещена в командной панели таблицы и имеет следующий код:

&НаКлиенте
Процедура УмножитьНа2(Команда)
    ТекДанные = Элементы.СписокТоваров.ТекущиеДанные;
    Если ТекДанные = Неопределено Тогда
        Возврат; //если пустая таблица
    КонецЕсли;
    ТекДанные.Количество = ТекДанные.Количество * 2;
    ТекДанные.Сумма = ТекДанные.Количество * ТекДанные.Цена;
КонецПроцедуры

Теперь доработаем этот пример: после увеличения текущей строки будем сдвигать текущую строку на строку вниз. Для этого допишем предыдущий код:

Идентификтор = Элементы.СписокТоваров.ТекущаяСтрока;
ИдентификторСлед = Идентификтор + 1;

Если ИдентификторСлед < Объект.СписокТоваров.Количество() Тогда
    Элементы.СписокТоваров.ТекущаяСтрока = ИдентификторСлед;
КонецЕсли;

В этом коде мы получаем идентификатор текущий строки при помощи свойства таблицы управляемой формы ТекущаяСтрока, и если мы не выходим за приделы таблицы, то сдвигаем нашу текущую строку на один шаг вниз.

Также при помощи текущей строки можно находить аналогичную строку в соответствующей табличной части основного реквизита формы Объект, которую также можно изменять (строка на форме тоже изменится автоматически). Мы ранее сделали пересчет суммы при изменении цены, теперь сделаем пересчет суммы при изменении количества, но напрямую через реквизит Объект.

&НаКлиенте
Процедура СписокТоваровКоличествоПриИзменении(Элемент)
    Идентификтор = Элементы.СписокТоваров.ТекущаяСтрока;
    Если Идентификтор = Неопределено Тогда
        Возврат;
    КонецЕсли;
    ТекСтрока = Объект.СписокТоваров.НайтиПоИдентификатору(Идентификтор);
    Если ТекСтрока = Неопределено Тогда
        Возврат;
    КонецЕсли;
    ТекСтрока.Сумма = ТекСтрока.Цена * ТекСтрока.Количество;
КонецПроцедуры

В этом коде мы используем метод НайтиПоИдентификатору переменной Объект.СписокТоваров, которая имеет типа ДанныйФормыКоллекция, этот метод получает элемент коллекции по указанному идентификатору. Если этот элемент найден, то мы можем с ними работать, причем данные на форме изменяться автоматически.

Смотрите также:
Электронный учебник по программированию в 1С
Рекомендации по изучению программирования 1С с нуля
Игра «Кто хочет стать миллионером?» с вопросами на определенную тематику (язык программирования JavaScript, английские, немецкие, французские, испанские, португальские, ни­дер­ландские, итальянские слова, электробезопасность, промышленная безопасность, бокс и т.п.), написанная на 1С
Программирование в 1С 8.3 с нуля — краткий самоучитель
Комплексная подготовка программистов 1С:Предприятие 8.2
Сайты с уроками программирования и со справочниками
Youtube-каналы с уроками программирования
Сайты для обучения программированию
Лекции и уроки

Источник

Программное добавление реквизитов в табличную часть.

 Я
   НачинающийВ1С

18.06.19 — 11:08

Доброе утро.

На форму в общем модуле добавляю реквизиты в табличную часть «Товары» программно. В самом документе в табличной части реквизиты в конфигураторе добавлены. Добавляю абсолютно одинаково, но почему-то характеристика добавляется, а номенклатура нет.

На что обратить внимание, где может быть ошибка?

         Если Форма.ИмяФормы = «Документ.НашДокумент.Форма.ФормаДокумента» тогда

            
            ДобавляемыеРеквизиты    = Новый Массив;

        //реквизиты ТЧ Товары

        Номенклатура = Новый РеквизитФормы(«Номенклатура»,    Новый ОписаниеТипов(«СправочникСсылка.Номенклатура»),    «Объект.Товары», «Номенклатура»);

            Характеристика      = Новый РеквизитФормы(«Характеристика»,        Новый ОписаниеТипов(«СправочникСсылка.ХарактеристикиНоменклатуры»), «Объект.Товары», «Характеристика»);

                
        //Заполним массив после описания реквизитов формы

        ДобавляемыеРеквизиты.Добавить(Номенклатура);

        ДобавляемыеРеквизиты.Добавить(Характеристика);

        
        //Добавим новые реквизиты в форму

        Форма.ИзменитьРеквизиты(ДобавляемыеРеквизиты);

                
        //добавление на форму элементов ТЧ

        Номенклатура                = Форма.Элементы.Добавить(«Номенклатура», Тип(«ПолеФормы»), Форма.Элементы.Товары);

                Номенклатура.ПутьКДанным    = «Объект.Товары.Номенклатура»;

                Номенклатура.Вид            = ВидПоляФормы.ПолеВвода;

        
        Характеристика                = Форма.Элементы.Добавить(«Характеристика», Тип(«ПолеФормы»), Форма.Элементы.Товары);

        Характеристика.ПутьКДанным    = «Объект.Товары.Характеристика»;

        Характеристика.Вид            =ВидПоляФормы.ПолеВвода;

         КонецЕсли;

  

Партнерская программа EFSOL Oblako

   НачинающийВ1С

1 — 18.06.19 — 11:10

Замечу, что в отладчике в «Форма.Объект.Товары» оба реквизита присутствуют после обхода этих строк.

А вот уже в предприятии номенклатуры нет, а характеристика есть.

   НачинающийВ1С

2 — 18.06.19 — 11:12

(1) Да собственно и перед выводом самим в самом конце события «при открытии формы» в отладчике оба реквизита присутствуют.

   aleks_default

3 — 18.06.19 — 11:24

Почисти кэш

   НачинающийВ1С

4 — 18.06.19 — 11:33

(3) Чистил, не помогло. На всякий случай еще раз почистил, снова не помогло.

   RomanYS

5 — 18.06.19 — 11:40

>> В самом документе в табличной части реквизиты в конфигураторе добавлены

Зачем добавлять реквизиты формы, если они уже есть в метаданных. По идее ты вообще ошибку должен получить

   НачинающийВ1С

6 — 18.06.19 — 11:41

(5) А как правильно добавить на форму реквизиты?

Ошибок никаких не получаю.

   RomanYS

7 — 18.06.19 — 11:46

(6) Зачем это делать программно? Просто добавьте их в редакторе формы.

Код подобный вашему может быть использован для упрощения поддержки, когда непосредственное редактирование форм не рекомендуется. Но «НашДокумент» явно не тот случай.

   НачинающийВ1С

8 — 18.06.19 — 11:47

(7) «НашДокумент» это абстрактное название документа. Документ типовой. Как и Номенклатура и Характеристика это абстрактные названия реквизитов.

А сама задача вполне реальна. И требование заключается в том, что все реквизиты на форму добавляются в расширении программно.

   catena

9 — 18.06.19 — 11:48

+(5)ТОже не поняла. Достаточно же элементы добавить.

   catena

10 — 18.06.19 — 11:48

Вот этого должно хватить, если реквизиты в ТЧ есть:

//добавление на форму элементов ТЧ

        Номенклатура                = Форма.Элементы.Добавить(«Номенклатура», Тип(«ПолеФормы»), Форма.Элементы.Товары);

                Номенклатура.ПутьКДанным    = «Объект.Товары.Номенклатура»;

                Номенклатура.Вид            = ВидПоляФормы.ПолеВвода;

        
        Характеристика                = Форма.Элементы.Добавить(«Характеристика», Тип(«ПолеФормы»), Форма.Элементы.Товары);

        Характеристика.ПутьКДанным    = «Объект.Товары.Характеристика»;

        Характеристика.Вид            =ВидПоляФормы.ПолеВвода;

   НачинающийВ1С

11 — 18.06.19 — 11:53

(10) Убрал добавление самих реквизитов. Оставил только добавление элементов.

Все осталось как прежде — один реквизит добавляется, второй нет.

   НачинающийВ1С

12 — 18.06.19 — 11:54

(7) (10) Вы были правы, добавление реквизитов само по себе излишне. Уберу это в коде.

Но проблема с выводом на форму так и не решена.

   RomanYS

13 — 18.06.19 — 11:55

(8) Прикольно. Каков уровень абстракции: реквизит Номенклатура в ТЧ Товары !!!

(10) +1

(8) Проверь права, возможно на абстрактный добавленный тип их забыли установить. Вряд ли у тебя там добавлены абстрактные функциональные опции, но тоже проверь.

   НачинающийВ1С

14 — 18.06.19 — 11:56

(13) Запускаю с полными правами.

   RomanYS

15 — 18.06.19 — 11:58

(14) проверь ещё раз ПутьКДанным. Хотя при ошибке по идее исключение должно выдаваться

   RomanYS

16 — 18.06.19 — 12:00

Ещё имена переменных поменяй, вместо

Номенклатура                = Форма.Элементы.Добавить(«Номенклатура», Тип(«ПолеФормы»), Форма.Элементы.Товары);

делай

НовыйЭлементФормы = Форма.Элементы.Добавить(«Номенклатура», Тип(«ПолеФормы»), Форма.Элементы.Товары);

   НачинающийВ1С

17 — 18.06.19 — 12:02

(16) Имена переменных в базе итак другие (Элемент_ИмяЭлемента)

Путь к данным правильный.

В последней строке события «При открытии» по прежнему в «Объект.Товары» есть оба нужных реквизита. А в итоге почему-то только один.

   НачинающийВ1С

18 — 18.06.19 — 12:03

(17) Не в базе, а в моем коде.

   RomanYS

19 — 18.06.19 — 12:05

(17) В Объект.Товары они независимо от твоего кода — из метаданных расширения.

Смотри Форма.Элементы.ИмяТвоегоАбстактногоРеквизита: видимость, доступность…

   singlych

20 — 18.06.19 — 12:12

ставлю на функциональную опцию

   НачинающийВ1С

21 — 18.06.19 — 12:20

(19) Сверил.

Все строчки у обоих реквизитов идентичны.

   mikecool

22 — 18.06.19 — 12:25

добавить в конфигураторе, рулить видимостью — не вариант?

   НачинающийВ1С

23 — 18.06.19 — 12:26

(22) Вы имеете ввиду добавить в конфигураторе на форме не кодом? Не вариант так.

   mikecool

24 — 18.06.19 — 12:29

(23) как пожелаешь

   aleks_default

25 — 18.06.19 — 12:31

Вообще-то непонятно. Если реквизиты изначально есть, то почему изначально нет элементов формы для этих реквизитов? Они тоже тогда наверное должны быть. Может они тоже на самом деле уже есть, а их потом где-то дальше в коде скрывают(убирают видимость)?

   НачинающийВ1С

26 — 18.06.19 — 12:31

(24) Ну это не мое желание. Задание такое.

   НачинающийВ1С

27 — 18.06.19 — 12:32

(25) Потому что реквизиты добавлены мной вручную. А формы типовые.

   Вафель

28 — 18.06.19 — 12:32

(10) должно работать

   aleks_default

29 — 18.06.19 — 12:32

Может просмотреть код на наличие действий с элементами формы?

   aleks_default

30 — 18.06.19 — 12:34

(27) А тоесть ты реквизиты в расширении добавил?

   НачинающийВ1С

31 — 18.06.19 — 13:20

(30) Нет, сами реквизиты добавлены в конфигурации основной. А общий модуль, в котором приведенный код написан, находится в расширении. (29) Что имеется ввиду?

   RomanYS

32 — 18.06.19 — 13:24

(31) Озвучь уже тип проблемного реквизита, конфигурацию и вид типового документа. В твоей абстракции возможно совершено другие проблемы и ошибки чем в реальности.

   НачинающийВ1С

33 — 18.06.19 — 13:26

(32) Комплексная автоматизация 2 (2.4.7.109)

Документ «Коммерческое предложение клиенту».

В табличную часть не добавляется реквизит «Направление» (СправочникСсылка.НаправленияДеятельности)

   RomanYS

34 — 18.06.19 — 13:31

(33) Возможно Справочник.НаправленияДеятельности выключен фукнциональными опциями

   НачинающийВ1С

35 — 18.06.19 — 13:32

(34) Если добавлять просто на форму руками, все добавляется.

Как можно проверить выключен или нет?

   Avalone2010

36 — 18.06.19 — 14:49

(0) КА — типовая.Пустая.Включена ФО по КП. В модуле формы расширения.В процедуре при создании на сервере.

    НовыйЭлементФормы = Элементы.Добавить(«Товары_НаправлениеДеятельности», Тип(«ПолеФормы»), Элементы.Товары);

    НовыйЭлементФормы.ПутьКДанным    = «Объект.Товары._НаправлениеДеятельности»;

    НовыйЭлементФормы.Вид            = ВидПоляФормы.ПолеВвода;

В КП добавлен в ТЧ товары новый реквизит «_НаправлениеДеятельности».

   Avalone2010

37 — 18.06.19 — 15:03

(35) Настройки фин реза и контролинг. раздел финансовый результат. галочка финансовый результат по направлениям деятельности. константа ФормироватьФинансовыйРезультат

  

НачинающийВ1С

38 — 18.06.19 — 15:21

(37) Спасибо! Это решило вопрос.

Источник

Понравилась статья? Поделить с друзьями:
  • Как проехать в белгороде от автовокзала на проспект славы
  • Как проехать в москве к храму матроны московской в москве
  • Как проехать в москву на грузовом транспорте без пропуска
  • Как проехать границу с грузией на машине гражданам россии
  • Как проехать до кладбища ракитки общественным транспортом