1с вывести табличный документ в реквизит формы

Оглавление (нажмите, чтобы раскрыть)

&НаКлиенте
Процедура ФормируемПечатнуюФормуИзТабличногоМакета(Команда)
 
    // В макетах обработки у нас определен макет с именем
    // ТабличныйМакет и типом ТабличныйДокумент.
    // Вот как создаются такие макеты:
    // helpme1s.ru/kak-sozdat-tablichnyj-maket-v-1s
 
    // Сформируем печатную форму на основе этого макета.
 
    // Важно понимать, что сама печатная форма - это тоже
    // табличный документ, просто составленный из кусочков других
    // документов (макетов).
 
    // Печатная форма формируется на сервере, а затем
    // возвращается обратно на клиент...
 
    ПечатнаяФорма = СформироватьПечатнуюФормуИзТабличногоДокумента();
 
    НастроитьКолонтитулы(ПечатнаяФорма);
    НастроитьПараметрыПечати(ПечатнаяФорма);
 
    // ... чтобы вывести её пользователю в виде отдельного окна
 
    ПечатнаяФорма.Показать(
        "Наш отчёт"  // заголовок окна с отчётом
    );
 
    // после показа пользователь может сам и распечатать
    // и сохранить эту форму, но ...
 
    // .. мы можем программно сами сохранить форму в файл в нужном формате
 
    //ПечатнаяФорма.Записать(
    //    СлужебныйНаКлиенте.СоздатьПапкуДляЭкспериментов() + "Наш отчёт.xls",
    //    ТипФайлаТабличногоДокумента.XLS
    //);
 
    // .. или сразу отправить её на принтер
 
    //ПечатнаяФорма.Напечатать(
    //    РежимИспользованияДиалогаПечати.НеИспользовать);
 
КонецПроцедуры
 
/// Как сформировать печатную форму из табличного документа в 1с 8.3, 8.2
 
&НаСервере
Функция СформироватьПечатнуюФормуИзТабличногоДокумента()
 
    // Получаем макет, сохраненный в нашей обработке.
    Макет = Обработки.ОбработкаДляИспытаний.ПолучитьМакет("ТабличныйМакет");    
 
    // Вот так можно изменить табличный макет программно,
    // уже после его создания.
    МеняемТабличныйДокументПрограммно(Макет);
 
    ПечатнаяФорма = Новый ТабличныйДокумент;
 
    // # Шапка документа #
 
    // Получаем область "Шапка" из макета.
    Шапка = Макет.ПолучитьОбласть("Шапка");
    // Заполняем её параметры.
    Шапка.Параметры.Номер = 1;
    Шапка.Параметры.Дата = Формат(ТекущаяДата(), "ДФ=dd.MM.yyyy");    
    // Выводим её в нашу печатную форму.
    ПечатнаяФорма.Вывести(Шапка);
 
    // # Заголовок табличной части #
    ТабличнаяЧастьЗаголовок = Макет.ПолучитьОбласть("ТабличнаяЧастьЗаголовок");
    ПечатнаяФорма.Вывести(ТабличнаяЧастьЗаголовок);
 
    // # Строки табличной части #
 
    // Если при выводе строк наша таблица не поместится на страницу -
    // будем повторять заголовок таблицы в начале страницы.
    // Выводим с 3 по 4 строки - это как раз заголовок таблицы.
    // Использовать область "ТабличнаяЧастьЗаголовок" не получится,
    // так как нужны именно строки целиком.
    ПечатнаяФорма.ПовторятьПриПечатиСтроки = Макет.Область(3,,4);
 
    ТабличнаяЧастьСтрока = Макет.ПолучитьОбласть("ТабличнаяЧастьСтрока");
    СсылкаНаКлубнику = Справочники.Номенклатура.НайтиПоНаименованию("Клубника");
 
    // Сгруппируем строки таблицы в сворачивающийся блок.
    ПечатнаяФорма.НачатьГруппуСтрок("Товар", Истина);
 
    Для Шаг = 1 По 100 Цикл
        ТабличнаяЧастьСтрока.Параметры.Номенклатура = СсылкаНаКлубнику;
        ТабличнаяЧастьСтрока.Параметры.Количество = Шаг;
 
        // В макете мы выделили ячейку с номенклатурой и прописали
        // её параметр расшифровки "РасшифровкаНоменклатуры".
        // Заполним этот параметр, чтобы когда пользователь кликнет
        // два раза по товару - открылась его форма.
        // Дополнительный пример обработки расшифровки - см. ниже,
        // когда мы выводим табличный документ в поле формы.
        ТабличнаяЧастьСтрока.Параметры.РасшифровкаНоменклатуры = СсылкаНаКлубнику;
 
        ПечатнаяФорма.Вывести(ТабличнаяЧастьСтрока);
    КонецЦикла;
 
    // Закончим начатую группировку.
    ПечатнаяФорма.ЗакончитьГруппуСтрок();    
 
    Возврат ПечатнаяФорма;
 
КонецФункции
 
/// Как настроить колонтитулы печатной формы в 1с 8.3, 8.2
 
&НаКлиенте
Процедура НастроитьКолонтитулы(ПечатнаяФорма)
 
    // Верхний колонтитул.
    ПечатнаяФорма.ВерхнийКолонтитул.Выводить = Истина;
    ПечатнаяФорма.ВерхнийКолонтитул.НачальнаяСтраница = 1;
    ПечатнаяФорма.ВерхнийКолонтитул.ТекстВЦентре = "Этот отчёт сделан нами для тестов";
    ПечатнаяФорма.ВерхнийКолонтитул.ВертикальноеПоложение = ВертикальноеПоложение.Центр;
 
    // Нижний колонтитул.
    ПечатнаяФорма.НижнийКолонтитул.Выводить = Истина;
    ПечатнаяФорма.НижнийКолонтитул.ТекстСправа = "[&НомерСтраницы] из [&СтраницВсего]";        
    ПечатнаяФорма.НижнийКолонтитул.ТекстВЦентре = "[&Дата][&Время]";
 
    // Использованные выше конструкции [&НомерСтраницы] и т.п. предопределены
    // платформой.
 
КонецПроцедуры
 
/// Как настроить параметры печати табличного документа в 1с 8.3, 8.2
 
&НаКлиенте
Процедура НастроитьПараметрыПечати(ПечатнаяФорма)
 
    // Можно установить конкретный масштаб:
    ПечатнаяФорма.МасштабПечати = 60; // 60%
    // Или указать вариант "по ширине страницы"
    ПечатнаяФорма.АвтоМасштаб = Истина;
 
    // Поля страницы
    ПечатнаяФорма.ПолеСлева = 10;
    ПечатнаяФорма.ПолеСверху = 10;
    ПечатнаяФорма.ПолеСправа = 10;
    ПечатнаяФорма.ПолеСнизу = 10;
 
    // Партрет или альбом (ландшафт).
    ПечатнаяФорма.ОриентацияСтраницы = ОриентацияСтраницы.Портрет;
 
    // Двусторонняя печать позволяет очень экономить бумагу.
    ПечатнаяФорма.ДвусторонняяПечать = ТипДвустороннейПечати.Нет;
 
    // Количество страниц на листе при выводе документа на печать.
    // 1 - одна страницы, 2 - две, 0 - автоматическое определение.
    ПечатнаяФорма.ЭкземпляровНаСтранице = 1;
 
    // Количество копий документа, которое нужно напечатать.
    ПечатнаяФорма.КоличествоЭкземпляров = 1;    
 
    // Если печатаем несколько экземпляров - очень удобная галка.
    ПечатнаяФорма.РазборПоКопиям = Истина;
 
    // Не будем отображать сетку пользователю.
    ПечатнаяФорма.ОтображатьСетку = Ложь;
 
    // А также запретим редактирование ячеек отчёта.
    ПечатнаяФорма.ТолькоПросмотр = Истина;
 
    // Зафиксируем верхние 4 строки таблицы, чтобы
    // пользователю было удобно прокручивать
    // вниз печатную форму.
    ПечатнаяФорма.ФиксацияСверху = 4;
    ПечатнаяФорма.ФиксацияСлева = 0;    
 
КонецПроцедуры
 
/// Как изменить табличный документ программно в 1с 8.3, 8.2
 
&НаСервере
Процедура МеняемТабличныйДокументПрограммно(Макет)
 
    ОбластьЯчеек = Макет.Область("Шапка");
    ОбластьЯчеек.ЦветТекста = Новый Цвет(255, 0, 0);
    ОбластьЯчеек.ГраницаСверху =
        Новый Линия(ТипЛинииЯчейкиТабличногоДокумента.БольшойПунктир, 2);
    ОбластьЯчеек.ГраницаСлева =
        Новый Линия(ТипЛинииЯчейкиТабличногоДокумента.БольшойПунктир, 2);
    ОбластьЯчеек.ГраницаСправа =
        Новый Линия(ТипЛинииЯчейкиТабличногоДокумента.БольшойПунктир, 2);
    ОбластьЯчеек.ГраницаСнизу =
        Новый Линия(ТипЛинииЯчейкиТабличногоДокумента.БольшойПунктир, 2);    
    ОбластьЯчеек.Примечание.Текст = "Привет";    
 
    // и т.д. и т.п.
 
КонецПроцедуры
 
/// Как в обработать расшифровку в отчёте в 1с 8.3, 8.2
 
&НаКлиенте
Процедура ПолеСПечатнойФормойОбработкаРасшифровки(Элемент, Расшифровка, СтандартнаяОбработка)
 
    // Дополнительная обработка расшифровки возможна только
    // для табличного документа, который выведен на форму.
 
    // Это событие мы прописали для элемента формы, который связан
    // с реквизитом, имеющим тип "ТабличныйДокумент".
 
    Сообщить("Обработка расшифровки");
    Сообщить(Элемент.ТекущаяОбласть.Имя);
    Сообщить(Расшифровка);
 
    // Мы не хотим, чтобы открывалось значение расшифровки,
    // которое мы программно прописали в печатной форме.
    // Остановим дальнейшую обработку расшифровки.
    СтандартнаяОбработка = Ложь;
 
КонецПроцедуры
 
/// Как вывести табличный документ на форму в 1с 8.3, 8.2
 
&НаКлиенте
Процедура ВыводимТабличныйДокументНаФорму(Команда)
 
    // Предварительно создаём на форме реквизит с именем
    // "ПолеСПечатнойФормой" и типом ТабличныйДокумент,
    // а затем перетаскиваем его в элементы формы.
 
    ВыводимТабличныйДокументНаФормуНаСервере();
 
КонецПроцедуры
 
&НаСервере
Процедура ВыводимТабличныйДокументНаФормуНаСервере()
 
    // Формируем табличный документ.
    ПечатнаяФорма = СформироватьПечатнуюФормуИзТабличногоДокумента();
 
    // Выводим его в соотв. реквизит формы.
    ПолеСПечатнойФормой.Очистить();    
    ПолеСПечатнойФормой.Вывести(ПечатнаяФорма);
    // После этого он автоматически отобразится
    // в поле формы, с которым он связан.
 
КонецПроцедуры
 
/// Как использовать табличный документ для ввода данных в 1с 8.3, 8.2
 
&НаКлиенте
Процедура НастраиваемТаблицуДляВводаДанных(Команда)
 
    // В начале выводим в поле формы табличный документ
    // из макета с именем "ТабличныйМакетДляВвода"
 
    НастраиваемТаблицуДляВводаДанныхНаСервере();
 
    // После этого пользователь должен ввести значение,
    // а мы его получим в коде ниже.
 
КонецПроцедуры
 
&НаСервере
Процедура НастраиваемТаблицуДляВводаДанныхНаСервере()
 
    ПолеСПечатнойФормой.Очистить();
    Макет = Обработки.ОбработкаДляИспытаний.ПолучитьМакет("ТабличныйМакетДляВвода");
    Форма = Макет.ПолучитьОбласть("ФормаВвода");    
    ПолеСПечатнойФормой.Вывести(Форма);
 
КонецПроцедуры
 
&НаКлиенте
Процедура УзнатьКакойЖеТоварВыбралПользователь(Команда)
 
    // Имя ячейки ввода мы задали в макете.
    ПолеВвода = ПолеСПечатнойФормой.Область("ПолеТовар");    
 
    Если ПолеВвода.Значение.Пустая() Тогда
        Сообщить("Укажите товар в табличной форме ввода!");
    Иначе
        Сообщить("Вы выбрали " + ПолеВвода.Значение);
    КонецЕсли;
 
КонецПроцедуры
 
/// Скачать и выполнить эти примеры на компьютере

&НаКлиенте
Процедура СозданиеПечатнойФормыИзТабличногоДокумента(Команда)ФормаПечати = СозданиеПечатнойФормыИзТабличногоДокументаНаСервере();НастройкаКолонтитуловПечатнойФормы(ФормаПечати);
    НастройкаПараметровПечатиТабличногоДокумента(ФормаПечати);ФормаПечати.Показать(«Отчет по долгам»);// Сохранение «Отчета по долгам»
    ФормаПечати.Записать(«D:StoragedataОтчетПоДолгам.xls», ТипФайлаТабличногоДокумента.XLS);// Печать «Отчета по долгам» сразу на принтер
    ФормаПечати.Напечатать(РежимИспользованияДиалогаПечати.НеИспользовать);

КонецПроцедуры

&НаСервере
Функция СозданиеПечатнойФормыИзТабличногоДокументаНаСервере()Макет = ЭтотОбъект.ПолучитьМакет(«Макет_Табл»);// Изменение табличного макета после его создания.
    ПрограммноеИзменениеТабличногоДокумента(Макет);ФормаПечати = Новый ТабличныйДокумент;// Получение области и макета по имени
    Шапка = Макет.ПолучитьОбласть(«Шапка»);
     // Заполнение параметров
    Шапка.Параметры.Дата = ТекущаяДата();
    Шапка.Параметры.Номер = 2020;
     // Вывод шапки в документ
    ФормаПечати.Вывести(Шапка);// Заголовок табличной части.
    ЗаголовокТ = Макет.ПолучитьОбласть(«ТЧ_Заголовок»);
    ФормаПечати.Вывести(ЗаголовокТ);ТЧ_Строка = Макет.ПолучитьОбласть(«ТЧ_Строка»);
    SSDIntelOptaneDC = Справочники.Номенклатура.НайтиПоНаименованию(«SSD Intel Optane DC P4800X 1.5TB»);// Группировка строк таблицы в сворачивающийся блок
    ФормаПечати.НачатьГруппуСтрок(«Номенклатура», Истина);

    Для

Х = 1 По 100 Цикл
        ТЧ_Строка.Параметры.Номенклатура = SSDIntelOptaneDC;
        ТЧ_Строка.Параметры.Количество = Х;// Параметр расшифровки «РасшифровкаНоменклатуры» — для открытия формы номенклатуры из макета по клику
        ТЧ_Строка.Параметры.РасшифровкаНоменклатуры = SSDIntelOptaneDC;
        ФормаПечати.Вывести(ТЧ_Строка);
    КонецЦикла;// Конец группировки
    ФормаПечати.ЗакончитьГруппуСтрок();

    Возврат

ФормаПечати;

КонецФункции

&НаСервере
Процедура ПрограммноеИзменениеТабличногоДокумента(Макет)ОбластьШапки = Макет.Область(«Шапка»);
    ОбластьШапки.ЦветТекста = Новый Цвет(0, 255, 0);
    ОбластьШапки.ГраницаСверху = Новый Линия(ТипЛинииЯчейкиТабличногоДокумента.РедкийПунктир, 1);
    ОбластьШапки.ГраницаСлева = Новый Линия(ТипЛинииЯчейкиТабличногоДокумента.РедкийПунктир, 1);
    ОбластьШапки.ГраницаСправа = Новый Линия(ТипЛинииЯчейкиТабличногоДокумента.РедкийПунктир, 1);
    ОбластьШапки.ГраницаСнизу = Новый Линия(ТипЛинииЯчейкиТабличногоДокумента.РедкийПунктир, 1);
    ОбластьШапки.Примечание.Текст = «Тут текст примечания…»;

КонецПроцедуры

&НаКлиенте
Процедура НастройкаПараметровПечатиТабличногоДокумента(ФормаПечати)// Поля страницы
    ФормаПечати.ПолеСлева = 20;
    ФормаПечати.ПолеСверху = 5;
    ФормаПечати.ПолеСправа = 5;
    ФормаПечати.ПолеСнизу = 5;ФормаПечати.АвтоМасштаб = Истина; // Установка авто-масштаба: «по ширине страницы»
    ФормаПечати.МасштабПечати = 85; // ИЛИ Установка определенного масштаба 85%

    // Ориентация: Портрет или альбом (ландшафт)

ФормаПечати.ОриентацияСтраницы = ОриентацияСтраницы.Портрет;// Двусторонняя печать = Да
    ФормаПечати.ДвусторонняяПечать = ТипДвустороннейПечати.Да;// Количество страниц на листе: 0 — автоматическое определение
    ФормаПечати.ЭкземпляровНаСтранице = 1;// Количество одинаковых копий
    ФормаПечати.КоличествоЭкземпляров = 1;// При печати несколько экземпляров, желательно установить «Истина»
    ФормаПечати.РазборПоКопиям = Истина;// Отключение отображения сетки в пользовательском режиме
    ФормаПечати.ОтображатьСетку = Ложь;// Запрет редактирования ячеек отчёта
    ФормаПечати.ТолькоПросмотр = Истина;// Фиксация двух верхних строк таблицы и одной строи слева для отображения заглавной информации при прокручивании
    ФормаПечати.ФиксацияСверху = 2;
    ФормаПечати.ФиксацияСлева = 1;

КонецПроцедуры

&НаКлиенте
Процедура НастройкаКолонтитуловПечатнойФормы(ФормаПечати)ФормаПечати.ВерхнийКолонтитул.Выводить = Истина;
    ФормаПечати.ВерхнийКолонтитул.НачальнаяСтраница = 1;
    ФормаПечати.ВерхнийКолонтитул.ТекстСлева = «Отчет по реализации и полученной прибыли»;
    ФормаПечати.ВерхнийКолонтитул.ВертикальноеПоложение = ВертикальноеПоложение.Центр;ФормаПечати.НижнийКолонтитул.Выводить = Истина;
    ФормаПечати.НижнийКолонтитул.ТекстВЦентре = «[&Дата][&Время]»;
    ФормаПечати.НижнийКолонтитул.ТекстВЦентре = «[&НомерСтраницы] из [&СтраницВсего]»;

КонецПроцедуры

&НаКлиенте
Процедура ОбработкаРасшифровкиОтчета(Элемент, Расшифровка, СтандартнаяОбработка)// Возможна только для табличного документа, который выведен на форму
    // Необходимо прописать для элемента формы, который связан с «ТабличныйДокумент»
    Сообщить(Расшифровка);
    Сообщить(Элемент.ТекущаяОбласть.Имя);
    СтандартнаяОбработка = Ложь;

КонецПроцедуры

&НаКлиенте
Процедура ВыводТабличногоДокументаНаФорму(Команда)ВыводТабличногоДокументаНаФормуНаСервере();
    // На форме нужно создать реквизит с именем «ПолеВвода», тип «ТабличныйДокумент»
    // и перенести на элементы формы.КонецПроцедуры&НаСервере
Процедура ВыводТабличногоДокументаНаФормуНаСервере()// Формирование табличного документа
    ФормаПечати = СозданиеПечатнойФормыИзТабличногоДокументаНаСервере();// Вывод табличного документа в нужный реквизит формы
    ПолеВвода.Очистить();
    ПолеВвода.Вывести(ФормаПечати); // Произойдет авто.отображение в поле формы (с которым связан)КонецПроцедуры

&НаКлиенте
Процедура НастройкаТабличногоДокументаДляВводаДанных(Команда)// Вывод из макета с именем «Макет_Табл_Ввод» в поле формы ТабличногоДокумента
    НастройкаТабличногоДокументаДляВводаДанныхНаСервере();// Получение значения после его ввода пользователем
    // см.Процедуру: ПолучениеЗначенияПослеЕгоВводаПользователемНаКлиентеКонецПроцедуры&НаСервере
Процедура НастройкаТабличногоДокументаДляВводаДанныхНаСервере()ПолеВвода.Очистить();
    Макет = Обработки.ОбработкаДляИспытаний.ПолучитьМакет(«Макет_Табл_Ввод»);
    Форма = Макет.ПолучитьОбласть(«ФормаДляВвода»);
    ПолеВвода.Вывести(Форма);

КонецПроцедуры

&НаКлиенте
Процедура ПолучениеЗначенияПослеЕгоВводаПользователемНаКлиенте(Команда)// Имя ячейки для ввода задано в макете
    ПолеОбластьВвода = ПолеВвода.Область(«ПолеТовар»);

    Если

ПолеОбластьВвода.Значение.Пустая() Тогда
        Сообщить(«В табличной форме ввода не указана номенклатура!»);
    Иначе
        Сообщить(«Выбрана номенклатура: » + ПолеОбластьВвода.Значение);
    КонецЕсли;

КонецПроцедуры

День добрый.

При создании внешнего отчета возник вопрос о выводе результата на форму.

На форме есть реквизит ТабДок типа Табличный документ.

Я его передаю как параметр  в функцию выполняемую на Сервере и заполняю данными.

Если в конце функции возвращаю ТабДок тогда могу вывести в отдельном окне — а нужно вывести на форме.

Пытался использовать ЗначениеВДанныеФормы(ТабДок,Объект.ТабДок); 

Типы совпадают — Табличный документ, но выскакивает ошибка несоответствие параметра №1 

Подскажите где я ошибаюсь — и вообще Табличный документ можно преобразовывать в реквизит?

Используйте ЗначениеВРеквизитФормы() и уберите ТабДок из объекта, не место ему там.

Убрать ТабДок из объекта — значит убрать реквизит?
И не могу нигде найти как мне правильно вывести ТабличныйДокумент созданный программно на форму.
В отдельном окне получается а на форму не очень…
Помогите разобраться пожалуйста…
Листинг примерно такой
& На Сервере \кусок
        ТаблДок = Новый ТабличныйДокумент;
   ТаблДок.Очистить();
   Макет = РеквизитФормыВЗначение(«Объект»).ПолучитьМакет(«Макет»);
   Шп = Макет.ПолучитьОбласть(«Шапка»);
   Шп.параметры.ДатаОтчета = Формат(ДатаОтчета,»ДЛФ=DD»);
   ТаблДок.Вывести(Шп);
   Заг = Макет.ПолучитьОбласть(«Заголовок|Начало»);
   Кол =  Макет.ПолучитьОбласть(«Заголовок|Колонка1»);
   СтрокаВыводаНачало = Макет.ПолучитьОбласть(«Строка|Начало»);
   СтрокаВыводаКол =  Макет.ПолучитьОбласть(«Строка|Колонка1»);
   ПТР = Макет.ПолучитьОбласть(«ПустаяСтрока|Начало»);
   ПТРК = Макет.ПолучитьОбласть(«ПустаяСтрока|Колонка1»);
   \выполняю кучу действий и в итоге получаю свой документ

если я делаю Возврат(ТаблДок) — тогда на &Клиенте я могу его вывести — но в отдельном окне,а мне надо на форму

я понимаю что надо использовать ЗначениеВРеквизитФормы() но если пишу
ЗначениеВРеквизитФормы(ТаблДок,ТабДок) получается плохо — несоответствие параметра1
ТаблДок — тип Табличный документ — создаю и заполняю сам
ТабДок — тип табличный документ — реквизит на форме

вместо ЗначениеВРеквизитФормы(ТаблДок,ТабДок)

нужно писать

ЗначениеВРеквизитФормы(ТаблДок,»ТабДок»)

{Форма.Форма.Форма(374)}: Ошибка при вызове метода контекста (ЗначениеВРеквизитФормы)
   ЗначениеВРеквизитФормы(ТаблДок,»ТабДок»);
по причине:
Недопустимое значение параметра (параметр номер ‘2’)

Час от часу не легче?!

Но вообще то все нужно делать не так.
Ничего конвертировать никуда не нужно. Нужно просто использовать тот объект, который находится на форме. Для примера прикладываю обработку.

Вай, шайтаномо насальнико…

ОГРОМНОЕ СПАСИБО