Как обратиться к реквизиту табличной части на форме 1с

08.09.06 — 22:35

Подскажите, пожалуйста, а то документации под рукой нет, и в v8 я чайник.

Как обратится к реквизиту табличной части, например, в процедуре ТабличнаяЧастьПриНачалеРедактирования() ?

И можно ли давать одинаковое имя основным реквизитам и реквизитам табличной части одного объекта?

1 — 08.09.06 — 22:37

К элементу формы или реквизиту документа/справочника?

2 — 08.09.06 — 22:42

К реквизиту справочника

3 — 08.09.06 — 22:44

+(1)

К реквизиту: ИмяТаблчасти.ИмяКолонки (выбирать можно, например в цикле ДляКаждого)

К эл.формы: ЭлементыФормы.ИмяТаблчасти… не помню дальше, см. хэлп :).

4 — 08.09.06 — 22:45

ИмяТаблчасти — таблица значений (стандартная коллекция) см. хэлп

5 — 08.09.06 — 22:54

(3)

Судя по тому что написано в хелпе — ИмяКолонки — это свойство объекта СтрокаТаблицыЗначений. А как к строке обратиться?

мне нужно при вводе новой строки в табличную часть присвоить ее реквизиту определенное значение

6 — 08.09.06 — 22:55

ИмяТаблчасти.ТекущиеДанные.ИмяКолонки

7 — 08.09.06 — 22:56

м.быть ИмяТаблчасти.ТекущиеДанные.ИмяКолонки.Значение, но скорее всего первый вариант

8 — 08.09.06 — 22:58

ЭлементыФормы.ИмяТабличнойЧасти.ТекущиеДанные.ИмяРеквизита

вот так получилось

как то сложно вроде…

9 — 08.09.06 — 23:00

(8) Привыкай, это еще цветочки :). Но зато и вкусности есть.

10 — 08.09.06 — 23:04

Спасибо

11 — 08.09.06 — 23:31

и правильно, что представление от данных отделили. Мне нравится

12 — 09.09.06 — 08:37

(8)

Все равно что то не так… А если у меня табличная часть на форме не размещена?

13 — 09.09.06 — 09:32

(12) А она все еще реквизит формы или таблчасть самого справочника? Разницу чуешь?

14 — 09.09.06 — 09:37

Она — табличная часть самого справочника. В данном случае табличное поле размещено на форме, поэтому (8) работает. А если бы я ее на форме не разместил?

15 — 09.09.06 — 09:40

Если бы ты ее не форме не размещал, то и интерактивный ввод данных пользователем был бы невозможен, тогда зачем тебе «текущие данные». Ввод данных в такую таблицу будет возможен только програмным путем, а там ты и так спозиционируешся на новой строке

16 — 09.09.06 — 09:47

(15)

А, ну да, вообще то…

17 — 09.09.06 — 11:04

(14) Ну к табличной части справочника можно обращаться напрямую без «Элементы формы», но тогда, действительно, «текущая строка» — мистика.

18 — 09.09.06 — 12:59

(17)

В этом случае надо обращаться к строке по индексу в [ ]

Так?

(18) Вроде бы так, попробуй.

 Как получить доступ к реквизитам формы?

Если реквизит объекта «вытащен» на форму, то реквизит формы можно получить через объект ЭлементыФормы, который содержит коллекцию элементов формы, сканируя ее в цикле:

ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
ДокОбъект = ДокСсылка.ПолучитьОбъект();
 
ФормаОбъекта = ДокОбъект.ПолучитьФорму();
Для Каждого Элемент Из ФормаОбъекта.ЭлементыФормы Цикл
        Сообщить(Элемент);
КонецЦикла;     
 

Этот цикл позволяет просмотреть имена а так же типы всех реквизитов формы, в том числе такие реквизиты как надписи, командные панели и тд.

Реквизиты формы могут быть различных типов. Поставив фильтр в виде типа реквизита мы можем просмотреть реквизиты определенного типа.

Если реквизит формы имеет тип «ТабличноеПоле», то можно такой элемент просканировать во вложенном цикле и узнать имена колонок таблицы:

 
Для Каждого Элемент Из ФормаОбъекта.ЭлементыФормы Цикл
        Сообщить(Элемент.Имя);
        Если Тип(Элемент) = Тип("ТабличноеПоле") Тогда
                Сообщить(" Это табличное поле! "  + Элемент.Имя );
                Для Каждого Колонка Из Элемент.Колонки Цикл
                        ИмяКолонки = Колонка.Имя;
                        Сообщить(ИмяКолонки);
                КонецЦикла;
        КонецЕсли;      
КонецЦикла;     
 

Как получить значение отдельного реквизита формы?

Чаще требуется получать не массив реквизитов формы,  а значение отдельных конкретных реквизитов формы. Например реквизиты «Шапки» или «Подвала» формы документа.

Пример:

 
ФормаОбъекта = ДокОбъект.ПолучитьФорму("ФормаДокумента");
Поставщик = ФормаОбъекта.ЭлементыФормы.Поставщик;
Поставщик = ФормаОбъекта.ЭлементыФормы.Получатель;
Сообщить(ФормаОбъекта.ЭлементыФормы.ТаблПоле.Колонки.Количество());
 

Реквизиты шапки могут иметь различные типы: Дата, СправочникСсылка, ЧекБокс, элемент раскрывающегося списка и др.

Как получить значение элементов табличной части формы?

Доступ к табличной части формы через объект

Доступ к табличной части формы (например: Товары) можно получить через объект:

 
  ДокОбъект = Док.ПолучитьОбъект(); //здесь Док - ссылка на объект
  //просканируем построчно таб часть документа
  Для Каждого Стр из ДокОбъект.Товары Цикл
      Номенклатура = Стр.Номенклатура;
      Стр.Коэффициент = 1;
  КонецЦикла;
 

Здесь ДокОбъект.Товары — это табличная часть «Товары» объекта. Далее в цикле табличная часть построчно сканируется!
В каждой итерации цикла можно получить доступ к любому полю строки указав через точку имя этого поля:

      Номенклатура = Стр.Номенклатура;

Доступ к табличной части формы через ЭлементыФормы

Табличная часть объекта и табличная часть формы объекта — это не одно и то же!

Для того, чтобы код работал правильно, надо чтобы колонка формы табчасти объекта в свойстве данные ссылалась на реквизит табличной части объекта. Этим определяется тип колонки таб части формы.

То есть должна быть установлена связь между реквизитом табчасти объекта и реквизитом табчасти формы. Форм у объекта метаданных может быть много мы знаем. Табличную часть формы объекта можно получить через объект ЭлементыФормы:

Объект ЭлементыФормы используется для доступа к элементам управления, расположенным на форме, в частности к таб части документа.

 
        ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
        ДокОбъект = ДокСсылка.ПолучитьОбъект();
                                
        ФормаОбъекта = ДокОбъект.ПолучитьФорму();
        Для Каждого Элемент Из ФормаОбъекта.ЭлементыФормы Цикл
                Если Тип(Элемент) = Тип("ТабличноеПоле") Тогда //элемент формы - табличное поле
                                                        
                        Если Элемент.Имя = "Товары" Тогда
                                Сообщить("Это табличное поле!! "  + Элемент.Имя );
                                
                                //ТабПоле = ФормаОбъекта.ЭлементыФормы.Товары.Значение;
                                ТабПоле = Элемент.Значение;
                                Колво = ТабПоле.Количество();
                                Сообщить("Количество строк: " + Колво); 
                                
                                Для Каждого ТекущаяСтрока Из ТабПоле Цикл
                                        
                                        Имя = ТекущаяСтрока.Номенклатура;
                                        Сообщить(Имя); 
                
                                КонецЦикла;                             
                                
                        КонецЕсли;      
                                                        
                КонецЕсли;                                      
        КонецЦикла;  
 

Результат для документа Авансовый отчет:

Это табличное поле!! Товары
Количество строк: 4
Женские ботфорты коричневые
Ботинки женские демисезонные
Ботинки женские натуральная кожа
Женские босоножки       

Если надо получить значение всех колонок всех строк, то организуем дважды вложенный цикл:
Во внешнем цикле сканируются строки, во внутреннем — колонки:

 
        ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
        ДокОбъект = ДокСсылка.ПолучитьОбъект();
                                
        ФормаОбъекта = ДокОбъект.ПолучитьФорму("ФормаДокумента");
        Для Каждого Элемент Из ФормаОбъекта.ЭлементыФормы Цикл
                Если Тип(Элемент) = Тип("ТабличноеПоле") Тогда
                                                        
                        Если Элемент.Имя = "ВыданныеАвансы" Тогда //таб часть объекта
                                Сообщить(" Это табличное поле!! "  + Элемент.Имя );
                                
                                ТабПоле = Элемент.Значение;
                                Индекс = 0;
                                Для Каждого ТекущаяСтрока Из ТабПоле Цикл
                                        
                                        Сообщить("=======================");
                                        Для Каждого Колонка Из Элемент.Колонки Цикл
                                                
                                                ИмяКолонки = Строка(Колонка.Имя);
                                                Сообщить(ИмяКолонки);
                                                Имя = ТекущаяСтрока[ИмяКолонки];//сработает только если есть такое поле таб части объекта
                                                Сообщить("=== " + Имя); 
                                                
                                        КонецЦикла;
                                        
                                        Индекс = Индекс + 1;
                                        Если Индекс > 0 Тогда break КонецЕсли; //только первая строка
                                        
                                        
                                КонецЦикла;                             
                                
                                                        
                        КонецЕсли;      
                                                        
                КонецЕсли;                                      
        КонецЦикла;    
 

Результат для документа Авансовый отчет:

Многие объекты метаданных в 1С могут иметь табличную часть. У одного объекта может быть создано неограниченное количество табличных частей.

Табличная часть может быть создана только как подчиненный объект у какого-либо объекта метаданных, например у справочника или у документа.

Строка табличной части не является отдельным объектом. К строке можно обратиться только по индексу строки в табличной части.

Программно нельзя создать табличную часть через конструктор. Можно только получить к ней доступ через основной объект:

//создаем объект
НовыйДок = Документы.РасходТовара.СоздатьДокумент();
//через объект получаем доступ к табличной части СписокУслуг
ТабЧастьДока = НовыйДок.СписокУслуг;

Строка табличной части

Добавить новую строку табличной части можно с помощью методов Добавить и Вставить. Через точку от строки табличной части можно обращаться к реквизитам строки:

//добавление строки табличной части
СтрокаТабличнойЧасти = НовыйДок.СписокУслуг.Добавить();
СтрокаТабличнойЧасти.Услуга = СсылкаНаУслугу;
СтрокаТабличнойЧасти.СуммаУслуги = 900;

//для метода Вставить нужно указать индекс строки
СтрокаТабличнойЧасти = НовыйДок.СписокУслуг.Вставить(1);
СтрокаТабличнойЧасти.Услуга = СсылкаНаУслугу;
СтрокаТабличнойЧасти.СуммаУслуги = 800;

//у строки есть предопределенная колонка НомерСтроки
Сообщить(СтрокаТабличнойЧасти.НомерСтроки); //2
//в отличии от индексов номера строк начинаются с 1

Заполнение табличной части

Заполнить табличную часть можно по одной строке с помощью методов Добавить и Вставить, а также с помощью методов Загрузить и ЗагрузитьКолонку для массового заполнения табличной части:

//создаем таблицу значений
ТЗТаблЧасть = Новый ТаблицаЗначений;
ТЗТаблЧасть.Колонки.Добавить("Услуга");
ТЗТаблЧасть.Колонки.Добавить("СуммаУслуги");

СтрокаТЗ = ТЗТаблЧасть.Вставить(1);
СтрокаТЗ.Услуга = СсылкаНаУслугу;
СтрокаТЗ.СуммаУслуги = 800;

СтрокаТЗ = ТЗТаблЧасть.Вставить(1);
СтрокаТЗ.Услуга = СсылкаНаУслугу;
СтрокаТЗ.СуммаУслуги = 900;

//создаем документ
НовыйДок = Документы.РасходТовара.СоздатьДокумент();

//заполнение табличной части из таблицы значений
//имена колонок должны совпадать
//все прежние строки будут удалены из табличной части
НовыйДок.СписокУслуг.Загрузить(ТЗТаблЧасть);

МассивТаблЧасть = Новый Массив;
МассивТаблЧасть.Добавить(500);
МассивТаблЧасть.Добавить(600);

//заполнение одной колонки табличной части
//все значения из массива будут загружены в колонку СуммаУслуги
НовыйДок.СписокУслуг.ЗагрузитьКолонку(МассивТаблЧасть, "СуммаУслуги");

Перебор табличной части

Перебрать табличную часть можно в цикле:

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//обход табличной части через цикл Для Каждого
Для Каждого СтрокаТабличнойЧасти Из ДокОбъект.СписокУслуг Цикл
	Сообщить(СтрокаТабличнойЧасти.НомерСтроки);
КонецЦикла;	

//количество строк табличной части
КолвоСтрок = ДокОбъект.СписокУслуг.Количество();

//Перебор табличной части через цикл Для
Для ё = 0 По КолвоСтрок Цикл
	//строку можно получить через квадратные скобки
	СтрокаТабличнойЧасти = ДокОбъект.СписокУслуг[ё];
	Сообщить(СтрокаТабличнойЧасти.НомерСтроки);
	
	//или методом Получить
	СтрокаТабличнойЧасти = ДокОбъект.СписокУслуг.Получить(ё);
	Сообщить(СтрокаТабличнойЧасти.НомерСтроки);
КонецЦикла;	

//через цикл Пока можно перебрать табличную часть с конца 
ИндСтр = КолвоСтрок; 
Пока ИндСтр > 0 Цикл
	//строку можно получить через квадратные скобки
	СтрокаТабличнойЧасти = ДокОбъект.СписокУслуг[ИндСтр];
	Сообщить(СтрокаТабличнойЧасти.НомерСтроки);	
	
	ИндСтр = ИндСтр - 1;
КонецЦикла;	

Удаление строк табличной части

Удалить одну строку табличной части можно с помощью метода Удалить. Для удаления всех строк применяется метод Очистить.

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//удалить строку табличной части по индексу
//удалит вторую строку
ДокОбъект.СписокУслуг.Удалить(1);

//удалить все строки табличной части
ДокОбъект.СписокУслуг.Очистить();
//можно так
Для Каждого СтрТаблЧасть Из ДокОбъект.СписокУслуг Цикл
	ДокОбъект.СписокУслуг.Удалить(СтрТаблЧасть);	
КонецЦикла;	

//удалить строки табличной части по условию
//строки перебираем с конца
ИндСтр = ДокОбъект.СписокУслуг.Количество() - 1;
Пока ИндСтр >= 0 Цикл
	//по индексу получаем строку
	СтрокаТабличнойЧасти = ДокОбъект.СписокУслуг.Получить(ИндСтр);
	//удаляем все строки, где СуммаУслуги < 500
	Если СтрокаТабличнойЧасти.СуммаУслуги < 500 Тогда
		ДокОбъект.СписокУслуг.Удалить(СтрокаТабличнойЧасти);	
	КонецЕсли;
	
	//уменьшаем индекс
	ИндСтр = ИндСтр - 1;
КонецЦикла;	

//после удаления строк нужно записать объект
ДокОбъект.Записать();

Как выгрузить табличную часть

Табличную часть можно выгрузить в таблицу значений методом Выгрузить. Также можно выгрузить в массив все значения одной колонки методом ВыгрузитьКолонку:

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//выгрузить табличную часть в таблицу значений
//в таблице значений будут такие же колонки, 
//как в табличной части + колонка НомерСтроки
ТЗТаблЧасть = ДокОбъект.СписокУслуг.Выгрузить();

//можно указать какие колонки выгружать
ТЗТаблЧасть = ДокОбъект.СписокУслуг.Выгрузить(, "Услуга");

//можно указать отбор строк табличной части
ОтборСтрокТаблЧасти = Новый Структура;
ОтборСтрокТаблЧасти.Вставить("Услуга", СсылкаНаУслугу);
ТЗТаблЧасть = ДокОбъект.СписокУслуг.Выгрузить(ОтборСтрокТаблЧасти);

//можно выгрузить в массив
МассивУслуг = ДокОбъект.СписокУслуг.ВыгрузитьКолонку("Услуга");

Методом ВыгрузитьКолонки можно создать пустую таблицу значений с такими же колонками, как у табличной части:

//все колонки
ПустаяТЗ = ДокОбъект.СписокУслуг.ВыгрузитьКолонки();

//можно указать список колонок
ПустаяТЗ = ДокОбъект.СписокУслуг.ВыгрузитьКолонки("Услуга");

Итог по табличной части

Для получения итога по числовой колонке табличной части можно воспользоваться методом Итог:

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//параметром указывается имя колонки
СуммаВсего = ДокОбъект.СписокУслуг.Итог("СуммаУслуги");

Свернуть табличную часть

Чтобы свернуть табличную часть можно воспользоваться методом Свернуть. Первым параметром указывается список колонок группировки, вторым колонки суммирования. Все колонки табличной части должны быть указаны или в первом или во втором параметре.

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//сворачиваем табличную часть
ДокОбъект.СписокУслуг.Свернуть("Услуга", "СуммаУслуги");

//записываем
ДокОбъект.Записать();

Сортировка табличной части

Для сортировки табличной части используется метод Сортировать:

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//сортировка табличной части по возрастанию сумму
ДокОбъект.СписокУслуг.Сортировать("СуммаУслуги");

//сортировка табличной части по убыванию сумму
ДокОбъект.СписокУслуг.Сортировать("СуммаУслуги Убыв");

//записываем
ДокОбъект.Записать();

Поиск в табличной части

Чтобы найти строку в табличной части можно воспользоваться методами Найти и НайтиСтроки. Метод Найти позволяет найти одну (первую попавшуюся) строку по значению. Метод НайтиСтроки позволяет найти несколько строк, подходящих под условие:

//из ссылки получаем объект
ДокОбъект = СсылкаНаДок.ПолучитьОбъект();

//найти строку с суммой равно 500
СтрокаТабличнойЧасти = ДокОбъект.СписокУслуг.Найти(500, "СуммаУслуги");
Если Не СтрокаТабличнойЧасти = Неопределено Тогда
	//нашли
КонецЕсли;

//найти все строки с суммой равной 500
СтрПоискаСтрок = Новый Структура;
СтрПоискаСтрок.Вставить("СуммаУслуги", 500);
МассивСтрокТаблЧасти = ДокОбъект.СписокУслуг.НайтиСтроки(СтрПоискаСтрок);
Для Каждого СтрокаТабличнойЧасти Цикл
	Сообщить(СтрокаТабличнойЧасти.НомерСтроки);
КонецЦикла;	

ОЧИСТКА ТАБЛИЧНОЙ ЧАСТИ ДОКУМЕНТА

Каждый раз при выполнении кода могут добавляться новые строки, а вполне возможно, что пользователю старые строки не нужны. Поэтому, чтобы очищать имеющиеся строки, перед добавлением новых строк можно воспользоваться методом Очистить объекта СписокТоваров, который имеет тип ДанныйФормыКоллекция.

Объект.СписокТоваров.Очистить();

После выполнения этого метода вся табличная часть будет очищена.

ТЕКУЩАЯ СТРОКА ТАБЛИЧНОЙ ЧАСТИ

В процессе работы может возникнуть необходимость отработать текущую строку табличной части, т.е. ту строку, которая в данный момент выделена.

Например, может возникать ситуация, что мы редактируем какое-нибудь поле текущей строки таблицы на форме, и нам нужно, чтобы было пересчитано другое поле (или несколько полей) этой текущей строки. Например, мы изменяем цену (или количество) нашей табличной части, и необходимо, чтобы сумма автоматически была пересчитана.

Для решения данной задачи нужно воспользоваться свойством ТекущиеДанные элемента с типом ТаблицаФормы, который соответствует нужной табличной части. Свойство ТекущиеДанные возвращает значение полей текущей строки.

Для того, чтобы отработать изменение текущего поля цены, создадим обработчик события ПриИзменении этого поля.

В этом обработчике напишем код, который будет пересчитывать значения полей текущей строки табличной части.

&НаКлиенте
Процедура СписокТоваровЦенаПриИзменении(Элемент)
	ТекДанные = Элементы.СписокТоваров.ТекущиеДанные;
	Если ТекДанные = Неопределено Тогда
		Возврат; //если пустая таблица
	КонецЕсли;
	ТекДанные.Сумма = ТекДанные.Количество * ТекДанные.Цена;
КонецПроцедуры

Ещё пример: я создал команду, которая должна увеличивать количество в текущий строке табличной части в два раза и пересчитывать сумму. Эта команда размещена в командной панели таблицы и имеет следующий код:

&НаКлиенте
Процедура УмножитьНа2(Команда)
    ТекДанные = Элементы.СписокТоваров.ТекущиеДанные;
    Если ТекДанные = Неопределено Тогда
        Возврат; //если пустая таблица
    КонецЕсли;
    ТекДанные.Количество = ТекДанные.Количество * 2;
    ТекДанные.Сумма = ТекДанные.Количество * ТекДанные.Цена;
КонецПроцедуры

Теперь доработаем этот пример: после увеличения текущей строки будем сдвигать текущую строку на строку вниз. Для этого допишем предыдущий код:

Идентификтор = Элементы.СписокТоваров.ТекущаяСтрока;
ИдентификторСлед = Идентификтор + 1;

Если ИдентификторСлед < Объект.СписокТоваров.Количество() Тогда
    Элементы.СписокТоваров.ТекущаяСтрока = ИдентификторСлед;
КонецЕсли;

В этом коде мы получаем идентификатор текущий строки при помощи свойства таблицы управляемой формы ТекущаяСтрока, и если мы не выходим за приделы таблицы, то сдвигаем нашу текущую строку на один шаг вниз.

Также при помощи текущей строки можно находить аналогичную строку в соответствующей табличной части основного реквизита формы Объект, которую также можно изменять (строка на форме тоже изменится автоматически). Мы ранее сделали пересчет суммы при изменении цены, теперь сделаем пересчет суммы при изменении количества, но напрямую через реквизит Объект.

&НаКлиенте
Процедура СписокТоваровКоличествоПриИзменении(Элемент)
    Идентификтор = Элементы.СписокТоваров.ТекущаяСтрока;
    Если Идентификтор = Неопределено Тогда
        Возврат;
    КонецЕсли;
    ТекСтрока = Объект.СписокТоваров.НайтиПоИдентификатору(Идентификтор);
    Если ТекСтрока = Неопределено Тогда
        Возврат;
    КонецЕсли;
    ТекСтрока.Сумма = ТекСтрока.Цена * ТекСтрока.Количество;
КонецПроцедуры

В этом коде мы используем метод НайтиПоИдентификатору переменной Объект.СписокТоваров, которая имеет типа ДанныйФормыКоллекция, этот метод получает элемент коллекции по указанному идентификатору. Если этот элемент найден, то мы можем с ними работать, причем данные на форме изменяться автоматически.

Смотрите также:
Электронный учебник по программированию в 1С
Рекомендации по изучению программирования 1С с нуля
Игра «Кто хочет стать миллионером?» с вопросами на определенную тематику (язык программирования JavaScript, английские, немецкие, французские, испанские, португальские, ни­дер­ландские, итальянские слова, электробезопасность, промышленная безопасность, бокс и т.п.), написанная на 1С
Программирование в 1С 8.3 с нуля — краткий самоучитель
Комплексная подготовка программистов 1С:Предприятие 8.2
Сайты с уроками программирования и со справочниками
Youtube-каналы с уроками программирования
Сайты для обучения программированию
Лекции и уроки

Табличные части существуют у многих объектов в 1С:

• Справочники
• Документы
• Отчеты и обработки
• Планы счетов
• Планы видов характеристик
• Планы видов расчета
• Бизнес-процессы и задачи

Табличные части позволяют хранить неограниченное количество структурированной информации, принадлежащей одному объекту.

Рассмотрим некоторые приемы работы с табличными частями.

Как обойти табличную часть

Для обхода табличной части можно использовать цикл Для каждого

На каждой итерации в переменную Строка передается очередная строка табличной части. Значения реквизитов строки можно получить выражением Строка.ИмяРеквизита.

Как получить и обойти выделенные строки табличной части

Для вывода информации из табличной части объекта служит элемент формы Табличное поле. Для включения возможности выделения нескольких строк на табличном поле нужно установить значение Множественный у его свойства Режим выделения.

Для получения перечня выделенных строк используется следующий код:

Для того чтобы обойти выделенные строки используется цикл Для каждого:

Как программно выделить строки табличной части (табличного поля) и снять выделение

Чтобы программно снять выделение строк табличного поля:

Чтобы программно выделить все строки табличного поля:

Как очистить табличную часть

Как получить текущую строку табличной части

Текущая строка — это срока, в которой у пользователя в данный момент находится курсор. Чтобы ее получить, нужно обратиться к элементу управления на форме, который связан с табличной частью.

Для обычных форм код будет выглядеть так:

Для управляемых форм:

Как добавить новую строку в табличную часть

Добавление новой строки в конец табличной части:

Добавление новой строки в любое место табличной части (последующие строки будут сдвинуты):

Как программно заполнить реквизиты строки табличной части

Если нужно программно заполнить реквизиты строки табличной части, которую добавляет пользователь, необходимо использовать обработчик события табличной части ПриНачалеРедактирования.

Создаваемая обработчиком процедура имеет три параметра:

• Элемент — содержит элемент управления ТабличноеПоле.
• НоваяСтрока — булево. Содержит значение Истина, если добавляется новая строка табличной части, и Ложь, если пользователь начал редактировать уже существующую строку.
• Копирование — булево. Содержит значение Истина, если пользователь копирует строку, и Ложь в остальных случаях.

Рассмотрим пример. Допустим, нам нужно заполнить реквизит табличной части СчетУчета, в случае, когда добавляется новая строка. При редактировании существующей строки изменять счет учета не нужно.