Задача заключается в том, чтобы получить реквизит от ссылочного значения, хранящегося в реквизите формы. Например у документа Накладная есть реквизит ссылочного типа – Поставщик. Необходимо получить ИНН этого поставщика:
Мы находимся в модуле формы на клиенте. В контексте клиента ссылочные типы очень сильно ограничены в своих возможностях. В частности, нельзя получить значение реквизита от ссылки «через точку». Это можно сделать только в контексте сервера.
Поэтому для решения этой задачи в модуле формы создадим серверную внеконтекстную функцию, которую вызовем с клиента и передадим в нее ссылку на поставщика. В теле функции, на сервере, мы получим ИНН поставщика и вернем его на клиента.
Например, локальная команда формы, вызывающая серверную функцию, будет выглядеть следующим образом:
&НаКлиенте Процедура ПолучитьИННПоставщика(Команда)
ИННПоставщика = ПолучитьИНННаСервере(Объект.Поставщик);
КонецПроцедуры
А функцию ПолучитьИНННаСервере() опишем здесь же, в модуле формы:
&НаСервереБезКонтекста Функция ПолучитьИНННаСервере(СсылкаНаПоставщика)
Возврат СсылкаНаПоставщика.ИНН;
КонецФункции
Таким образом на сервере мы сразу же получаем значение реквизита «через точку» от полученной ссылки и возвращаем его на клиента.
Важно заметить, что функция ПолучитьИНННаСервере() не использует контекст формы (директива компиляции &НаСервереБезКонтекста). Потому что все, что нужно передать на сервер, – это только ссылка, и мы передаем ее в параметре функции. Использовать контекстный вызов и передавать на сервер весь контекст формы только ради того, чтобы на сервере взять из него значение одного реквизита формы, — это слишком расточительно.
Получить реквизит элемента справочника по ссылке |
Я |
28.05.14 — 18:09
Тестовая конфигурация с нуля. Справочник «Номенклатура» содержит реквизит Цена (Число 15,2). Есть документ «Ввод остатков». В табличной части все банально, Номенклатура, Цена, Количество, Сумма. Пытаюсь в табличную часть документа подставить цену из реквизита Цена, не могу добраться до нее. В модуле формы документа использую событие ОбработкаВыбора(). Вот код
&НаКлиенте
Процедура ТоварыНоменклатураОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
ТекущиеДанныеТовары = Элементы.Товары.ТекущиеДанные;
ТекущиеДанныеТовары.Цена = ВыбранноеЗначение.Цена;
КонецПроцедуры
ВыбранноеЗначение.Цена = недопустимый реквизит, хотя ВыбранноеЗначение Тип СправочникСсылк.Номенклатура и значение есть в «Вычислить выражение»
1 — 28.05.14 — 18:15
получай цену на сервере
2 — 28.05.14 — 18:21
чтобы получить цену надо слазить в базу, а базы на клиенте нет
3 — 28.05.14 — 18:22
клиент про реквизиты реквизитов не в курсе…
4 — 28.05.14 — 18:23
(2) не дает создать обработчик на сервере (только без контекста)
Сделал так
&НаКлиенте
Процедура ТоварыНоменклатураОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
ТекущиеДанныеТовары = Элементы.Товары.ТекущиеДанные;
ТекущиеДанныеТовары.Цена = ТоварыНоменклатураОбработкаВыбораНаСервере(ВыбранноеЗначение);
КонецПроцедуры
&НаСервереБезКонтекста
Функция ТоварыНоменклатураОбработкаВыбораНаСервере(ВыбранноеЗначение)
Возврат ВыбранноеЗначение.Цена;
КонецФункции
Заработало ))
Спасибо!
5 — 28.05.14 — 18:23
(3),(4) я уловил уже. Спасибо!
6 — 28.05.14 — 18:24
Или есть способ оптимальнеекрасивее? В одну процедуруфункцию?
7 — 28.05.14 — 18:27
>ВыбранноеЗначение.Цена;
весь объект то читать зачем?
8 — 28.05.14 — 18:29
(7) Какой? Цена? Цена это реквизит числовой
9 — 28.05.14 — 18:30
(8) и ради одной цифры ты еретично читаешь весь объект…
10 — 28.05.14 — 18:32
(9) а как мне еще цифру получить как не через ссылку на объект?
11 — 28.05.14 — 18:33
богоподобным запросом
12 — 28.05.14 — 18:33
тфу, богоугодным
13 — 28.05.14 — 18:34
Запрос для того чтобы прочитать одну цифру оптимальнее?! О_о
14 — 28.05.14 — 18:37
(13) Как думаешь, что делает система, когда просишь её получить цену в ВыбранноеЗначение.Цена?
15 — 28.05.14 — 18:38
(12) А вот правда, чем лучше. Запрос (внутри) создастся и так и так, отбор будет одинаковый, на равенство ссылке.
На клиент уйдет все равно только одна цифра. Дельта получается на объем передачи лишних реквизитов между СУБД и сервером. Там должны быть такие копейки, что меньше ошибки измерения.
16 — 28.05.14 — 18:38
(13) В общем случае — да. При обращении через точку идет тот же самый запрос, только на все поля объекта, а не на одно. Зато выполняется кэширование объекта. При повторном обращении через точку к этому же объекту запроса уже не будет.
17 — 28.05.14 — 18:38
(14) наверное не В а ИЗ ВыбранноеЗначение.Цена
Хочешь сказать запрос и делает? Только по всему объекту?
18 — 28.05.14 — 18:39
>Как думаешь, что делает система
она убьет очередного котенка
19 — 28.05.14 — 18:40
(0) Посмотри, как в типовых обрабатывается изменение цены/количества/товара в ТЧ документа. Со всякими кэшированиями, чтобы по каждому чиху в базу не лазить, как в (4).
20 — 28.05.14 — 18:40
(16) ок, я примерно понял
21 — 28.05.14 — 18:40
(15) Далеко не всегда копейки. Объект может быть «тяжелым» — с большими табличными частями и хранилищами значений. А тянуться он будет весь, хотя нужен только один реквизит.
22 — 28.05.14 — 18:41
>При повторном обращении через точку к этому же объекту запроса уже не будет
скуль тоже данные кэшировать умеет
23 — 28.05.14 — 18:42
(19) нету типовой у меня…. Тем более подозреваю там цены вообще по нормальному — регистр сведений
24 — 28.05.14 — 18:43
Попробую переделать на запрос. Спасибо всем за направление вектора моих мыслей в правильную сторону ))
25 — 28.05.14 — 18:43
(16) О, точно. Правильно запросом, потому, что кэширование жрет ресурсов. Главное ведь проверял же недавно. (правда в толстом клиенте, и получение всего объекта. Идет в 5-10 раз быстрее, чем чтение одного поля через точку)
26 — 28.05.14 — 18:46
(25) так получается же кеширование жрет ресурсы а кешируется после Запроса?
27 — 28.05.14 — 18:49
(26) результат запроса в кеш не складывается, просто кладется в память. А получение реквизита ссылки через точку приводит к помещению данных объекта в хитросделанный кеш.
28 — 28.05.14 — 18:51
Ок
29 — 28.05.14 — 18:52
(23) ну.. типовую найти при желании — не проблема, было бы это желание.
А вопрос в подходе. В типовой данные из ТЧ кэшируются в переменную, при изменении, например, количества, кратность упаковки берется не из объекта через точку, а из таблицы кэшированных значений. И только если там нет — лезем на сервер.
Ну а так — дело ваше, конечно..
30 — 28.05.14 — 18:55
Ну, непосредственно по сабжевому моменту (выбор новой номенклатуры из списка), механизм кэширования значений в типовых ничем не поможет. И к этому механизму, если честно, у меня серьезные претензии. Какого хрена весь клиентский кэш постоянно гоняется на сервер??
31 — 28.05.14 — 18:56
По сабжу можно хитрее извратиться, через альтернативную форму выбора. Цену получать еще в динамическом списке формы, и возвращать её в документ при выборе вместе с номенклатурой.
32 — 28.05.14 — 18:59
Переделал
&НаКлиенте
Процедура ТоварыНоменклатураОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
ТекущиеДанныеТовары = Элементы.Товары.ТекущиеДанные;
ТекущиеДанныеТовары.Цена = ТоварыНоменклатураОбработкаВыбораНаСервере(ВыбранноеЗначение);
КонецПроцедуры
&НаСервереБезКонтекста
Функция ТоварыНоменклатураОбработкаВыбораНаСервере(ВыбранноеЗначение)
Запрос = Новый Запрос;
Запрос.Текст =
«ВЫБРАТЬ
| Номенклатура.Цена
|ИЗ
| Справочник.Номенклатура КАК Номенклатура
|ГДЕ
| Номенклатура.Ссылка = &Ссылка»;
Запрос.УстановитьПараметр(«Ссылка», ВыбранноеЗначение);
РезультатЗапроса = Запрос.Выполнить();
ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
ВыборкаДетальныеЗаписи.Следующий();
Возврат ВыборкаДетальныеЗаписи.Цена;
КонецФункции
Так?
33 — 28.05.14 — 18:59
(31) я не очень силен в 8ке. Вот разбираюсь
34 — 28.05.14 — 19:00
(29) понял. Спасибо!
35 — 28.05.14 — 19:04
(29) в типовую я полезу когда буду делать «по правильному» с нормальными ценами (в регистре) и тп. Сейчас простой вопрос, зачем городить огород. Два ответа и все стало понятно.
36 — 28.05.14 — 19:04
Запрос то правильно сделал? (работает, но мало ли)
neetro
37 — 28.05.14 — 19:18
(31) понял идею, интересно.
Как получить реквизит от ссылочного значения на клиенте
На чтение 2 мин Просмотров 6.3к. Опубликовано 20.04.2017
На стороне клиента нельзя обратиться к данным базы, в т.ч. получить реквизит от ссылочного значения. Рассмотрим как все же можно решить эту задачу.
На стороне клиента код вида
Контрагент.ИНН
приведет к ошибке. Такие конструкции возможны только на сервере.
Предположим, что стоит задача при нажатии на кнопку отобразить ИНН контрагента, выбранного на форме. Для решения поставленной задачи необходимо обратиться на сервер для получения требуемой информации(ИНН). Программный код может иметь вид:
&НаКлиенте
Процедура ПолучитьИНН(Команда)
// Вызов серверной внеконтекстной функции
ИННКонтрагента = ПолучитьИНННаСервере(Контрагент);
Сообщить("ИНН контрагента: " + ИННКонтрагента);
КонецПроцедуры
&НаСервереБезКонтекста
Функция ПолучитьИНННаСервере(Контрагент)
Возврат Контрагент.ИНН;
КонецФункции
При нажатии на кнопку ПолучитьИНН вызывается серверная функция ПолучитьИНННаСервере(). В единственном параметре передается контрагент, выбранный интерактивно пользователем. Функция получает ИНН через точку и сразу же возвращает значение обратно на клиент. Результат работы серверной функции помещается в переменную ИННКонтрагента и выводится пользователю с помощью метода Сообщить().
Серверная функция является внеконтекстной (&НаСервереБезКонтекста). Это значит, что данные, содержащиеся в форме, не будут отсылаться на сервер, что уменьшит объем передаваемых данных и скорость возврата результата функции.
Внимание!
При работе с конфигурациями, в которые встроена библиотека стандартных подсистем, вместо получения реквизита через точку рекомендуется использовать функцию ЗначениеРеквизитаОбъекта() из общего модуля ОбщегоНазначения. Таким образом, строку
Возврат Контрагент.ИНН;
можно заменить на:
Возврат ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Контрагент, "ИНН");
В случае, когда значение реквизита нужно только для визуального отображения пользователю, можно пойти другим путем: имеется возможность вывести реквизит от ссылочного значения на форму. При этом пользователь не сможет отредактировать этот реквизит.
Рассмотрим пример: на форме документа рядом с полем ввода контрагента должен выводиться его ИНН. Для этого перенесем реквизит ИНН на форму:
В пользовательском режиме при указании контрагента, его ИНН будет автоматически отображен на форме. Никакого программирования в этом случае не потребовалось.
Как получить доступ к реквизитам объекта?
Статья носит справочный характер. Предназначена для начинающих программистов.
Получить массив реквизитов объекта можно при помощи самого объекта:
ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
ДокОбъект = ДокСсылка.ПолучитьОбъект();
МассивРеквизитовОбъекта = ДокОбъект.Метаданные().Реквизиты;
Получив массив реквизитов, можно организовать Цикл для просмотра имен реквизитов:
Для каждого Реквизит Из ДокОбъект.Метаданные().Реквизиты Цикл
Сообщить(Реквизит.Имя + " :" + Реквизит.Представление());
КонецЦикла;
Для того, чтобы получить значения реквизитов объекта вообще говоря надо обратиться с запросом к БД, типа:
Запрос = "ВЫБРАТЬ
| ИмяРеквизита,
|ИЗ
| Объект.ТипОбъекта КАК ОбъектТипОбъекта
|ГДЕ
| ОбъектТипОбъекта.Ссылка = &СсылкаНаОбъект
Запрос.УстановитьПараметр("СсылкаНаОбъект", СсылкаНаОбъект);
В запрос надо передать ссылку на объект и имя реквизита. Запрос вернет таблицу или выборку со значением реквизита.
Удобнее конечно для поиска значений реквизитов воспользоваться готовыми решениями, например фунцией ПолучитьЗначенияРеквизитов() общего модуля ОбщегоНазначения.
// Возвращает структуру, содержащую значения реквизитов прочитанные из информационной базы
// по ссылке на объект.
//
// Если доступа к одному из реквизитов нет, возникнет исключение прав доступа.
// Если необходимо зачитать реквизит независимо от прав текущего пользователя,
// то следует использовать предварительный переход в привилегированный режим.
//
// Параметры:
// Ссылка - ссылка на объект, - элемент справочника, документ, ...
// ИменаРеквизитов - Строка или Структура - Если Строка, то имена реквизитов,
// перечисленные через запятую, в формате требований к свойствам структуры.
// Например, "Код, Наименование, Родитель".
// Если Структура, то в качестве ключа передается псевдоним поля для
// возвращаемой структуры с результатом, а в качестве значения (опционально)
// - фактическое имя поля в таблице.
// Если значение не определено, то имя поля берется из ключа.
//
// Возвращаемое значение:
// Структура - содержит список свойств, как список имен в строке
// ИменаРеквизитов, со значениям реквизитов, прочитанных
// из информационной базы.
//
Функция ПолучитьЗначенияРеквизитов(Ссылка, ИменаРеквизитов) Экспорт
Если ТипЗнч(ИменаРеквизитов) = Тип("Структура") Тогда
СтруктураРеквизитов = ИменаРеквизитов;
ИначеЕсли ТипЗнч(ИменаРеквизитов) = Тип("Строка") Тогда
СтруктураРеквизитов = Новый Структура(ИменаРеквизитов);;
Иначе
ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
НСтр("ru = 'Неверный тип второго параметра ИменаИлиСтруктураРеквизитов: %1'"),
Строка(ТипЗнч(ИменаРеквизитов)));
КонецЕсли;
ТекстПолей = "";
Для каждого КлючИЗначение Из СтруктураРеквизитов Цикл
ИмяПоля = ?(ЗначениеЗаполнено(КлючИЗначение.Значение), СокрЛП(КлючИЗначение.Значение), СокрЛП(КлючИЗначение.Ключ));
Псевдоним = СокрЛП(КлючИЗначение.Ключ);
ТекстПолей = ТекстПолей + ?(ПустаяСтрока(ТекстПолей), "", ",") + "
| " + ИмяПоля + " КАК " + Псевдоним;
КонецЦикла;
Запрос = Новый Запрос(
"ВЫБРАТЬ
|" + ТекстПолей + "
|ИЗ
| " + Ссылка.Метаданные().ПолноеИмя() + " КАК ПсевдонимЗаданнойТаблицы
|ГДЕ
| ПсевдонимЗаданнойТаблицы.Ссылка = &Ссылка
|");
Запрос.УстановитьПараметр("Ссылка", Ссылка);
Выборка = Запрос.Выполнить().Выбрать();
Выборка.Следующий();
Результат = Новый Структура;
Для каждого КлючИЗначение Из СтруктураРеквизитов Цикл
Результат.Вставить(КлючИЗначение.Ключ);
КонецЦикла;
ЗаполнитьЗначенияСвойств(Результат, Выборка);
Возврат Результат;
КонецФункции
Значение реквизитов в этой функции получено через запрос к БД. Возвращаемое значение — структура (ключ-значение). Пример использования:
ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
СтруктураНастроек = Новый Структура;
//инициируем структуру настроек именами реквизитов
Для каждого Реквизит Из ДокОбъект.Метаданные().Реквизиты Цикл
СтруктураНастроек.Вставить(Реквизит.Имя, Реквизит.Имя);
КонецЦикла;
ЗначенияРеквизитов = ПолучитьЗначенияРеквизитов(ДокСсылка , СтруктураНастроек);
СканПростойСтруктуры(ЗначенияРеквизитов); //вывести структуру для просмотра
Поскольку в функцию ПолучитьЗначенияРеквизитов() во второй параметр надо передать структуру, то мы создали структуру и организовали Цикл ее инициализации данными из массива имен реквизитов объекта. Возвращает функция так же структуру (ключ-значение), с которой удобно работать. Для просмотра этой структуры можно воспользоваться циклом, либо вызвать функцию СканПростойСтруктуры(), которой передать структуру для просмотра.
Функция СканПростойСтруктуры(Структура)
Для каждого Элемент из Структура Цикл
Сообщить(Элемент.Ключ + ": " + Элемент.Значение);
КонецЦикла;
КонецФункции
Если исследуемый объект использует так же еще и общие реквизиты, и их необходимо найти, то можно воспользоваться функцией МассивИменРеквизитовОбъекта(), которая находит не только реквизиты объекта но и общие и даже стандартные реквизиты, которые использует объект:
// Возвращает массив имен всех реквизитов переданного объекта
//
Функция МассивИменРеквизитовОбъекта(Объект) Экспорт
МассивИменРеквизитов = Новый Массив;
Если ТипЗнч(Объект) = Тип("ОбъектМетаданных") Тогда
МетаданныеОбъекта = Объект;
Иначе
МетаданныеОбъекта = Метаданные.НайтиПоТипу(ТипЗнч(Объект));
Если МетаданныеОбъекта = Неопределено Тогда
Возврат МассивИменРеквизитов;
КонецЕсли;
КонецЕсли;
Для индекс = 0 по 1 Цикл
// КоллекцияРеквизитов = ?(индекс = 0, МетаданныеОбъекта.СтандартныеРеквизиты, МетаданныеОбъекта.Реквизиты);
КоллекцияРеквизитов = МетаданныеОбъекта.Реквизиты;
Для каждого Реквизит Из КоллекцияРеквизитов Цикл
МассивИменРеквизитов.Добавить(Реквизит.Имя);
КонецЦикла;
КонецЦикла;
Для каждого ОбщийРеквизит Из Метаданные.ОбщиеРеквизиты Цикл
Если ИспользуетсяОбщийРеквизит(ОбщийРеквизит, МетаданныеОбъекта) Тогда
МассивИменРеквизитов.Добавить(ОбщийРеквизит.Имя);
КонецЕсли;
КонецЦикла;
Возврат МассивИменРеквизитов;
КонецФункции
Тогда программа будет выглядеть так:
ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
ДокОбъект = ДокСсылка.ПолучитьОбъект();
мМассивИмен = МассивИменРеквизитовОбъекта(ДокОбъект);
СтруктураНастроек = Новый Структура;
Для каждого эл Из мМассивИмен Цикл
СтруктураНастроек.Вставить(эл, эл);
КонецЦикла;
ЗначенияРеквизитов = ОбщегоНазначения.ПолучитьЗначенияРеквизитов(ДокСсылка , СтруктураНастроек);
СканПростойСтруктуры(ЗначенияРеквизитов);
Вспомогательная функция:
// Проверяет используется ли в Объекте указанный общий реквизит
//
Функция ИспользуетсяОбщийРеквизит(ОбщийРеквизит, Объект) Экспорт
Если ТипЗнч(Объект) = Тип("ОбъектМетаданных") Тогда
МетаданныеОбъекта = Объект;
Иначе
МетаданныеОбъекта = Метаданные.НайтиПоТипу(ТипЗнч(Объект));
Если МетаданныеОбъекта = Неопределено Тогда
Возврат Ложь;
КонецЕсли;
КонецЕсли;
Если ТипЗнч(ОбщийРеквизит) = Тип("ОбъектМетаданных") Тогда
МетаданныеОбщегоРеквизита = ОбщийРеквизит;
Иначе
МетаданныеОбщегоРеквизита = Метаданные.ОбщиеРеквизиты.Найти(ОбщийРеквизит);
Если МетаданныеОбщегоРеквизита = Неопределено Тогда
Возврат Ложь;
КонецЕсли;
КонецЕсли;
ЭлементСостава = МетаданныеОбщегоРеквизита.Состав.Найти(МетаданныеОбъекта);
Если ЭлементСостава = Неопределено Тогда
Возврат Ложь;
КонецЕсли;
пИспользованиеОбщегоРеквизита = Метаданные.СвойстваОбъектов.ИспользованиеОбщегоРеквизита;
Если ЭлементСостава.Использование = пИспользованиеОбщегоРеквизита.Использовать Тогда
Возврат Истина;
ИначеЕсли ЭлементСостава.Использование = пИспользованиеОбщегоРеквизита.НеИспользовать Тогда
Возврат Ложь;
Иначе
пАвтоИспользованиеОбщегоРеквизита = Метаданные.СвойстваОбъектов.АвтоИспользованиеОбщегоРеквизита;
Если МетаданныеОбщегоРеквизита.АвтоИспользование = пАвтоИспользованиеОбщегоРеквизита.Использовать Тогда
Возврат Истина;
Иначе
Возврат Ложь;
КонецЕсли;
КонецЕсли;
КонецФункции
Как получить значение отдельного реквизита объекта?
Иногда необязательно получать значения всего массива реквизитов. Программист как правило знает имя реквизита, значение которого необходимо получить. К отдельному реквизиту объекта можно обратиться просто по его имени:
Поставщик = ДокОбъект.Метаданные().Реквизиты.Поставщик;
Получить значение этого реквизита можно так же через запрос, написанный специально для этого реквизита. Но можно воспользоваться все той же функцией ПолучитьЗначенияРеквизитов(). Цикл для настройки структуры в этом случае не нужен, так как нам надо найти значение всего одного элемента:
ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
ДокОбъект = ДокСсылка.ПолучитьОбъект();
Организация = Строка(ДокОбъект.Метаданные().Реквизиты.Организация);
СтруктураНастроек = Новый Структура;
СтруктураНастроек.Вставить(Организация, Организация);
ЗначенияРеквизитов = ОбщегоНазначения.ПолучитьЗначенияРеквизитов(ДокСсылка , СтруктураНастроек);
СканПростойСтруктуры(ЗначенияРеквизитов);
Обратите внимание что здесь реквизит который необходимо найти преобразовывается к типу Строка, потому, что в структуру настроек надо передать именно строку.
Как найти имена реквизитов в таб части объекта?
Функция определяет есть ли реквизит в таб части документа:
// Позволяет определить есть ли среди реквизитов табличной части документа
// реквизит с переданным именем.
//
// Параметры:
// ИмяРеквизита - строковое имя искомого реквизита,
// МетаданныеДокумента - объект описания метаданных документа, среди реквизитов которого производится поиск.
// ИмяТабЧасти - строковое имя табличной части документа, среди реквизитов которого производится поиск
//
// Возвращаемое значение:
// Истина - нашли реквизит с таким именем, Ложь - не нашли.
//
Функция ЕстьРеквизитТабЧастиДокумента(ИмяРеквизита, МетаданныеДокумента, ИмяТабЧасти) Экспорт
ТабЧасть = МетаданныеДокумента.ТабличныеЧасти.Найти(ИмяТабЧасти);
Если ТабЧасть = Неопределено Тогда // Нет такой таб. части в документе
Возврат Ложь;
Иначе
Возврат НЕ (ТабЧасть.Реквизиты.Найти(ИмяРеквизита) = Неопределено);
КонецЕсли;
КонецФункции
Пример использования:
ИмяРеквизита = "Номенклатура";
МетаданныеДокумента = ДокОбъект.Метаданные();
ИмяТабЧасти = "Товары";
Если ЕстьРеквизитТабЧастиДокумента(ИмяРеквизита, МетаданныеДокумента, ИмяТабЧасти) Тогда
Сообщить("Реквизит есть!");
Иначе
Сообщить("Реквизита нет");
КонецЕсли;
Сообщить имя реквизитов таб части:
Для каждого Реквизит Из ДокОбъект.Метаданные().ТабличныеЧасти.Найти("Товары").Реквизиты Цикл
Собщить(Реквизит.Имя);
КонецЦикла;
Как найти значение всех реквизитов всех таб частей документа через запрос
Чтобы найти значения всех реквизитов всех табличных частей объекта через запрос воспользуемся функцией
ПолучитьЗначенияРеквизитовТабЧасти().
Функция ПолучитьЗначенияРеквизитовТабчасти(Ссылка, ИменаРеквизитов, ИмяТабЧасти) Экспорт
ИмяТЧ = ИмяТабЧасти;
ПолноеИмя = Ссылка.Метаданные().ПолноеИмя();
Если ТипЗнч(ИменаРеквизитов) = Тип("Структура") Тогда
СтруктураРеквизитов = ИменаРеквизитов;
ИначеЕсли ТипЗнч(ИменаРеквизитов) = Тип("Строка") Тогда
СтруктураРеквизитов = Новый Структура(ИменаРеквизитов);;
Иначе
ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
НСтр("ru = 'Неверный тип второго параметра ИменаИлиСтруктураРеквизитов: %1'"),
Строка(ТипЗнч(ИменаРеквизитов)));
КонецЕсли;
ТекстПолей = "";
Для Каждого КлючИЗначение Из СтруктураРеквизитов Цикл
ИмяПоля = ?(ЗначениеЗаполнено(КлючИЗначение.Значение), СокрЛП(КлючИЗначение.Значение), СокрЛП(КлючИЗначение.Ключ));
Псевдоним = СокрЛП(КлючИЗначение.Ключ);
ТекстПолей = ТекстПолей + ?(ПустаяСтрока(ТекстПолей), "", ",") + "
| " + ИмяПоля + " КАК " + Псевдоним;
КонецЦикла;
Запрос = Новый Запрос(
"ВЫБРАТЬ
|" + ТекстПолей + "
|ИЗ
| " + ПолноеИмя + "." + ИмяТЧ + " КАК ПсевдонимЗаданнойТаблицы
|ГДЕ
| ПсевдонимЗаданнойТаблицы.Ссылка = &Ссылка
|");
Запрос.УстановитьПараметр("Ссылка", Ссылка);
Результат = Запрос.Выполнить().Выгрузить();
Возврат Результат;
КонецФункции
Пример использования:
ДокСсылка = СсылкаНаДокумент(ТипДокумента, НомерДок);
ДокОбъект = ДокСсылка.ПолучитьОбъект();
МассивТабЧастей = Новый Массив;
Для каждого ТабЧасть Из ДокОбъект.Метаданные().ТабличныеЧасти Цикл
МассивТабЧастей.Добавить(ТабЧасть.Имя);
КонецЦикла;
Для Каждого ТабЧасть Из МассивТабЧастей Цикл
СтруктураНастроек = Новый Структура;
Для каждого Реквизит Из ДокОбъект.Метаданные().ТабличныеЧасти.Найти(ТабЧасть).Реквизиты Цикл
СтруктураНастроек.Вставить(Реквизит.Имя, Реквизит.Имя);
КонецЦикла;
Сообщить("Имя таб части: " + ТабЧасть);
ТабЗнач = ПолучитьЗначенияРеквизитовТабЧасти(ДокСсылка , СтруктураНастроек, ТабЧасть);
ПоказатьТаблицу(ТабЗнач);
КонецЦикла;
Вспомогательная функция:
функция ПоказатьТаблицу(Табл)
Сообщить("///Функция ПоказатьТаблицу///");
Количество = Табл.Колонки.Количество();
Для каждого Строка из Табл Цикл
Для Индекс = 0 По Количество-1 Цикл
Сообщить(СокрЛП(Индекс)+" "+СокрЛП(Табл.Колонки[Индекс].Имя)+ ": " + Строка[СокрЛП(Табл.Колонки[Индекс].Имя)]);
КонецЦикла;
КонецЦикла;
Сообщить("///Конец Функция ПоказатьТаблицу///");
КонецФункции
Результат для документа «Реализация товаров услуг»:
Имя таб части: Товары
///Функция ПоказатьТаблицу///
0 ЕдиницаИзмерения: шт
1 ЕдиницаИзмеренияМест:
2 Качество: Новый
3 Количество: 1
4 КоличествоМест: 0
5 Коэффициент: 1
6 Номенклатура: Вентилятор настольный
7 ПроцентСкидкиНаценки: 0
8 СерияНоменклатуры: Н-908, С-890 от 01.01.2003
9 СпособСписанияОстаткаТоваров: Со склада
10 СтавкаНДС: Без НДС
11 Сумма: 445,5
12 СуммаНДС: 0
13 ХарактеристикаНоменклатуры:
14 Цена: 450
15 Склад: Магазин «Бытовая техника»
16 ПроцентАвтоматическихСкидок: 1
17 УсловиеАвтоматическойСкидки: По виду дисконтных карт
18 ЗначениеУсловияАвтоматическойСкидки: Серебряная карта
19 КлючСтроки: 3
20 КлючСвязи: 0
21 ЗаказПокупателя: Заказ покупателя ТД000000001 от 08.06.2008 12:00:00
0 ЕдиницаИзмерения: шт
1 ЕдиницаИзмеренияМест:
2 Качество: Новый
3 Количество: 1
4 КоличествоМест: 0
5 Коэффициент: 1
6 Номенклатура: Набор вентиляторов
7 ПроцентСкидкиНаценки: 0
8 СерияНоменклатуры:
9 СпособСписанияОстаткаТоваров: Со склада
10 СтавкаНДС: Без НДС
11 Сумма: 1948,32
12 СуммаНДС: 0
13 ХарактеристикаНоменклатуры:
14 Цена: 1968
15 Склад: Магазин «Бытовая техника»
16 ПроцентАвтоматическихСкидок: 1
17 УсловиеАвтоматическойСкидки: По виду дисконтных карт
18 ЗначениеУсловияАвтоматическойСкидки: Серебряная карта
19 КлючСтроки: 4
20 КлючСвязи: 0
21 ЗаказПокупателя: Заказ покупателя ТД000000001 от 08.06.2008 12:00:00
///Конец Функция ПоказатьТаблицу///
Имя таб части: ВозвратнаяТара
///Функция ПоказатьТаблицу///
///Конец Функция ПоказатьТаблицу///
Имя таб части: Услуги
///Функция ПоказатьТаблицу///
///Конец Функция ПоказатьТаблицу///
Имя таб части: СоставНабора
///Функция ПоказатьТаблицу///
0 Номенклатура: Вентилятор BINATONE ALPINE 160вт, напольный ,
1 ХарактеристикаНоменклатуры:
2 СерияНоменклатуры: 01234/11020/7654321, БОЛГАРИЯ
3 Количество: 1
4 ЕдиницаИзмерения: шт
5 Склад: Магазин «Бытовая техника»
6 Качество: Новый
7 СпособСписанияОстаткаТоваров: Со склада
8 КлючСтроки: 4
9 Цена: 1068
10 КлючСвязи: 0
0 Номенклатура: Вентилятор JIPONIC (Тайв.),
1 ХарактеристикаНоменклатуры:
2 СерияНоменклатуры: 11234/11020/7654321, ТАЙВАНЬ (КИТАЙ)
3 Количество: 1
4 ЕдиницаИзмерения: шт
5 Склад: Магазин «Бытовая техника»
6 Качество: Новый
7 СпособСписанияОстаткаТоваров: Со склада
8 КлючСтроки: 4
9 Цена: 900
10 КлючСвязи: 0
///Конец Функция ПоказатьТаблицу///
Имя таб части: СерийныеНомера
///Функция ПоказатьТаблицу///
///Конец Функция ПоказатьТаблицу///
Имя таб части: СерийныеНомераСоставНабора
///Функция ПоказатьТаблицу///
///Конец Функция ПоказатьТаблицу///
Имя таб части: ДокументыРасчетовСКонтрагентом
///Функция ПоказатьТаблицу///
///Конец Функция ПоказатьТаблицу///
Способы получения реквизитов объекта (Помогите разобраться)
Автор Nikolai999, 22 сен 2019, 14:22
0 Пользователей и 1 гость просматривают эту тему.
Здравствуйте!
Только начинаю программировать в 1С, поэтому есть несколько (возможно простых) вопросов:
У меня имеется ссылка на объект, и мне нужно получить несколько его реквизитов. Что будет работать быстрее: получение каждого реквизита отдельно «через точку», или запрос?
Второй вопрос: у меня имеется ссылка на документ, и мне нужно скопировать его табличную часть в другой документ. Как это правильно реализовать? Через ссылку или запросом? И если запросом, то как его правильно написать?
Третий вопрос: когда лучше использовать запрос, а когда получение «через точку»?
Большое спасибо!
(0) если реквизиты нужны МНОГО раз, то лучше СРАЗУ их из базы запросом достать и использовать, а если ПРОСТО Ссылка.Наименование, то запрос ДОЛЬШЕ писать…
если другой документ вводится на основании исходного, то ЕСТЬ ОбработкаЗаполнения, а если ПРОСТО копируешь, то Выгрузить() — Загрузить()
у каждой задачи есть ОПТИМАЛЬНОЕ решение, когда запрос, когда «через точку»…
Представьте себе, какая была бы тишина, если бы люди говорили только то, что знают
Получение любого реквизита ссылки «через точку» приводит к тому, что весь объект целиком (включая табличные части) считывается из базы данных и где-то там в памяти кэшируется. Поэтому в большинстве случаев целесообразно пользоваться запросом.
А если более подробно то:
Всегда нужно думать о том, что дальше происходит в коде и о размере прочитанных данных. Если это справочник из 3х реквизитов и вы получаете один из них через точку — да и пускай. Данные не того объёма чтоб городить запрос, гораздо легче Ссылка.ИмяРеквизита написать.
Или допустим это ДокументСсылка, с которой вы далее в коде будете активно работать, читать табличные части, в цикле обходить строки и т.д. — тут смело получаете нужный вам реквизит через точку.
Во всех остальных случаях я бы рекомендовал использовать запрос. В Стандартных Подсистемах есть функции «ПолучитьЗначениеРеквизита» и «ПолучитьЗначенияРеквизитов», предназначенные специально для чтения всех нужных реквизитов за раз запросом.
Перейти к контенту
Перейти в раздел примеры кода 1С 8.3:
1С 8.3 БСП ЗначениеРеквизитаОбъекта. Возвращает значения реквизита, прочитанного из информационной базы по ссылке на объект. Рекомендуется использовать вместо обращения к реквизитам объекта через точку от ссылки на объект для быстрого чтения отдельных реквизитов объекта из базы данных. Функция доступна только на сервере, но если нужно получить реквизит на клиенте, то я ищу модуль ВызовCервера, например, в БП 3.0 это ОбменСКонтрагентамиСлужебныйВызовСервера.ЗначениеРеквизитаОбъекта/
Примера кода от rayastar
&НаКлиенте
Процедура ЗначениеРеквизитаОбъекта(Команда)
// Использование на клиенте.
СтранаПроисхождения = ОбщегоНазначенияРТВызовСервера.ЗначениеРеквизитаОбъекта(Номенклатура,«СтранаПроисхождения»);
// Использование на сервере
СтранаПроисхождения = СтранаПроисхождения();
КонецПроцедуры
&НаСервере
Функция СтранаПроисхождения()
Возврат ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Номенклатура, «СтранаПроисхождения»);
КонецФункции
// Автор библиотеки: ООО «1С-Софт». Все права защищены © 2021
// Типовая конфигурация Библиотека стандартных подсистем (далее — БСП)
// Код БСП распространяется по лицензии Attribution 4.0 International (CC BY 4.0):
// ссылка на лицензию: https://creativecommons.org/licenses/by/4.0/legalcode
Функция БСП
Функция ЗначениеРеквизитаОбъекта(Ссылка, ИмяРеквизита, ВыбратьРазрешенные = Ложь) Экспорт
Если ПустаяСтрока(ИмяРеквизита) Тогда
ВызватьИсключение
НСтр(«ru = ‘Неверный второй параметр ИмяРеквизита в функции ОбщегоНазначения.ЗначениеРеквизитаОбъекта:
|- Имя реквизита должно быть заполнено'»);
КонецЕсли;
Результат = ЗначенияРеквизитовОбъекта(Ссылка, ИмяРеквизита, ВыбратьРазрешенные);
Возврат Результат[СтрЗаменить(ИмяРеквизита, «.», «»)];
КонецФункции
// Автор библиотеки: ООО «1С-Софт». Все права защищены © 2021
// Типовая конфигурация Библиотека стандартных подсистем (далее — БСП)
// Код БСП распространяется по лицензии Attribution 4.0 International (CC BY 4.0):
// ссылка на лицензию: https://creativecommons.org/licenses/by/4.0/legalcode
Функция на клиенте
ОбщегоНазначенияУТВызовСервера.ЗначенияРеквизитовОбъекта(Ссылка, ИмяРеквизита, ВыбратьРазрешенные);
Copyright©, «Программист 1С в г.Минске», 07.06.2021
Перепечатка текста и фотографий разрешена при наличии прямой ссылки на источник
Мы уже познакомились с таким понятием, как объект в 1С , следующим шагом будет логично познакомиться с таким понятием, как ссылка в 1С.
Ссылка указывает на данные экземпляра объекта, но не хранит их, т.е. получив ссылку на конкретный экземпляр объекта, мы сможем узнать всю информацию об экземпляре этого объекта, но не сможем внести какие-нибудь коррективы в эту информацию.
Мы помним, что в платформе 1С 8.3. существуют три вида объектов. Это объекты метаданных, общие объекты и универсальные коллекции значений.
Подробно об объектах в 1С
Так вот, ссылка может быть только у объектов метаданных.
Замечу что, ссылка указывает не на сам объект, а на экземпляр объекта. Хотя, очень часто употребляют выражения «ссылка объекта», «ссылка на объект» и т.п.
Все ссылки объектов имеют тип СправочникСсылка.<НазваниеОбъекта>, ДокументСсылка.<НазваниеОбъекта> и т.д.
Ссылку можно использовать в качестве переменной, и также ссылку можно указывать, как реквизит других объектов метаданных.
Например, в моей конфигурации есть справочник Контрагенты.
А также какой-то документ, пусть будет Оплата. И я могу какому-то реквизиту документа Оплата присвоить тип — ссылка на справочник Контрагент.
Это значит, теперь в документе Оплата можно хранить информацию о контрагенте, который сделал оплату.
Если мы используем ссылку в качестве реквизита какого-то объекта, то при редактировании экземпляра, на который указывает ссылка, сам реквизит не изменится.
Поясню на примере. Я выше создал документ Оплата и реквизит Оплативший для этого документа с типом СправочникСсылка.Контрагенты.
Если я переименую элемент справочника Контрагенты.
Затем, зайду обратно в выше созданный документ Оплата, то увижу, что отображение контрагента в реквизите поменялось автоматически.
Что это значит? Это не значит, что реквизит Оплативший элемента и сам элемент справочника Номенклатура поменялся автоматически. Нет, это значит, что данный реквизит хранит указатель на экземпляр объекта, который отображается посредством наименования. Поменяли наименование, поменялось только отображение, если бы поменяли какой-нибудь другой реквизит справочника Контрагенты, то пользователь бы ничего не заметил.
Получить ссылку 1С
Каким образом программно получить ссылку на экземпляр объекта, который уже есть в базе?
Сделать это можно несколькими способами: найти по коду, найти по наименованию, найти по реквизиту и найти по нескольким реквизитам через запрос. Я рассмотрю первые два метода.
Для демонстрации этих методов, на основной форме документа Оплата я создам команду «Установить контрагента», которую размещу в командной панели формы.
При выполнении этой команды я буду в поле Оплативший записывать определенного контрагента. Для этого я создам обработчики команды на клиенте и на сервере.
Первый способ получения ссылки: найти по коду, для поиска по коду необходимо использовать функцию менеджера объекта НайтиПоКоду.
Объект.Оплативший = Справочники.Контрагенты.НайтиПоКоду("000000002");
Функция НайтиПоКоду вернёт ссылку на экземпляр объекта справочник Контрагенты, которому соответствует код 000000002. Почему мы задали код в виде строки, а не в виде цифры, например? Чтобы понять это, нужно открыть непосредственно редактор справочника Контрагенты в конфигураторе, перейти на закладку «Данные» и посмотреть, какой тип кода у этого справочника.
Тип кода у справочника Контрагенты — строка, поэтому код мы ищем по строковому значению.
Таким образом, данный код:
Справочники.Контрагенты.НайтиПоКоду("000000002")
возвращает ссылку на справочник Контрагенты, код у которого 000000002. Если такой нет, возвращается пустая ссылка (о них ниже), если с таким кодом несколько элементов, то возвращается один из них, какой конкретно — предугадать невозможно, платформа выберет элемент по своим внутренним идентификаторам.
Рассмотрим синтаксис этой функции для менеджера справочника:
НайтиПоКоду(<Код>,<ПоискПоПолномуКоду>,<Родитель>,<Владелец>)
Где:
Код – непосредственно тот код, по которому мы ищем наш элемент;
ПоискПоПолномуКоду — если стоит параметр Истина, то поиск будет вестись по кодам всей иерархии, т.е. Вам необходимо будет указывать код каждой группы, куда входит элемент через флеш. Например, так: 001/005/110, где слева будет располагаться самая верхняя группа, а справа непосредственно код элемента.
Данное поле необязательно, по умолчанию – Ложь;
Родитель – для иерархических справочников можно указать группу, тогда поиск будет вестись внутри группы. Данное поле необязательно;
Владелец – для подчиненных справочников можно указать владельца, тогда поиск будет вестись только среди элементов, подчиненных данному владельцу. Данное поле необязательно.
Второй способ получения ссылки: найти по наименованию, для поиска по наименованию необходимо использовать функцию менеджера объекта НайтиПоНаименованию.
Объект.Оплативший = Справочники.Контрагенты.НайтиПоНаименованию("ООО Поставка");
Этот способ можно применить только для тех объектов, у которых имеется стандартный реквизит Наименование.
Например, у справочников этот реквизит имеется.
А у документов его нет.
В случае этой функции, поиск ведется по тому значению, которое в поле Наименование объекта
Синтаксис функции для менеджера справочника следующий:
НайтиПоНаименованию(<Наименование>,<ТочноеСоответствие>,<Родитель>,<Владелец>)
Где:
«Наименование» – непосредственно то наименование, по которому мы ищем наш элемент;
«ТочноеСоответствие» — если стоит параметр Ложь, то поиск будет вестись не точно, т.е. когда левая часть наименования элемента и строка поиска будут совпадать (например, Металл и Металл 01), то поиск выдаст результат. Если стоит Истина, то будут найдены только те элементы, наименование которых будет точно совпадать со строкой поиска.
Данное поле необязательно, по умолчанию – Ложь.
Помните это, что по умолчанию поиск ведется не точно;
Параметры «Родитель» и «Владелец» точно такие же, как для процедуры НайтиПоКоду.
Пустая ссылка 1С
У Вас уже, наверное, назрел вопрос: что будут возвращать методы НайтиПоКоду, НайтиПоНаименованию, если такой элемент справочника не был найден. Они будут возвращать Пустую ссылку. Пустая ссылка — это пустое значение какого-нибудь справочника или документа. У менеджеров справочника или документа есть методы, которые возвращают пустую ссылку соответствующих объектов.
Выглядит он так:
ПустаяНоменклатура= Справочники.Номенклатура.ПустаяСсылка();
ПустаяОплата = Документы.Оплата.ПустаяСсылка();
Переменные ПустаяНоменклатура и ПустаяОплата содержат в себе пустые ссылки на каждый объект.
Обращаю Ваше внимание, что для каждого вида справочника и каждого документа будет своя собственная пустая ссылка.
Данный метод очень удобно использовать, когда нам необходимо знать, найден ли элемент справочника по коду (названию) или нет.
Например, доработаем код выше: если элемента с таким названием нет, то выведем сообщение.
ПоставкаОплативший = Справочники.Контрагенты.НайтиПоНаименованию("ООО Поставка"); Если ПоставкаОплативший = Справочники.Контрагенты.ПустаяСсылка() Тогда Сообщить("Не найден контрагент по наименованию ООО Поставка"); иначе Объект.Оплативший = ПоставкаОплативший; КонецЕсли;
ПустаяСсылка() – это метод менеджера объекта. Также есть метод ссылки объекта Пустая(), который возвращает тип булево. Истина — если это пустая ссылка. Код выше можно переделать:
ПоставкаОплативший = Справочники.Контрагенты.НайтиПоНаименованию("ООО Поставка"); Если ПоставкаОплативший.Пустая() Тогда Сообщить("Не найден контрагент по наименованию ООО Поставка"); иначе Объект.Оплативший = ПоставкаОплативший; КонецЕсли;
Метод Пустая() удобно использовать работая в клиентском контексте (в том числе на тонком клиенте), потому что менеджер объекта это «тяжелый» объекта и с ним можно работать только в серверном контексте. Т.е. установку контрагента можно сделать таким способом:
&НаСервере Процедура УстановитьКонтрагентаНаСервере() ПоставкаОплативший = Справочники.Контрагенты.НайтиПоНаименованию("ООО Поставка"); Если Не ПоставкаОплативший = Справочники.Контрагенты.ПустаяСсылка() Тогда Объект.Оплативший = ПоставкаОплативший; КонецЕсли; КонецПроцедуры &НаКлиенте Процедура УстановитьКонтрагента(Команда) УстановитьКонтрагентаНаСервере(); Если Объект.Оплативший.Пустая() Тогда ПоказатьПредупреждение(,"Не найден контрагент по наименованию ООО Поставка"); КонецЕсли; КонецПроцедуры
В этом коде я получаю по наименованию ссылку на нужного контрагента, делаю это в серверном методе, поскольку обращаюсь к менеджеру справочника, записываю если он не пустой, а потом в клиентском методе проверяю, найден контрагент по такому наименованию или нет, если не найден то вывожу предупреждение.
Более подробно и основательно начальные вопросы программирования в 1С есть вы можете изучить в
Книга «Программировать в 1С за 11 шагов»
Изучайте программирование в 1С в месте с моей книгой «Программировать в 1С за 11 шагов»
Книга написана понятным и простым языком — для новичка.
- Книга посылается на электронную почту в формате PDF. Можно открыть на любом устройстве!
- Научитесь понимать архитектуру 1С;
- Станете писать код на языке 1С;
- Освоите основные приемы программирования;
- Закрепите полученные знания при помощи задачника.
О том как разрабатывать под управляемым приложением 1С, читайте в книге Книга «Основы разработки в 1С: Такси»
Отличное пособие по разработке в управляемом приложении 1С, как для начинающих разработчиков, так и для опытных программистов.
- Очень доступный и понятный язык изложения
- Книга посылается на электронную почту в формате PDF. Можно открыть на любом устройстве!
- Поймете идеологию управляемого приложения 1С
- Узнаете, как разрабатывать управляемое приложение;
- Научитесь разрабатывать управляемые формы 1С;
- Сможете работать с основными и нужными элементами управляемых форм
- Программирование под управляемым приложением станет понятным
Промо-код на скидку в 15% — 48PVXHeYu
Эти книги, плюс книга по программированию оперативного учета имеются в едином комплекте: комплект книг по разработке в 1С.
Только для читателей моего блога,
промо-код на скидку в 300 рублей на весь комплект: blog
Если Вам понравился этот урок, был полезен или помог решить какую-нибудь проблему, то Вы можете поддержать мой проект, перечислив любую сумму.
можно оплатить вручную:
Яндекс.Деньги — 410012882996301
Web Money — R955262494655
Вступайте в мои группы:
Вконтакте: https://vk.com/1c_prosto
Фейсбуке: https://www.facebook.com/groups/922972144448119/
ОК: http://ok.ru/group/52970839015518
Твиттер: https://twitter.com/signum2009