1с проверка заполнения реквизита объекта программно

Механизм проверки заполнения позволяет автоматически проверить, заполнены ли указанные реквизиты объекта. Для этого нужно воспользоваться свойством ПроверкаЗаполнения, которое есть у реквизитов объектов конфигурации.

Если установить это свойство в значение «Выдавать ошибку», поле Поставщик в форме будет помечено как обязательное для заполнения. А при записи накладной платформа будет контролировать заполненность этого реквизита. Если реквизит окажется не заполнен, платформа выдаст автоматическое сообщение и запись накладной будет отменена.

Разработчик может повлиять на стандартную проверку заполнения, выполняемую платформой. Для этого у него есть два события:

• Одно событие — ОбработкаПроверкиЗаполненияНаСервере — можно обработать в модуле формы.
• Другое событие — ОбработкаПроверкиЗаполнения — можно обработать в модуле прикладного объекта.

У формы, как правило, есть основной реквизит (редактируемый объект) и могут быть реквизиты, не относящиеся к редактируемому объекту, а являющиеся лишь частью формы:

Поэтому серверное событие формы ОбработкаПроверкиЗаполненияНаСервере предназначено для проверки заполнения тех реквизитов формы, которые не относятся к редактируемому объекту. Это данные только формы, у формы могут быть свои причины и алгоритмы для проверки этих данных.

Напротив, событие объекта ОбработкаПроверкиЗаполнения предназначено для для того, чтобы проверить реквизиты основного реквизита формы.

Обработчики обеих событий имеют параметр ПроверяемыеРеквизиты, в который платформа передает массив имен тех реквизитов, которые подлежат проверке. Если после выхода из обработчика в этом массиве все еще останутся какие-то имена реквизитов — платформа выполнит автоматическую проверку оставшися реквизитов.

Поэтому существует несколько сценариев того, как разработчик может встроить свой алгоритм в механизм проверки заполнения:

• самостоятельно проверить заполненность всех реквизитов и очистить массив ПроверяемыеРеквизиты, чтобы платформа не выполняла их проверку
• проверить часть реквизитов самостоятельно, удалить их из массива ПроверяемыеРеквизиты, а оставшиеся оставить на проверку платформе
• добавить в массив ПроверяемыеРеквизиты какие-то реквизиты, чтобы платформа проверила и их тоже
• вообще отказаться от проверки заполненности реквизитов, очистив массив

Все эти сценарии реализуются довольно просто. Например, чтобы самостоятельно проверить заполненность реквизитов, можно выполнить следующий код:

Если Поставщик = Справочники.Поставщики.ПустаяСсылка() Тогда
    Сообщение = Новый СообщениеПользователю();
    Сообщение.Текст = "Необходимо заполнить поставщика!";
    Сообщение.Поле  = "Поставщик";
    Сообщение.УстановитьДанные(ЭтотОбъект);
    Сообщение.Сообщить();
    Отказ = Истина;
КонецЕсли;

// Проверка остальных реквизитов
// ..........

// Очистить массив проверяемых реквизитов, чтобы платформа
// не выполняла их автоматическую проверку
ПроверяемыеРеквизиты.Очистить(); 

Чтобы проверить лишь часть реквизитов, можно выполнить такой код:

Если Поставщик = Справочники.Поставщики.ПустаяСсылка() Тогда
    Сообщение = Новый СообщениеПользователю();
    Сообщение.Текст = "Необходимо заполнить поставщика!";
    Сообщение.Поле  = "Поставщик";
    Сообщение.УстановитьДанные(ЭтотОбъект);
    Сообщение.Сообщить();
    Отказ = Истина;
    // Удалить поставщика из массива проверяемых реквизитов
    ИндексПоляПоставщик = ПроверяемыеРеквизиты.Найти("Поставщик");
    Если ИндексПоляПоставщик <> Неопределено Тогда
        ПроверяемыеРеквизиты.Удалить(ИндексПоляПоставщик);
    КонецЕсли;
КонецЕсли;

Добавить в массив проверяемых реквизитов еще один реквизит можно следующим образом:

ПроверяемыеРеквизиты.Добавить("Комментарий");

А очистить массив проверяемых реквизитов, чтобы ничего не проверять ни самому, ни платформе, можно так:

ПроверяемыеРеквизиты.Очистить();

Вторым параметром в обработчиках этих событий является параметр Отказ. Если ему присвоить значение Истина, то после выхода из обработчика дальнейшая запись объекта будет отменена. Таким образом этот параметр нужно устанавливать в значение Истина тогда, когда ваш алгоритм приходит к выводу, что реквизит не заполнен. В этом случае запись объекта выполнена не будет.

Справка

ОбработкаПроверкиЗаполненияНаСервере(Отказ, ПроверяемыеРеквизиты)

УправляемаяФорма.ОбработкаПроверкиЗаполненияНаСервере(Отказ, ПроверяемыеРеквизиты)

• Отказ. Тип: Булево. Признак отказа от записи. Если в теле процедуры-обработчика установить данному параметру значение Истина, то запись выполнена не будет. Значение по умолчанию Ложь.
• ПроверяемыеРеквизиты. Тип: Массив. Массив путей к реквизитам, для которых будет выполнена проверка заполнения. Массив может быть модифицирован удалением или добавлением путей к необходимым реквизитам.

Вызывается расширением формы при необходимости проверки заполнения реквизитов при записи в форме, а также при выполнении метода ПроверитьЗаполнение(). Для вызова проверки заполнения системой необходимо, чтобы у формы (с которой происходит работа) было установлено свойство ПроверятьЗаполнениеАвтоматически. В этом случае вначале будет вызван данный обработчик, а затем обработчик ОбработкаПроверкиЗаполнения() модуля объекта.

Позволяет разработчику самостоятельно реализовать проверку заполнения в обработчике события. При этом в обработчике можно полностью отказаться от системной обработки (очистив список проверяемых реквизитов), отказаться от проверки системой части реквизитов (выполнив проверку отдельных реквизитов особенным образом и исключив эти реквизиты из списка), а также добавить для проверки другие реквизиты, проверка которых не была указана.

Для формы документа, если при конфигурировании для документа свойство Проведение установлено в Разрешить, событие вызывается только при проведении. Если документ не проводится (свойство Проведение установлено в Запретить), то вызывается при записи.

ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)

ДокументОбъект.ИмяДокумента.ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)

• Отказ. Тип: Булево. Если в теле процедуры-обработчика установить данному параметру значение Истина, то будет выполнен отказ от продолжения работы после выполнения проверки заполнения. Значение по умолчанию Ложь.
• ПроверяемыеРеквизиты. Тип: Массив. Массив путей к реквизитам, для которых будет выполнена проверка заполнения. Массив может быть модифицирован удалением или добавлением путей к необходимым реквизитам.

Вызывается расширением формы при необходимости проверки заполнения реквизитов при записи или при проведении документа в форме, а также при выполнении метода ПроверитьЗаполнение(). Если для документа при конфигурировании свойство Проведение установлено в Разрешить, то вызывается только при проведении. Если документ не проводится (установлено Запретить), то вызывается при записи.

Позволяет разработчику конфигурации самостоятельно реализовать проверку заполнения в обработчике события. При этом в обработчике можно полностью отказаться от системной обработки (очистив список проверяемых реквизитов), отказаться от проверки системой части реквизитов (выполнив проверку отдельных реквизитов особенным образом и исключив эти реквизиты из списка), а также добавить для проверки другие реквизиты, проверка которых не была указана.

Процедура ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)

    // Проверим заполненность реквизита «Покупатель»
    Покупатель = ПроверяемыеРеквизиты.Найти("Покупатель");

    Если Не ЗначениеЗаполнено(Покупатель) Тогда
        
        // Если он не заполнен, сообщим об этом пользователю
        Сообщение = Новый СообщениеПользователю();
        Сообщение.Текст = "Не указан Покупатель, на которого выписывается товарная накладная!";
        Сообщение.Поле = "Покупатель";
        Сообщение.УстановитьДанные(ЭтотОбъект);
        Сообщение.Сообщить();
            
        // Сообщим платформе, что мы сами обработали проверку заполнения реквизита «Покупатель»
        ПроверяемыеРеквизиты.Удалить(Покупатель);

        // Так как информация не консистентна, то продолжать работу дальше смысла нет
        Отказ = Истина;
            
    КонецЕсли;

    // Сообщим платформе, что мы сами обрабатываем проверку реквизита товар в табличной части «Товары»
    ПроверяемыеРеквизиты.Удалить(ПроверяемыеРеквизиты.Найти("Товары.Товар"));

    // Обходим строки и проверяем заполнение реквизита
    Для Индекс = 0 По Товары.Количество()-1 Цикл
        СтрокаТовар = Товары.Получить(Индекс);
        Если Не ЗначениеЗаполнено(СтрокаТовар.Товар) Тогда
            Сообщение = Новый СообщениеПользователю();
            Сообщение.Текст = "В строке " + Индекс + " не заполнено значение товара";
            Сообщение.Поле = "Товары[" + Индекс + "].Товар";
            Сообщение.УстановитьДанные(ЭтотОбъект);
            Сообщение.Сообщить();
            Отказ = Истина;
        КонецЕсли;
    КонецЦикла;
    
КонецПроцедуры

Поиск:
1С:Предприятие • Обработка проверки заполнения • Проверяемые реквизиты • Реквизит • Управляемая форма

Как вызвать стандартную проверку заполнения реквизитов?

Код 1C v 8.2 УП

 ПроверитьЗаполнение()    

Возвращаемое значение:

Тип: Булево. Истина — ошибок не обнаружено, Ложь — в противном случае.

Описание:

Проверяет заполнение реквизитов. Для реквизитов, у которых свойство «Проверка заполнения» установлено в значение «Показывать ошибку» и реквизит не заполнен, будет сформировано сообщение об ошибке.

Доступность:

Тонкий клиент, веб-клиент, сервер, толстый клиент.

Код 1C v 8.2 УП

 &НаКлиенте

Процедура СформироватьБезСКД(Команда)

        // Проверим заполнение обязательных реквизитов

	Если Не ПроверитьЗаполнение() Тогда  	

		Возврат;                         	

	КонецЕсли;     	

	СформироватьСервер();		

КонецПроцедуры   

Обработчик проверки заполнения

У прикладных объектов на платформе 1С Предприятие 8.2 появился новый обработчик события ОбработкаПроверкиЗаполнения, где теперь рекомендуется делать все проверки на заполненность реквизитов объекта. Рассмотрим работу с этим обработчиком. Обработчик должен быть расположен в модуле объекта (для констант в модуле менеджера значений) и имеет следующий синтаксис:

Код 1C v 8.2 УП

 Процедура ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты) 

КонецПроцедуры   

Здесь параметр Отказ (тип Булево) отвечает за возможность дальнейшей работы программы после проверки заполнения, а в параметре ПроверяемыеРеквизиты(тип Массив) содержатся реквизиты объекта, которые система будет проверять на заполненность. Напомним, что в версии 1С Предприятие 8.2 появилось возможность на уровне свойств реквизитов объекта устанавливать свойство Проверка заполнения. Так вот в массив ПроверяемыеРеквизиты по умолчанию система помещает реквизиты с установленным свойством «Выдавать ошибку». Однако разработчик может сам некоторые реквизиты добавить в массив или удалить из него в зависимости от каких-либо условий:

Код 1C v 8.2 УП

 Процедура ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)


  Клиент = ПроверяемыеРеквизиты.Найти("Контрагент");



  


                       
  





  Если Клиент<>Неопределено тогда


   ПроверяемыеРеквизиты.Удалить(Клиент);


  конецесли;


  ПроверяемыеРеквизиты.Добавить("Склад");


КонецПроцедуры    

Как видно из примера в качестве элементов массива выступают строковые наименование реквизитов, как они заданы в конфигураторе. Для того чтобы полностью отказаться от системной проверки, необходимо очистить массив. При этом разработчик может проводить проверку реквизитов по произвольным алгоритмам, система же проверяет только на заполненность/незаполненность:
Процедура ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)

Код 1C v 8.2 УП

 ПроверяемыеРеквизиты.Очистить();


Если Контрагент.ПометкаУдаления Тогда


  Отказ = Истина;


  Сообщение = Новый СообщениеПользователю;



  


                       
  





  Сообщение.Текст = "Нельзя указывать контрагента, помеченного на удаление!";


  Сообщение.Поле = "Контрагент";


  Сообщение.УстановитьДанные(ЭтотОбъект);


  Сообщение.Сообщить();



КонецЕсли; 


КонецПроцедур   

Далее рассмотрим, когда вызывается данный обработчик. Это зависит от типа объекта и его свойств. Так для, например, для справочника обработчик вызывается перед записью объекта; для документа: если разрешено проведение — при проведении, иначе при записи; для обработки : при вызове стандартных команд «OK», Да». Подробно это описано во встроенной справке. Но также есть возможность вызвать данный обработчик в произвольный момент, используя метод объекта ПроверитьЗаполнение(). Например, определить команду Проверить в форме документа:

Код 1C v 8.2 УП

 &НаКлиенте


Процедура Проверить(Команда)


  ПроверитьНаСервере();



  


                       
  





КонецПроцедуры



&НаСервере


Процедура ПроверитьНаСервере()


  Документ = РеквизитФормыВЗначение("Объект");


  Документ.ПроверитьЗаполнение(); 


КонецПроцедуры   

Автор: Борис Захаров

Код 1C v 8.х

  //СписокРеквизитов - список значений. Элемент списка значений - имена реквизитов для проверки через запятую. 

//Если представление заполнено - считается, что передаются реквизиты табличной части.  Пример:

СписокРеквизитовДляПроверки=Новый СписокЗначений;

СписокРеквизитовДляПроверки.Добавить("Контрагент,МестоХранения,ВидОперации");

СписокРеквизитовДляПроверки.Добавить("Номенклатура,Единица,Цена,Количество","ПолнаяТаблица");

СписокРеквизитовДляПроверки.Добавить("ВидОтклонений,Номенклатура,Единица,Серия,Цена,Количество","ТаблицаОтклонений");

        
Если Не глРеквизитыОбъектаЗаполнены(Источник,СписокРеквизитовДляПроверки) Тогда

     Отказ=Истина;

     Возврат;

КонецЕсли;


Функция глРеквизитыОбъектаЗаполнены(Объект,СписокРеквизитов) Экспорт

    МетаданныеОбъекта=Объект.Метаданные();

    МетаданныеТабличныеЧасти=МетаданныеОбъекта.ТабличныеЧасти;



  


                       
  




    
    РеквизитыЗаполнены=Истина;

    
    СтрокаДляВыполнения="";

    
    Для каждого НаборРеквизитов Из СписокРеквизитов Цикл

        НаименованиеТаблицы=НаборРеквизитов.Представление;

        РеквизитыДляПроверки=СтрЗаменить(НаборРеквизитов.Значение,",",Символы.ПС);

        
        ДлинаСпискаРеквизитов=СтрЧислоСтрок(РеквизитыДляПроверки);

        
        Если НаименованиеТаблицы<>"" Тогда

            МетаданныеТаблица=МетаданныеТабличныеЧасти[НаименованиеТаблицы];

            МетаданныеРевизитыТаблицы=МетаданныеТаблица.Реквизиты;

            
            ТаблицаОбъекта=Объект[НаименованиеТаблицы];

            
            Для СчетчикСтрокРевизитов=1 По ДлинаСпискаРеквизитов Цикл

                ИдентРеквизита=СтрПолучитьСтроку(РеквизитыДляПроверки,СчетчикСтрокРевизитов);

                
                МетаданныеРеквизит=МетаданныеРевизитыТаблицы[ИдентРеквизита];

                ОписаниеТиповРеквизита=МетаданныеРеквизит.Тип;

                ТипыЗначенийРеквизита=ОписаниеТиповРеквизита.Типы();

                
                СтрокаПоиска=ТаблицаОбъекта.Найти(глПолучитьПустоеЗначениеТипа(ТипыЗначенийРеквизита[0]),ИдентРеквизита);

                Если СтрокаПоиска=Неопределено Тогда

                    Продолжить;

                КонецЕсли; 

                
                Возврат глВозвратЛожьССообщением("Не заполнен реквизит """+МетаданныеРеквизит.Синоним+""" Табличная часть строка "+СтрокаПоиска.НомерСтроки);

            КонецЦикла;

        Иначе

            Для СчетчикСтрокРевизитов=1 По ДлинаСпискаРеквизитов Цикл

                ИдентРеквизита=СтрПолучитьСтроку(РеквизитыДляПроверки,СчетчикСтрокРевизитов);



  


                       
  




                
                Если Не ЗначениеЗаполнено(Объект[ИдентРеквизита]) Тогда

                    МетаданныеРевизитыШапки=МетаданныеОбъекта.Реквизиты;

                    Попытка

                        Возврат глВозвратЛожьССообщением("Не заполнен реквизит """+МетаданныеРевизитыШапки[ИдентРеквизита].Синоним+"""");

                    Исключение

                        Возврат глВозвратЛожьССообщением("Не заполнен реквизит """+ИдентРеквизита+"""");

                    КонецПопытки; 

                КонецЕсли;

            КонецЦикла;

        КонецЕсли; 

    КонецЦикла; 

    
    Возврат Истина;

КонецФункции   

Код 1C v 8.х

 // Ярослав Волохов aka YVolohov

// Функция проверяет заполнение шапки или табличной части справочника, документа или плана, бизнес-процесса, задачи

// Параметры:

// пИмяТаблицы (строка) - имя табличной части объекта, если не указано то будет проверятся шапка объекта

// пИменаПолей (массив строк) - имена проверяемых реквизитов объекта

// пВыводитьСообщения - если это свойство установлено в "Истина" то будут выводится сообщения в табло о

//     незаполненных реквизитах таблицы, если не установлено - то не будут

// пСсылка (ссылка) - ссылка на элемент справочника или плана, документ, по которому будет произведена проверка

// Возвращаемое значение:

// Истина - если все реквизиты найдены и заполнены

// Ложь - если хоть один реквизит не заполнен, табличная часть не найдена

// или хоть один реквизит не найден


Функция ПроверитьЗаполнениеТаблицыОбъекта(пИмяТаблицы = Неопределено,

    пИменаПолей, пВыводитьСообщения = Истина, пСсылка) Экспорт


    МассивСообщений   = Новый Массив;

    ЗначениеВозврата  = Истина;

    МетаданныеОбъекта = пСсылка.Метаданные();


    Если НЕ(пИмяТаблицы = Неопределено) Тогда

        МетаданныеТаблицы = МетаданныеОбъекта.ТабличныеЧасти.Найти(пИмяТаблицы);

    Иначе

        МетаданныеТаблицы = МетаданныеОбъекта;

    КонецЕсли;


    // Проверка существования табличной части

    Если НЕ(МетаданныеТаблицы = Неопределено) Тогда


        МассивМетаданныхРеквизитов  = Новый Массив;

        МетаданныеРеквизитов        = МетаданныеТаблицы.Реквизиты;


        // Проверка существования полей

        Для Каждого ИмяПоля Из пИменаПолей Цикл


            МетаданныеРеквизита = МетаданныеРеквизитов.Найти(ИмяПоля);



  


                       
  





            Если НЕ(МетаданныеРеквизита = Неопределено) Тогда

                МассивМетаданныхРеквизитов.Добавить(МетаданныеРеквизита);

            Иначе


                Если пИмяТаблицы = Неопределено Тогда

                    МассивСообщений.Добавить("Реквизит шапки с именем '" + ИмяПоля + "' не найден !!!");

                Иначе

                    МассивСообщений.Добавить("Реквизит табличной части '" + пИмяТаблицы + "' с именем '" +

                    ИмяПоля + "' не найден !!!");

                КонецЕсли;


                ЗначениеВозврата = Ложь;

            КонецЕсли;


        КонецЦикла;


        // Проверка заполнения полей

        КоличествоСтрокТаблицы = ?(НЕ(пИмяТаблицы = Неопределено), пСсылка[пИмяТаблицы].Количество(), 1);

        КоличествоСтрокТаблицы = ?(МассивМетаданныхРеквизитов.Количество() > 0, КоличествоСтрокТаблицы, 0);


        // Обход строк таблицы

        Для НомерСтрокиТаблицы = 1 По КоличествоСтрокТаблицы Цикл


            СтрокаТаблицы = ?(НЕ(пИмяТаблицы = Неопределено),

            пСсылка[пИмяТаблицы].Получить(НомерСтрокиТаблицы - 1), пСсылка);


            // Обход списка проверяемых реквизитов

            Для Каждого ЭлементМетаданныхРеквизитов Из МассивМетаданныхРеквизитов Цикл


                // Получение значения ячейки и проверка ее заполнения

                ЗначениеЯчейкиТЧ = СтрокаТаблицы[ЭлементМетаданныхРеквизитов.Имя];

                ЯчейкаПустая     = НЕ(ЗначениеЗаполнено(ЗначениеЯчейкиТЧ));


                // Если значение пустое, добавляем сообщение в массив сообщений

                Если ЯчейкаПустая Тогда



  


                       
  





                    Если пИмяТаблицы = Неопределено Тогда

                        МассивСообщений.Добавить("Реквизит шапки с именем '" + ЭлементМетаданныхРеквизитов.Имя + "' не заполнен !!!");

                    Иначе

                        МассивСообщений.Добавить("В строке № " + НомерСтрокиТаблицы + " табличной части '" +

                        пИмяТаблицы + "' не заполнен реквизит с именем '" + ЭлементМетаданныхРеквизитов.Имя + "' !!!");

                    КонецЕсли;


                    ЗначениеВозврата = Ложь;


                КонецЕсли;


            КонецЦикла;


        КонецЦикла;


    Иначе

        МассивСообщений.Добавить("Табличная часть с именем '" + пИмяТаблицы + "' не найдена !!!");

        ЗначениеВозврата = Ложь;

    КонецЕсли;


    // Здесь выводим все сообщения

    Если пВыводитьСообщения Тогда


        Для Каждого ТекстСообщения Из МассивСообщений Цикл

            Сообщить(ТекстСообщения, СтатусСообщения.Важное);

        КонецЦикла;


    КонецЕсли;


    Возврат ЗначениеВозврата;



  


                       
  





КонецФункции   

Встроенные методы проверки заполнения

Во встроенном языке 1С есть функция для автоматической проверки заполнения полей формы. Функция ПроверитьЗаполнение() проверяет заполнение реквизитов у которых свойство «Проверка заполнения» установлено в значение «Показывать ошибку». Если реквизит не заполнен, то выводится сообщение об ошибке.

Свойство «Проверка заполнения» можно установить в двух местах:

1) В свойствах реквизита формы

2) В свойствах реквизита объекта метаданных (справочника, документа и т.д)

Процедура ВыполнитьНажатие()Если НЕ ПроверитьЗаполнение() Тогда
		Возврат;
	КонецЕсли;//...
	//...
	//...

КонецПроцедуры 

Программная проверка заполнения

Встроенный язык программирования обладает всеми необходимыми возможностями для того чтобы написать проверку на заполненность полей формы. В основном, для проверки заполнения используется несколько функций. Для проверки ссылочных значений применяется встроенная функция Пустая(), которая вызывается непосредственно из ссылки. Для проверки строковых значений подходит функция ПустаяСтрока(<Строка>). Есть более универсальный метод ЗначениеЗаполнено(<Значение>), он проверяет заполненность значений любых типов. Информацию о том как работает та или иная функция можно найти в синтакс-помощнике.

Процедура ПроверитьЗаполнение()//Проверка ссылочных знаечний
	Если Номенкалтура.Пустая() Тогда
		Сообщить("Номенлатура пустая ссылка");
	КонецЕсли;//Проверка строковых знаечний
	Если ПустаяСтрока(Артикул) Тогда
		Сообщить("Строка пустая");
	КонецЕсли;//Проверка с помощью функции ЗначениеЗаполнено()
	//Булево значение всегда заполнено
	//Строка не пустая, если в строке есть непробельные символы
	//Массив или коллекция не пустая, если в них есть хотя бы 1 элемент
	//Неопределено и Null это всегда пустые значения
	Если НЕ ЗначениеЗаполнено(Номенкалтура) Тогда
		Сообщить("Номенлатура пустая ссылка");
	КонецЕсли;Если НЕ ЗначениеЗаполнено(Артикул) Тогда
		Сообщить("Строка пустая");
	КонецЕсли;КонецПроцедуры 

Содержание:

1.       Свойство 1С «Проверка заполнения»

2.       Процесс проверки заполнения реквизита

Приветствую, коллеги! В данной статье я расскажу, как проводить программную проверку заполнения реквизита в режиме конфигуратора в 1С. Для начала мы рассмотрим общие понятия, после чего будет показан пример программного кода с комментариями. Также я расскажу, как проводить проверку на заполнение реквизита при помощи специального свойства и в каком случае это работает лучше, чем программная проверка. Всё описанное будет проиллюстрировано на вполне конкретном примере.  

1.    Свойство 1С «Проверка заполнения»

Чтобы проверить заполнение реквизита в 1С используется специальное свойство – Проверка заполнения. Для всех объектов метаданных, которые имеют типы, а также для реквизитов, которые выступают в стандартном формате, и таблиц, которые обязательно должны быть заполнены, для свойства «Проверка заполнения» должно быть определено значение «Выдавать ошибку».

В некоторых случаях проводить документацию, в которой не заполнены значения в реквизитах и таблицах – не является уместным, так как во время учётов документ не будет иметь отображения. Как пример, рассмотрим документ «Заказ клиента», по сути – это запрос клиента для поставки некоторой продукции в некотором количестве. Согласно определению, не сложно понять, что документ, в котором не заполнены обязательные реквизиты «Клиент» и таблица «Товары» не является корректным и в свойстве «Проверка заполнения» нужно выставить «Выдавать ошибку».

Во время установки свойства «Проверка заполнения» обязательно опираться на то, что все возможные ограничения и сверки нужно прописывать в метаданных внутри конфигурации. Так что когда хоть один из возможных вариантов требует заполнения всех реквизитов, свойство «Проверка заполнения» будет установлено в «Выдавать ошибку». В случае отсутствия обязательных к заполнению реквизитов подобные сценарии должны быть прописаны внутри обработчика «ОбработкаПроверкиЗаполнения».

Стоит отметить, что не нужно создавать противоположную схему: когда свойство «Проверка заполнения» установлено в «Не проверять», а в обработчике «ОбработкаПроверкиЗаполнения» дописаны некоторые проверки по заполнению, так как подобный план станет лишь путать логику в работе в режиме конфигурации 1С.  

2.    Процесс проверки заполнения реквизита

Бывают случаи, когда при работе в режиме конфигуратора приходится вручную произвести проверку заполнения реквизитов. Когда реквизит имеет специальное свойство «Проверка значения» и при этом имеет значение «Выдавать ошибку», необходимо удалить данный реквизит в массиве проверяемых реквизитов, после чего нужно сверить заполнение реквизита документа при помощи программы, так как это более точный способ. В случае, если проверки в реквизите по умолчанию не было, то стоит программно добавить заданный реквизит в общий массив тех реквизитов, которые подлежат проверке заполнения реквизита.

Проверка по заполнению реквизитов в 1С происходит в обработчике «ОпработкаПроверкиЗаполнения()». Данный обработчик необходимо разместить внутри модуля соответствующего объекта. Его можно вызвать автоматически, когда проводим документацию или сохраняем форму.

Для проверки необходимо запустить модуль документа «ОказаниеУслуги» и поместить в него следующую процедуру:

Рис. 1 Осуществление проверки заполнения реквизита в 1С

Теперь рассмотрим, что именно происходит в данной процедуре.

В начале нам нужно найти и получить реквизит из части таблицы «НаборСвойств», которая находится в массиве «ПроверяемыеРеквизиты». Данный массив будет передан к самому обработчику – в нём и содержатся те реквизиты, которые подлежат проверке. Для всех реквизитов внутри данного реквизита нужно выставить свойство «Проверка заполнения» для значения «Выдавать ошибку». В случае, если он будет распознан и найден, нужно будет удалить его, ведь проверка заполнения реквизитов будет выполняться полностью вручную.

Далее в цикле нужно будет обойти строки внутри табличной части нужного документа, а также провести формировку сообщения, которое будет выводить ошибку лишь для тех случаев, когда данное наименование номенклатуры – это материал, в котором заполнен столбец по набору свойств.

В параметре «Отказ» нужно выставить значение в виде «Истина». Так как данное значение подтверждает, что конкретный документ не подлежит проведению, в случае, когда будет найден хотя бы один реквизит, который не будет заполненным, определится «НабрСвойств», ведь он является материалом. Если сделать комментарий на параметр, то документ будет проводится, но также будут всплывать сообщения об ошибке.

Также вместо «ПереченьНоменклатуры» и «ВидНоменклатуры» можно использовать запросы.

Специалист компании «Кодерлайн»

Айдар Фархутдинов

рубрики: Платформа 8.3 | Дата: 12 июля, 2018

Одной из стандартных задач при работе с формами различных объектов 1С является проверка реквизитов формы на заполненность.
Рассмотрим несколько способов проверки заполненности реквизитов на форме. Рассматривать будем на примере элемента справочника.

Проверка средствами платформы

Как правило у различных объектов метаданных (справочники, документы и т.д.) часть реквизитов обязательны к заполнению. Это могут быть как стандартные реквизиты, например, для справочника наименование и код, так и реквизиты созданные в процессе конфигурирования. Для таких реквизитов свойство «Проверка заполнения» обычно устанавливается в значение «Выдавать ошибку»

Кроме этого в свойствах самой формы должен быть установлен флаг Проверять Заполнение Автоматически

Это позволяет выполнять проверку средствами платформы в момент записи объекта без написания дополнительного кода. Давайте посмотрим как это работает в режиме предприятия.

При выполнении такой проверки платформа осуществляет вызов предопределенной процедуры ОбработкаПроверкиЗаполненияНаСервере(), расположенной в модуле формы, а затем и вызов процедуры ОбработкаПроверкиЗаполнения(), которая находится уже в модуле объекта, если конечно эти процедуры имеются в наличии. И как мы видим организация такого рода проверки занимает минимальное количество усилий.

Программная проверка реквизитов с флагом «Выдавать ошибку»

Для реквизитов у которых свойство «Проверка заполнения» установлено в значение «Выдавать ошибку» достаточно легко можно организовать программную проверку буквально одной строчкой кода c помощью метода ПроверитьЗаполнение():

&НаСервере
Процедура ПроверитьРеквизитыНаСервере()

	ПроверитьЗаполнение();

КонецПроцедуры

В отличие от предыдущего способа (когда проверка происходит в момент записи), мы можем вызвать данную проверку в любом месте своего кода. И точно также как и в предыдущем случае будут выполнены процедуры ОбработкаПроверкиЗаполненияНаСервере() и ОбработкаПроверкиЗаполнения()

Программная проверка реквизитов

И конечно же мы всегда можем программно проверить заполненность реквизитов вне зависимости от значения свойства «Проверка заполнения». В самом простейшем случае с помощью метода ЗначениеЗаполнено():

Если НЕ ЗначениеЗаполнено(Поставщик) Тогда

	Сообщение = Новый СообщениеПользователю;
	Сообщение.Текст = "Не заполнен поставщик";
	Сообщение.Сообщить();

КонецЕсли;

Давайте теперь попробуем разобраться в каком из предопределенных модулей лучше выполнять проверку, когда речь идет о записи объекта. Если мы обратимся к схеме событий при проведении документа, то увидим, что логично будет выполнить проверку до начала транзакции. То есть это следующие предопределенные процедуры:

• Модуль формы. ПередЗаписью()
• Модуль формы. ОбработкаПроверкиЗаполненияНаСервере()
• Модуль объекта. ОбработкаПроверкиЗаполнения()
• Модуль формы. ПередЗаписьюНаСервере()

Как правило проверка реквизитов выполняется в предопределенной процедуре модуля объекта ОбработкаПроверкиЗаполнения(). По умолчанию она выглядит следующим образом:

Процедура ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)

КонецПроцедуры

Здесь ПроверяемыеРеквизиты — это массив с именами реквизитов, которые подлежат проверке. Тип элементов массива — строка. Естественно, что платформа автоматически добавляет в этот массив имена реквизитов для которых установлено свойство «Выдавать ошибку». Но мы можем программно добавлять или удалять элементы массива и таким образом менять перечень проверяемых реквизитов:

Процедура ОбработкаПроверкиЗаполнения(Отказ, ПроверяемыеРеквизиты)

	ПроверяемыеРеквизиты.Добавить("Поставщик");

КонецПроцедуры

Однако следует учитывать, что процедура ОбработкаПроверкиЗаполнения() не отрабатывает при программной записи объекта. Поэтому если заранее известно, что контроль реквизитов нужно производить как при интерактивной записи так и при программной, контроль заполненности реквизитов следует перенести в другую предопределенную процедуру в модуле объекта. Например ПередЗаписью().

Выводы

Из всего вышесказанного можно сделать вывод, что выбирать способ проверки заполненности реквизитов нужно для каждого случая индивидуально, но по возможности лучше возлагать эту обязанность на саму платформу.