1с установить тип реквизита табличной части программно

Просматривая Волшебный форум, наткнулся на тему, в которой коллега интересовался возможностью отключения выбора типа в элементе табличной части справочника при программной установке значения в реквизите составного типа. Приведу часть своего кода, всю тему можно посмотреть здесь.

&НаКлиенте
Процедура ДобавитьВалюту(Команда)
    
    ТС = Объект.ТЧ.Добавить();
    ТС.Имя = "Валюта";
    ТС.Значение = ПредопределенноеЗначение("Справочник.Валюты.ПустаяСсылка");
    Элементы.ТЧ.ПодчиненныеЭлементы.ТЧЗначение.ВыбиратьТип = Ложь;
    
КонецПроцедуры
 

После решил добавить решению универсальности и реализовать программное формирование контекстного меню для табличной части справочника с составным реквизитом с заранее неизвестным перечнем типов.

Создаем справочник, имя произвольное. Добавляем табличную часть ТЧ, реквизиты Имя, тип Строка, Значение, тип составной. Для своего примера я установил Строка, Дата, Число, СправочникСсылка. В форме элемента добавляем реквизит ФормаТипы, тип ОписаниеТипов.

Остальное за нас сделает код:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
 
 //формируем массив типов и удаляем тип текущего справочника, 
 //поскольку у нас тип значения включает все справочники
 фТипы = РеквизитФормыВЗначение("Объект").Метаданные().ТабличныеЧасти.ТЧ.Реквизиты.Значение.Тип.Типы();
 фИндекс = фТипы.Найти(ТипЗнч(Объект.Ссылка));
 фТипы.Удалить(фИндекс);
 //помещаем новое описание типов в реквизит формы
 ФормаТипы = Новый ОписаниеТипов(фТипы);
 //формируем группу контекстного меню
 фГруппа = Элементы.Добавить("ГруппаДополнительно", Тип("ГруппаФормы"), Элементы.ТЧКонтекстноеМеню);
 фГруппа.Заголовок = "Добавить...";
 мТипы = ФормаТипы.Типы();
 Для сч = 0 По мТипы.ВГраница() Цикл
  
  //создаем команды формы, имена формируются с учетом индекса текущего типа в массиве типов
  //потом по этому индексу в имени будем определять необходимый тип данных
  ИндексКоманды = Формат(сч, "ЧН=0; ЧГ=0");
  фКоманда = Команды.Добавить("КомандаДобавитьТипСтроки_" + ИндексКоманды);
  фКоманда.Действие = "ДобавитьЭлементТипа";
  кЭлемент = Элементы.Добавить("ДобавитьТипСтроки_" + ИндексКоманды, Тип("КнопкаФормы"), фГруппа);
  кЭлемент.Заголовок = Строка(мТипы[сч]);
  кЭлемент.Вид = ВидКнопкиФормы.КнопкаКоманднойПанели;
  кЭлемент.ИмяКоманды = фКоманда.Имя;
  
 КонецЦикла;
 
КонецПроцедуры                                     

&НаКлиенте
Процедура ДобавитьЭлементТипа(Команда)

 //определяем индекс для массива типов
 ИндексТипа = Число(СтрЗаменить(Команда.Имя, "КомандаДобавитьТипСтроки_", ""));
 сТип = ФормаТипы.Типы()[ИндексТипа];
 ТС = Объект.ТЧ.Добавить();
 ТС.Имя = Строка(сТип);
 мТипы = Новый Массив;
 мТипы.Добавить(сТип);
 //формируем новое описание типов и приводим к пустому значению этого типа
 ТипТС = Новый ОписаниеТипов(мТипы);
 ТС.Значение = ТипТС.ПривестиЗначение();
 Элементы.ТЧЗначение.ВыбиратьТип = Ложь;
 
КонецПроцедуры


&НаКлиенте
Процедура ТЧПередНачаломДобавления(Элемент, Отказ, Копирование, Родитель, Группа)

 //при добавлении через стандартную команду формы будем выбирать тип
 Элементы.ТЧЗначение.ВыбиратьТип = Истина;
 
КонецПроцедуры
 

Теперь запускаем конфигурацию и добавляем элемент нашего справочника. При использовании стандартной команды формы Добавить перед выбором значения мы будем выбирать его тип. При добавлении через программно сформированные пункты контекстного меню значение будет приводиться к необходимому типу.

1с УПП, обычные формы.

В табличной части есть колонка у которой составной тип данных.

По условию мне нужно программно установить определенный тип, чтобы пользователь при некоторых условиях не выбирал тип, а сразу открывался нужный справочник для выбора элемента.

Делаю так:

Массив = Новый Массив();

Массив.Добавить(Тип(«СправочникСсылка.ОсновныеСредства»));

ОписаниеТипа = Новый ОписаниеТипов(Массив);

ЭлементыФормы.СписокОС.Колонки.ОсновноеСредство.ЭлементУправления.ОграничениеТипа = ОписаниеТипа;

//До этого момента все работает.

Но при выборе в ячейке все равно запрашивает тип, хотя и выбрать можно только один указанный мною.

Пробовал:

ЭлементыФормы.СписокОС.Колонки.ОсновноеСредство.ЭлементУправления.ВыбиратьТип=Ложь

Это не катит, поскольку тогда вообще ничего не происходит при выборе в ячейке.

Если написать:

ЭлементыФормы.СписокОС.Колонки.ОсновноеСредство=ОписаниеТипа.ПривестиЗначение(ЭлементыФормы.СписокОС.Колонки.ОсновноеСредство);

Тоже ничего не происходит. Как я понимаю я привожу значение элементу формы, а мне нужно привести значение именно колонке таблицы значений. Не пойму, как это сделать.

1С 8.x : Как изменить, присвоить, указать Тип Значения Ячейки табличной части?

 //Создадим строки с разним типом значения

НовСтрока = ТабЧасть.Добавить();

НовСтрока.РеквизитПроизвольный = 12345;

НовСтрока = ТабЧасть.Добавить();

НовСтрока.РеквизитПроизвольный = "Это строка";

НовСтрока = ТабЧасть.Добавить();

НовСтрока.РеквизитПроизвольный = ТекущаяДата();

НовСтрока = ТабЧасть.Добавить();

НовСтрока.РеквизитПроизвольный = Истина;


// измененим тип значения в ячейке ТЧ

// Найдем Строку и заменим на Дату

НайденСтрока = ТабЧасть.Найти("Это строка", "РеквизитПроизвольный"); 

НайденСтрока.РеквизитПроизвольный = ТекущаяДата();

// Найдем Число и заменим на Пустую ссылку справочника Номенклатуры (полученную с Вида судконто)

Счет = ПланыСчетов.Хозрасчетный.ТоварыНаСкладе;

НайденСтрока = ТабЧасть.Найти(12345, "РеквизитПроизвольный");

// Получим первое субконто Номенклатура

Субконото1 = Счет.ВидыСубконто[1]; 

// Присвоим тип значения

НайденСтрока.РеквизитПроизвольный = Субконото1.ВидСубконто.ТипЗначения.ПривестиЗначение();   

Установка типа значения для поля табличной части

Автор Tasselhof, 25 мар 2019, 15:54

0 Пользователей и 1 гость просматривают эту тему.

Задача.
Например, есть табличная часть с двумя колонками «ВидПоступленияДС» и «Аналитика». Поле «Аналитика» может содержать значения составного типа. Необходимо, в зависимости от введенного значения в поле «ВидПоступленияДС», установить нужный тип для поля «Аналитика».
Решение.
В событии «ПриИзменении» поля ввода «ВидПоступленияДС» пропишем следующий код:

&НаКлиенте
Процедура ОсновнаяВидПоступленияДСПриИзменении(Элемент)
    ТекСтрока = Элементы.Основная.ТекущиеДанные;
    Если ТекСтрока.ВидПоступленияДС = ПредопределенноеЗначение("Перечисление.ВидыПоступленияДС.ОплатаОтКлиента") Тогда
        ОписаниеТипов = Новый ОписаниеТипов("СправочникСсылка.Контрагенты");
    ИначеЕсли ТекСтрока.ВидПоступленияДС = ПредопределенноеЗначение("Перечисление.ВидыПоступленияДС.ПрочиеПоступленияДС") Тогда
        ОписаниеТипов = Новый ОписаниеТипов("СправочникСсылка.СтатьиПриходаДС");
    Иначе
        ТекСтрока.Аналитика = Неопределено;
        Возврат;
    КонецЕсли;
    ТекСтрока.Аналитика = ОписаниеТипов.ПривестиЗначение(ТекСтрока.Аналитика);
КонецПроцедуры