Как передать реквизит формы в другую форму

Ключевые слова: передать значение, значение в форму, передать параметр, передать параметр в форму, параметр в форму, передать праметр в форму

Как из одной формы открыть другую, передав параметры, и получить обратно результат?

Варианты:

1. ОткрытьМодально, параметр закрытия, метод Закрыть

//первая форма
ВозвращаемоеЗначение = ДругаяФорма.ОткрытьМодально();

//в другой форме:
ЭтаФорма.Закрыть(ВозвращаемоеЗначение);

2. Реквизиты формы (или свойства расширения формы)

Реквизиты формы видимы снаружи как свойства объекта Форма. Их можно создать столько сколько нужно и присвоить им нужный тип.

//в первой форме
ДругаяФорма.ИмяРеквизита = Значение;

см. также: Книга знаний: v8: Реквизиты форм

3. Через ЭлементыФормы (не очень красиво)

//в первой форме
ДругаяФорма = ДокументСсылка.ПолучитьФорму();
ДругаяФорма.ЭлементыФормы.ИмяПоля.Значение = Значение;

4. Оповещения

//в первой форме оповестить все открытые формы
Оповестить("ИмяСобытия","Форма1",Данные)

//в другой форме назначить обработчик события Оповещение
Процедура ОбработкаОповещения(Событие, Источник, Данные)
   Если Событие = "ИмяСобытия" И Источник = "Форма1" Тогда
   КонецЕсли;
КонецПроцедуры

5. Экспортные переменные модулей форм

Они становятся видимы снаружи, примерно как реквизиты форм:

//в первой форме
ДругаяФорма.ИмяПеременной = Значение;

//в другой форме
Перем ИмяПеременной Экспорт;

6. Экспортные переменные модуля объекта, если он является основным реквизитом формы

Например, есть форма элемента справочника, т.е. ее основной реквизит имеет тип «СправочникОбъект.Номенклатура». Тогда экспортная переменная в модуле объекта расширяет контекст модуля формы и становится видна снаружи.

//в первой форме
ДругаяФорма.ИмяПеременной = Значение;

//в модуле объекта 
Перем ИмяПеременной Экспорт;

7. Глобальные переменные (экспортные переменные модуля приложения)

8. Внешний файл

9. СохранитьЗначение, ВосстановитьЗначение

10. Параметры сеанса

//в первой форме
ПараметрыСеанса.ИмяПараметра = Значение;

//в другой форме
Если ПараметрыСеанса.ИмяПараметра = Значение Тогда
КонецЕсли;

Обратите внимание! Попытка прочитать неинициализированный параметр сеанса приводит к ошибке! Поэтому нужно инициализировать все параметры сеанса раньше, например, еще в процедуре ПриНачалеРаботыСистемы.

11. Объекты базы данных (справочники, константы, регистры сведений и т.д.)

12. Частный случай — при вызове формы для выбора значения в элемент, например поле ввода, не передается ссылка на текущую форму, в которой этот элемент располагается. Поэтому данные или ссылку на эту форму можно передать в некоторых редко используемых реквизитах поля ввода, например: «СписокВыбора».

В этой статье я приведу небольшой пример, который может возникнуть в реальной жизни, и который будет полезен начинающим программистам 1С, особенно тем, кто столкнулся с открытием одной управляемой формы из другой формы и передачей значений с формы на форму.

Рассмотрим следующую задачу: в табличной части некоторого документа есть реквизит «Пояснение» (тип строка), для удобства работы пользователей необходимо сделать так, чтобы при нажатии на кнопку «Лупа» поля ввода этого реквизита текущей строки табличной части, открывалась форма с многострочным полем ввода, где пользователь может ввести нужный ему текст. После нажатия на кнопку «Поместить» открывшейся формы вся информация из поля ввода должна быть передана в соответствующее поле текущей строки табличной части.

Для демонстрации решения, я использую учебную конфигурацию, где в табличной части документа «Поступление товаров и услуга» имеется реквизит «Пояснение» (строка (250)).

На форме документа у поля «Пояснение» таблицы формы в свойство «КнопкаОткрытия» установим значение «Да».

В результате у нас у соответствующего поля на форме появится кнопка Открыть.

Теперь создадим произвольную форму документа, которую назовем ФормаВводаПояснения.

У этой формы создадим реквизит управляемой формы «Ввод пояснения» (строка (250))

И поместим этот реквизит на форму в виде поля ввода. У поля ввода установим многострочный режим и уберем заголовок.

У командной панели формы снимем флаг «Автозаполнение»

Создадим команду формы «Поместить», которую разместим в командной панели формы в виде кнопки. И у этой кнопки установим флаг у свойства «Кнопка по умолчанию»

Теперь займемся параметрами. Вполне возможно, что в нашем поле таблицы формы документа уже будет какая-то информация, поэтому её необходимо будет передать в форму ввода пояснения. Для этого на форме ввода пояснения создадим параметр ПриемникПояснения, в который, впоследствии, и будем передавать значение пояснения из формы документа.

Теперь сделаем так, чтобы при открытии формы значение из этого параметра передавалось в реквизит «Ввод пояснения» из нашей формы. Для этого у нашей формы ввода пояснения создадим событие при создании на сервере.

В этом обработчике напишем следующий код

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

ВводПояснения = Параметры.ПриемникПояснения;

КонецПроцедуры

Нам осталось отработать нажатие на кнопку «Поместить», для этого создадим обработчик соответствующей команды в клиентском контексте.

В этом обработчике мы будем закрывать форму, а в качестве параметра закрытия передадим реквизит формы.

&НаКлиенте
Процедура Поместить(Команда)

Закрыть(ВводПояснения);

КонецПроцедуры

С этой формой мы закончили, перейдем к форме документа. На форме документа у поля Пояснения таблицы формы создадим обработчик события ПриОткрытии в клиентском контексте.

Это событие возникает, когда пользователь нажимает на кнопку «Открыть» соответствующего поля.

В обработчике события, первым делом, в параметр СтандартнаяОбработка установим значение Ложь. Тогда при нажатии на кнопку открытия, не будет срабатывать стандартная обработка платформы, которая срабатывает при нажатии на эту кнопку.

&НаКлиенте
Процедура СписокТоваровПояснениеОткрытие(Элемент, СтандартнаяОбработка)

СтандартнаяОбработка = Ложь;

КонецПроцедуры

Теперь в этой же процедуре нам нужно получить значение поля Пояснение текущей строки.

ТекущаяСтрока = Элементы.СписокТоваров.ТекущиеДанные;
ЗначениеПояснения = ТекущаяСтрока.Пояснение;

Это значение мы будем передавать в качестве параметра в форму ввода пояснения при её открытии. Для этого я создам структуру, где в качестве ключа будет название параметра из формы ввода пояснения (ПриемникПояснения), который мы создали в форме ввода пояснения, а в качестве значения структуры будет значение, которое мы только что получили.

ПараметрыВвода = Новый Структура("ПриемникПояснения",ЗначениеПояснения);

Открывать формы мы будем при помощи метода глобального контекста ОткрытьФорму, передадим в неё параметры ввода, а также установим, чтобы блокировалось окно владельца.

ОткрытьФорму("Документ.ПоступлениеТоваров.Форма.ФормаВводаПояснения",ПараметрыВвода,,,,,,РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);

Если мы на этом остановимся, то у нас форма ввода пояснения откроется, информация из формы документа там появится, но информация с формы пояснения не будет передана в форму документа, как мы планировали. Для того, чтобы это произошло необходимо создать описание оповещения, в котором будет указан метод, который сработает после закрытия формы ввода описания. В конечном итоге у нас должен получиться следующий обработчик события нажатия на кнопку открытия.

&НаКлиенте
Процедура СписокТоваровПояснениеОткрытие(Элемент, СтандартнаяОбработка)

СтандартнаяОбработка = Ложь;
ТекущаяСтрока = Элементы.СписокТоваров.ТекущиеДанные;
ЗначениеПояснения = ТекущаяСтрока.Пояснение;

ПараметрыВвода = Новый Структура("ПриемникПояснения",ЗначениеПояснения);
ОписаниеОповещения = Новый ОписаниеОповещения("ПослеВыбораПояснения",ЭтаФорма);

ОткрытьФорму("Документ.ПоступлениеТоваров.Форма.ФормаВводаПояснения",ПараметрыВвода,,,,,ОписаниеОповещения,РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);

КонецПроцедуры

В описании оповещения мы указали процедуру ПослеВыбораПояснения. Нам необходимо создать такую процедуру в клиентском контексте, и сделать её экспортной.

&НаКлиенте
Процедура ПослеВыбораПояснения(Результат, ДопПараметры) Экспорт
Если Результат = Неопределено Тогда
Возврат;
КонецЕсли;
Элементы.СписокТоваров.ТекущиеДанные.Пояснение = Результат;
КонецПроцедуры

В этой процедуре, мы текущему значению поля Пояснение присваиваем результат закрытия формы ввода пояснения.

На этом наше программирование закончено. Работа выполнена.

Другие статьи про открытие управляемых форм:

Программное открытие управляемой формы выбора

Открытие управляемой формы по верх окон

Открытие обычной формы в управляемом приложении

Открытие формы на основании другого объекта

Открытие управляемой формы существующего объекта

Открытие управляемой формы с передачей параметров

Подробно вопросы передачи параметров, открытия форм рассмотрены в книге «Основы разработки в 1С: Такси. Разработка управляемого приложения за 12 шагов». Эта книга станет настоящим подспорьем для тех, кто только начал знакомиться с разработкой управляемого приложения.

Книга «Основы разработки в 1С: Такси»

Книга «Основы разработки в 1С: Такси» отлично подойдёт тем, кто уже начал программировать и испытывает определенные сложности с этой темой и тем, кто уже давно программирует, но ни разу еще не работал с управляемыми формами 1С

1. Без сложных технических терминов;
2. Более 600 страниц практического материала;
3. Каждый пример сопровождается рисунком (скриншот);
4. Книга посылается на электронную почту в формате PDF. Можно открыть на любом устройстве!

Промо-код на скидку в 15% — 48PVXHeYu

Изучайте программирование в 1С в месте с моей книгой «Программировать в 1С за 11 шагов»

Книга «Программировать в 1С за 11 шагов»

Пусть у нас есть есть документ ПриходнаяНакладная с табличной частью Состав. Для этого документа необходимо реализовать подбор номенклатур в табличную часть. Должна быть возможность переносить в документ несколько номенклатур за раз. То есть сначала пользователь подбирает номенклатуры в определенную таблицу, а затем по команде «Перенести в документ» данные из этой таблицы переносятся в табличную часть документа. При переносе в табличную часть, если номенклатура уже была добавлена ранее, нужно увеличить количество в этой строке на значение, указанное в подборе.

Рассмотрим два способа решения этой задачи: без обращения к серверу и с обращением к серверу.

Без обращения к серверу

Создадим форму списка у справочника Номенклатура не назначая ее основной. Добавим реквизит формы ПодобранныеНоменклатуры (тип ТаблицаЗначений) и разместим соответствующий элемент формы. Для полей динамического списка ЭтоГруппа и Ссылка установим флаг ИспользоватьВсегда. Чуть позже станет понятно, для чего.

Все действия выбора будут сводиться к добавлению строки в таблицу ПодобранныеНоменклатуры элементов динамического списка. Если элемент уже был добавлен в таблицу, то увеличиваем его количество. Код обработки выбора элемента списка номенклатуры:

&НаКлиенте
Процедура СписокВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
    // Проверка на наличие выбранной строки в динамическом списке
    ТекущиеДанные = Элементы.Список.ТекущиеДанные;
    Если ТекущиеДанные = Неопределено Тогда
        Возврат;
    КонецЕсли;       
    // Для групп номенклатуры подбор не производится. Именно для обращения
    // к свойству «ЭтоГруппа» был установлен флаг «Использовать всегда», иначе
    // при отсутствии колонки «Это группа» в списке вылетала бы ошибка
    // «Поле объекта не найдено»
    Если ТекущиеДанные.ЭтоГруппа Тогда
        Возврат;
    КонецЕсли;
    // Отключаем стандартную обработку
    СтандартнаяОбработка = Ложь;
    // Ищем товар в таблице ПодобранныеНоменклатуры. Если нет — добавляем
    // строку, иначе увеличиваем количество
    РезультатПоиска = ПодобранныеНоменклатуры.НайтиСтроки(
        Новый Структура("Наименование", ТекущиеДанные.Ссылка)
    );
    Если РезультатПоиска.Количество() = 0 Тогда
        Строка = ПодобранныеНоменклатуры.Добавить();
        Строка.Наименование = ТекущиеДанные.Ссылка;
    Иначе
        Строка = РезультатПоиска[0];
    КонецЕсли;
    Строка.Количество = Строка.Количество + 1;
КонецПроцедуры

Форма подбора номенклатур вызывается из формы документа ПриходнаяНакладная по команде Подбор:

&НаКлиенте
Процедура Подбор(Команда)
    // Первый параметр — полное имя формы, третий параметр — элемент формы,
    // в который осуществляется подбор (владелец). Последним параметром
    // передается уникальный идентификатор формы.
    ОткрытьФорму(
        "Справочник.Номенклатура.Форма.ФормаПодбораИзДокумента",
        ,
        Элементы.Состав,
        УникальныйИдентификатор
    );
КонецПроцедуры

Когда в форме выбора необходимые номенклатуры подобраны, выполняется команда ПеренестиКлиент:

&НаКлиенте
Процедура ПеренестиКлиент(Команда)
    // Передаем данные выбора владельцу формы, т.е. документу ПриходнаяНакладная
    ОповеститьОВыборе(ПодобранныеНоменклатуры); 
КонецПроцедуры

Теперь подобранные номенклатуры доступны в обработчике ОбработкаВыбора элемента формы документа:

&НаКлиенте
Процедура СоставОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
    // Заполняем таблицу документа подобранными номенклатурами
    Для Каждого Строка Из ВыбранноеЗначение Цикл
        РезультатПоиска = Объект.Состав.НайтиСтроки(
            Новый Структура("Номенклатура", Строка.Наименование)
        );
        Если РезультатПоиска.Количество() = 0 Тогда
            НоваяСтрока = Объект.Состав.Добавить();
            НоваяСтрока.Номенклатура = Строка.Наименование;
        Иначе
            НоваяСтрока = РезультатПоиска[0];    
        КонецЕсли;
        НоваяСтрока.Количество = НоваяСтрока.Количество + Строка.Количество;
    КонецЦикла;
КонецПроцедуры

С обращением к серверу

Отличия в реализации подбора будут в этом случае только в передаче данных в документ и, затем, обработки подобранных номенклатур в документе. Вот таким образом будет выглядеть команда передачи данных в документ из подбора:

&НаКлиенте
Процедура ПеренестиСервер(Команда)
    // Помещаем подобранные номенклатуры во временное хранилище на
    // сервере  и получаем соответствующий адрес в нем
    Адрес = ПодготовитьДанныеПодбора();
    // Передаем владельцу формы данные выбора 
    ОповеститьОВыборе(Адрес); 
КонецПроцедуры

&НаСервере
Функция ПодготовитьДанныеПодбора()
    // Выгружаем таблицу формы в таблицу значений для корректной
    // работы с данными на сервере
    ТаблицаПодобранныхНоменклатур = ПодобранныеНоменклатуры.Выгрузить();
    // Помещаем во временное хранилище и возвращаем адрес. Вторым параметром
    // передаем уникальный идентификатор формы. После закрытия формы данные
    // во временном хранилище будут очищены.
    Адрес = ПоместитьВоВременноеХранилище(
        ТаблицаПодобранныхНоменклатур,
        УникальныйИдентификатор
    );
    Возврат Адрес;
КонецФункции

Обработчик события ОбработкаВыбора элемента формы документа:

&НаКлиенте
Процедура СоставОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
    // Обрабатываем выбранные номенклатуры на сервере
    ОбработатьВыбранноеЗначение(ВыбранноеЗначение);
КонецПроцедуры

&НаСервере
Процедура ОбработатьВыбранноеЗначение(ВыбранноеЗначение)
    // Получаем таблицу подобранных номенклатур из хранилища
    ТаблицаПодобранныхНоменклатур = ПолучитьИзВременногоХранилища(ВыбранноеЗначение);
    // Заполняем таблицу документа подобранными номенклатурами
    Для Каждого Строка Из ТаблицаПодобранныхНоменклатур Цикл
        РезультатПоиска = Объект.Состав.НайтиСтроки(
            Новый Структура("Номенклатура", Строка.Наименование)
        );
        Если РезультатПоиска.Количество() = 0 Тогда
            НоваяСтрока = Объект.Состав.Добавить();
            НоваяСтрока.Номенклатура = Строка.Наименование;
        Иначе
            НоваяСтрока = РезультатПоиска[0];    
        КонецЕсли;
        НоваяСтрока.Количество = НоваяСтрока.Количество + Строка.Количество;
    КонецЦикла;    
КонецПроцедуры

Поиск:
1С:Предприятие • Документ • Обработка выбора • Открыть форму • Список • Справочник • Управляемая форма

Передача данных между обычными формами 1С

Открытие формы

Необходимо модально открыть произвольную форму с помощью функции ОткрытьФормуМодально().

Значение = ОткрытьФормуМодально("ВнешняяОбработка.ВнешняяОбработка1.Форма.Форма1"); 

Закрытие формы с возвратом значения

У открытой формы необходимо вызвать встроенный метод Закрыть(), который на вход принимает возвращаемое значение. Тип возвращаемого значения произвольный. В данном примере возвращается структура.

Процедура ДополнительнаяФормаКнопкаВыполнитьНажатие(Кнопка)
			Значение 
= Новый Структура();
	Значение.Вставить("Параметр1", "Значение1");
	Значение.Вставить("Параметр2", "Значение2");
	Значение.Вставить("Параметр3", "Значение3");
	ЭтаФорма.Закрыть(Значение);КонецПроцедуры