1с как на клиенте получить реквизиты ссылки

Как получить реквизит от ссылочного значения на клиенте

На чтение 2 мин Просмотров 6.3к. Опубликовано 20.04.2017

На стороне клиента нельзя обратиться к данным базы, в т.ч. получить реквизит от ссылочного значения. Рассмотрим как все же можно решить эту задачу.

На стороне клиента код вида
Контрагент.ИНН
приведет к ошибке. Такие конструкции возможны только на сервере.

Предположим, что стоит задача при нажатии на кнопку отобразить ИНН контрагента, выбранного на форме. Для решения поставленной задачи необходимо обратиться на сервер для получения требуемой информации(ИНН). Программный код может иметь вид:

&НаКлиенте
Процедура ПолучитьИНН(Команда)
// Вызов серверной внеконтекстной функции
ИННКонтрагента = ПолучитьИНННаСервере(Контрагент);
Сообщить("ИНН контрагента: " + ИННКонтрагента);
КонецПроцедуры

&НаСервереБезКонтекста
Функция ПолучитьИНННаСервере(Контрагент)
Возврат Контрагент.ИНН;
КонецФункции
При нажатии на кнопку ПолучитьИНН вызывается серверная функция ПолучитьИНННаСервере(). В единственном параметре передается контрагент, выбранный интерактивно пользователем. Функция получает ИНН через точку и сразу же возвращает значение обратно на клиент. Результат работы серверной функции помещается в переменную ИННКонтрагента и выводится пользователю с помощью метода Сообщить().

Серверная функция является внеконтекстной (&НаСервереБезКонтекста). Это значит, что данные, содержащиеся в форме, не будут отсылаться на сервер, что уменьшит объем передаваемых данных и скорость возврата результата функции.

---

Внимание!

При работе с конфигурациями, в которые встроена библиотека стандартных подсистем, вместо получения реквизита через точку рекомендуется использовать функцию ЗначениеРеквизитаОбъекта() из общего модуля ОбщегоНазначения. Таким образом, строку

Возврат Контрагент.ИНН;

можно заменить на:

Возврат ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Контрагент, "ИНН");

---

В случае, когда значение реквизита нужно только для визуального отображения пользователю, можно пойти другим путем: имеется возможность вывести реквизит от ссылочного значения на форму. При этом пользователь не сможет отредактировать этот реквизит.

Рассмотрим пример: на форме документа рядом с полем ввода контрагента должен выводиться его ИНН. Для этого перенесем реквизит ИНН на форму:

В пользовательском режиме при указании контрагента, его ИНН будет автоматически отображен на форме. Никакого программирования в этом случае не потребовалось.

Задача заключается в том, чтобы получить реквизит от ссылочного значения, хранящегося в реквизите формы. Например у документа Накладная есть реквизит ссылочного типа – Поставщик. Необходимо получить ИНН этого поставщика:

Мы находимся в модуле формы на клиенте. В контексте клиента ссылочные типы очень сильно ограничены в своих возможностях. В частности, нельзя получить значение реквизита от ссылки «через точку». Это можно сделать только в контексте сервера.

Поэтому для решения этой задачи в модуле формы создадим серверную внеконтекстную функцию, которую вызовем с клиента и передадим в нее ссылку на поставщика. В теле функции, на сервере, мы получим ИНН поставщика и вернем его на клиента.

Например, локальная команда формы, вызывающая серверную функцию, будет выглядеть следующим образом:

&НаКлиенте
Процедура ПолучитьИННПоставщика(Команда)

   ИННПоставщика = ПолучитьИНННаСервере(Объект.Поставщик);

КонецПроцедуры 

А функцию ПолучитьИНННаСервере() опишем здесь же, в модуле формы:

&НаСервереБезКонтекста
Функция ПолучитьИНННаСервере(СсылкаНаПоставщика)

   Возврат СсылкаНаПоставщика.ИНН;

КонецФункции   

Таким образом на сервере мы сразу же получаем значение реквизита «через точку» от полученной ссылки и возвращаем его на клиента.

Важно заметить, что функция ПолучитьИНННаСервере() не использует контекст формы (директива компиляции &НаСервереБезКонтекста). Потому что все, что нужно передать на сервер, – это только ссылка, и мы передаем ее в параметре функции. Использовать контекстный вызов и передавать на сервер весь контекст формы только ради того, чтобы на сервере взять из него значение одного реквизита формы, — это слишком расточительно.

Перейти к контенту

Перейти в раздел примеры кода 1С 8.3:

1С 8.3 БСП ЗначениеРеквизитаОбъекта. Возвращает значения реквизита, прочитанного из информационной базы по ссылке на объект. Рекомендуется использовать вместо обращения к реквизитам объекта через точку от ссылки на объект для быстрого чтения отдельных реквизитов объекта из базы данных. Функция доступна только на сервере, но если нужно получить реквизит на клиенте, то я ищу модуль ВызовCервера, например, в БП 3.0 это ОбменСКонтрагентамиСлужебныйВызовСервера.ЗначениеРеквизитаОбъекта/

Примера кода от rayastar

&НаКлиенте
Процедура ЗначениеРеквизитаОбъекта(Команда)

   // Использование на клиенте.
   СтранаПроисхождения = ОбщегоНазначенияРТВызовСервера.ЗначениеРеквизитаОбъекта(Номенклатура,«СтранаПроисхождения»);

   // Использование на сервере
   СтранаПроисхождения = СтранаПроисхождения();

КонецПроцедуры

&НаСервере
Функция СтранаПроисхождения()

   Возврат ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Номенклатура, «СтранаПроисхождения»);

КонецФункции

// Автор библиотеки: ООО «1С-Софт». Все права защищены © 2021

// Типовая конфигурация Библиотека стандартных подсистем (далее — БСП)
// Код БСП распространяется по лицензии Attribution 4.0 International (CC BY 4.0):
// ссылка на лицензию: https://creativecommons.org/licenses/by/4.0/legalcode

Функция БСП

Функция ЗначениеРеквизитаОбъекта(Ссылка, ИмяРеквизита, ВыбратьРазрешенные = Ложь) Экспорт

   Если ПустаяСтрока(ИмяРеквизита) Тогда
       ВызватьИсключение
           НСтр(«ru = ‘Неверный второй параметр ИмяРеквизита в функции ОбщегоНазначения.ЗначениеРеквизитаОбъекта:
                    |- Имя реквизита должно быть заполнено'»);
   КонецЕсли;

   Результат = ЗначенияРеквизитовОбъекта(Ссылка, ИмяРеквизита, ВыбратьРазрешенные);
   Возврат Результат[СтрЗаменить(ИмяРеквизита, «.», «»)];

КонецФункции

// Автор библиотеки: ООО «1С-Софт». Все права защищены © 2021

// Типовая конфигурация Библиотека стандартных подсистем (далее — БСП)
// Код БСП распространяется по лицензии Attribution 4.0 International (CC BY 4.0):
// ссылка на лицензию: https://creativecommons.org/licenses/by/4.0/legalcode

Функция на клиенте

ОбщегоНазначенияУТВызовСервера.ЗначенияРеквизитовОбъекта(Ссылка, ИмяРеквизита, ВыбратьРазрешенные);

Copyright©, «Программист 1С в г.Минске», 07.06.2021

Перепечатка текста и фотографий разрешена при наличии прямой ссылки на источник

УФ. Как получить данные через элемент управления на клиенте?

Я

   fisher

18.02.14 — 12:23

Есть ссылка на поле ввода формы справочника, источником данных у которого — реквизит справочника (ссылочного типа).

Как можно на клиенте получить значение этого реквизита справочника (ссылку) без серверных вызовов? Или это невозможно?

Зная имя реквизита, могу сделать это напрямую: Объект.ИмяРеквизита.

А если есть только ссылка на поле ввода? ПутьКДанным непонятно какого рожна только на сервере доступен…

   fisher

1 — 18.02.14 — 12:44

Ммм?

   1Сергей

2 — 18.02.14 — 12:45

   fisher

3 — 18.02.14 — 12:55

>>дальше можно не читать

Ага. Давай, до свиданья.

   Fedor-1971

4 — 18.02.14 — 12:57

(3) Это ты зря.

Что сделать то хочешь, напиши словами без привязки к формам 1С

   Жан Пердежон

5 — 18.02.14 — 13:00

(0) если элементы управления именовать согласованно, то объект[f(Элемент.Имя)]

   grigo

6 — 18.02.14 — 13:12

На клиенте доступна ТОЛЬКО ССЫЛКА. Все остальное — на сервере.

   Жан Пердежон

7 — 18.02.14 — 13:28

(6) да ладно?

   VikingKosmo

8 — 18.02.14 — 13:33

(7) а что есть способ получить значение реквизита объекта прямо таки на клиенте?!

   grigo

9 — 18.02.14 — 13:44

(7) Ну-ка, продемонстрируй.

   grigo

10 — 18.02.14 — 13:47

   Feunoir

11 — 18.02.14 — 13:52

   grigo

12 — 18.02.14 — 14:25

(11) не бойся, мы не кому не скажем, что ты читать не умеешь. Вопрос был в том,  как это сделать, НЕ ВЫЗЫВАЯ СЕРВЕР. Но мы, повторяю, никому не скажем, что ты не умеешь читать.

   Жан Пердежон

13 — 18.02.14 — 14:31

(12) ты читаешь не лучше, вопрос совсем не про вызов сервера

   Feunoir

14 — 18.02.14 — 14:57

(12) Ах-ах. Мне-то казалось, что то, что нельзя получить произвольный реквизит без вызова сервера, уже выяснили. Ну да ладно.

   fisher

15 — 18.02.14 — 15:17

(14) Я только присел на плотную разработку под УФ. Раньше по-мелочам приходилось. Поэтому не все шишки еще набиты.

Ну что ж… Еще одна несуразность в копилку…

   fisher

16 — 18.02.14 — 15:20

Если сабж неясно изложен, поясню с другого бока:

Есть поле ввода на форме, через которое происходит редактирование реквизита справочника. Реквизит хранит ссылку на элемент другого справочника.

Можно ли получить значение этой ссылки, зная имя элемента управления на форме без обращения к серверу?

Как я понял — нельзя.

   fisher

17 — 18.02.14 — 15:24

Чорд. Все равно могут неправильно понять… Итак:

1) есть справочники «Номенклатура» и «Категория»

2) в справочнике «Номенклатура» есть реквизит «Категория» и поле ввода на форме с именем «ВыборКатегории», которое его редактирует

3) можно ли зная имя поля ввода («ВыборКатегории») получить ссылку на категорию без обращению к серверу?

   Fedor-1971

18 — 18.02.14 — 16:18

(17) Посмотри в отладчике Форма.ВыборКатегории.ТекущиеДанные, на сервере туда записана ссылка на справочник Категории. Аналогично будет Объект.Категория — та же ссылка.

&НаКлиенте можно получить ссылку, но полноценно работать с оной не получится, если только передать как параметр куда нить.

   Жан Пердежон

19 — 18.02.14 — 16:27

(18) ТекущиеДанные у поля ввода?

(17) в (5) не ответ? если имена менять нельзя — можно соответствие хранить имяэлемента-имяреквизита, костыль конечно…

   Fedor-1971

20 — 18.02.14 — 16:41

Да лажанулся, через форму ссылку получить не получится, можно только через Объект.

   fisher

21 — 18.02.14 — 16:47

(19) Я просто не могу придумать ни одного логического объяснения тому, что свойство «ПутьКДанным» не транслируется на клиента. Это же гребанная строка! Думал, может я не вкуриваю чего. Оказалось — таки просто еще одна милая фича.

   grigo

22 — 18.02.14 — 19:16

(13) см. (0) строка 2 «без серверных вызовов». И тоже учись читать. )))

   PiVa123

23 — 18.02.14 — 19:24

(21) Это только начало пути УФ. Еще много подобного придется понять и простить … или ругаться на форуме.

   Torquader

24 — 18.02.14 — 19:26

Да, пока они не поймут, что нужно иметь возможность с клиента обращаться к любому объекту на сервере, как это сделано через указатели на нормальных системах — будет ещё много сюрпризов и огорчений.

   Feunoir

25 — 18.02.14 — 19:45

(24) В толстом клиенте таких проблем вообще нет. Проблема только в тонком и web. И то, что так сделано в некотором смысле может быть логичным. Тащить все поля на клиента через кучу промежуточных узлов и тормозных каналов неправильно.

   Torquader

26 — 18.02.14 — 19:52

(25) Тащить надо то, что нужно.

Просто, в нормальных системах есть «Proxy-объекты» для таких целей.

   grigo

27 — 18.02.14 — 19:53

(24) Была такая возможность. И все (ну, почти все) то и дело ОБРАЩАЛИСЬ К ОБЪЕКТУ НА СЕРВЕРЕ. А потом плакали, что у них 1с тормозит.

Поэтому разрабы неявные вызовы сервера сделали явными.

Но не волнуйтесь — тяжело только первые полгода. Дальше все на автомате пойдет.

   Feunoir

28 — 18.02.14 — 19:56

(26) Ну так и делай себе прокси. Сам руками именно то, что нужно. Дернул сервер — он тебе в ответ структуру со всеми реквизитами переданной ссылки. Ты данные на клиенте в кеш положил и пользуешься когда надо. Нормальный взрослый принцип, когда ты сам думаешь, а не система за тебя.

   Torquader

29 — 18.02.14 — 19:58

(28) Ну, тогда, быть может, вместо рисования формы тоже самому думать — тогда зачем 1С.

   Feunoir

30 — 18.02.14 — 20:00

(29) Вот тут соглашусь, конечно. Возможностей по управлению внешним видом управляемых форм частенько не хватает.

(30) Да там вообще мало чего хватает — хочешь данные — пихай в хранилище — передавай и там обрабатывай — а то, что это «матрёшка» и размер растёт — это никому не важно.

Опять же, события с сервера на клиента — а это в идеологию не вписывается — то есть в html-5 Web-сокеты вписываются, а у 1С — ещё не вписывается.

Теги:

Похожие темы (5)

Общий принцип оптимизации заключается в сокрашении количества обращений к базе данных. Для этого в линейном алгоритме анализируем, что за объект перед нами, если это ссылка, то описываем запрос, с помощью которого получаем все данные и в дальнейшем работаем с результатом запроса.

Задача: Описать функции позволяющие получить значения реквизитов различных объектов (независимо от типа объекта). Но ограничимся объектами метаданных конфигурации, которые могут иметь ссылочный тип данных: Справочники, Документы и т.п.

Описанные далее функции желательно располагать в общем серверном модуле без возможности вызова сервера. Если будет возможность вызывать данные функции с клиента, то злоумышленник сможет получить любые данные из базы без особого труда.

Определимся с параметрами:

1. Объект — объект, данные которого необходимо получить;
2. ИменаРеквизитов — Список имен реквизитов, данные которых необходимо получить. Если спиок не указан, то предполагаем, что нужно получить данные всех реквизитов;
3. ДополнительныеРеквизиты — Структура, с помошью которой можно было бы описать дополнительные данные, которые нужно получить вместе с реквизитами объекта (без использования явных соединений с другими таблицами) или выполнение каких-то действий с полями выборки на языке запросов. В ключе элемента структуры описываем имя реквизита в общем списке реквизитов объекта, в значении — поле выборки или алгоритм обработки полей выборки на языке запросов.

Функция ДанныеРеквизитовОбъекта(Объект, ИменаРеквизитов = Неопределено,
                                ДополнительныеРеквизиты = Неопределено) Экспорт

Разберем, значения каких реквизитов необходимо получить из базы и приведем список имен к типу данных Массив.

    СтруктураОбъекта = Новый Структура;
    МетаданныеОбъекта = Объект.Метаданные();

    Если ИменаРеквизитов = Неопределено тогда
        МассивИменРеквизитов = МассивИменРеквизитовОбъекта(Объект);
    иначе
        Если ТипЗнч(ИменаРеквизитов) = Тип(«Массив») тогда
            МассивИменРеквизитов = ИменаРеквизитов;
        иначеЕсли ТипЗнч(ИменаРеквизитов) = Тип(«Строка») тогда
            МассивИменРеквизитов = МассивПодстрокИзСтроки(ИменаРеквизитов);
        КонецЕсли;
    КонецЕсли;

Если список имен не задан, то с помощью функции МассивИменРеквизитовОбъекта() получим массив имен всех реквизитов объекта (алгоритм этой функции смотри ниже).

Если список имен задан в виде строки разделенной запятыми, то разложим ее на подстроки с помошью функции МассивПодстрокИзСтроки(). Это не сложная задача, алгоритм этой функции разбирать не будем.

Далее с помошью функции ЭтоСсылка() определим, является ли объект ссылочным типом. Для ссылочных типов значения необходимо получить из БД, в противном случае значения реквизитов хранятся в памяти.

    ЭтоСсылка = ЭтоСсылка(Объект);
    СсылкаОбъекта = ?(ЭтоСсылка, Объект, Объект.Ссылка);

    ПолучитьДанныеИзОбъекта = НЕ ЭтоСсылка;
    Если ЭтоСсылка И СсылкаОбъекта.Пустая() тогда
        // это пустая ссылка (данных в базе нет)
        ПолучитьДанныеИзОбъекта = Истина;
    КонецЕсли;

Теперь, если данные объекта хранятся в памяти — мы можем их сразу получить, в противном случае необходио подготовиться для составления запроса к БД (переведем список имен реквизитов из типа данных Массив в тип Структура).

    ОсновныеРеквизиты = Новый Структура;
    Для каждого ИмяРеквизита Из МассивИменРеквизитов Цикл
        Если ПолучитьДанныеИзОбъекта тогда
            СтруктураОбъекта.Вставить(ИмяРеквизита, Объект[ИмяРеквизита]);
        иначе
            ОсновныеРеквизиты.Вставить(ИмяРеквизита);
        КонецЕсли;
    КонецЦикла;

Все готово к составлению запроса чтобы получить значения реквизитов если перед нами объект ссылочного типа, а так же для получения дополнительных реквизитов, описанных в 3-ем параметре функции. Но смысл всех этих действий есть, только если данный объект существует в БД (на него есть ссылка).

Для начала составим текст запроса для полей выборки поочередно обходя структуры Основных и Дополнительных реквизитов

    Если НЕ СсылкаОбъекта.Пустая() тогда

        // сформируем текст выборки по реквизитам
        ТекстВыборкиРеквизиты = «»;
        Для индекс = 0 по 1 Цикл
            СтруктураРеквизитов = ?(индекс = 0, ОсновныеРеквизиты, ДополнительныеРеквизиты);
            Если СтруктураРеквизитов = Неопределено тогда
                Продолжить;
            КонецЕсли;
            Для каждого ЭлементСтруктуры из СтруктураРеквизитов Цикл
                Если НЕ МетаданныеОбъекта.ТабличныеЧасти.Найти(ЭлементСтруктуры.Ключ) = Неопределено тогда
                    // это имя табличной части
                    Продолжить;
                КонецЕсли;
                ТекстВыборкиРеквизиты = ТекстВыборкиРеквизиты
                     + ?(ПустаяСтрока(ТекстВыборкиРеквизиты), «», «,» + Символы.ПС)
                     + ?(ЗначениеЗаполнено(ЭлементСтруктуры.Значение), ЭлементСтруктуры.Значение, ЭлементСтруктуры.Ключ)
                     + » КАК » + ЭлементСтруктуры.Ключ;
            КонецЦикла;
        КонецЦикла;

Теперь соберем текст запроса и выполним его. Результат запроса добавим в общую структуру данных объекта

        // получим реквизиты одним запросом
        Если НЕ ПустаяСтрока(ТекстВыборкиРеквизиты) тогда
            Запрос = Новый Запрос;
            Запрос.Текст = «ВЫБРАТЬ
                           |» + ТекстВыборкиРеквизиты + «
                           |ИЗ
                           |    » + МетаданныеОбъекта.ПолноеИмя() + «
                           |ГДЕ
                           |    Ссылка = &Ссылка»;
            Запрос.УстановитьПараметр(«Ссылка», СсылкаОбъекта);
            РезультатЗапроса = Запрос.Выполнить();
            Выборка = РезультатЗапроса.Выбрать();
            Если Выборка.Следующий() тогда
                Для каждого Колонка из РезультатЗапроса.Колонки Цикл
                    СтруктураОбъекта.Вставить(Колонка.Имя, Выборка[Колонка.Имя]);
                КонецЦикла;
            КонецЕсли;
        КонецЕсли;

    КонецЕсли;

Все данные получены, можно завершать функцию

    Возврат СтруктураОбъекта;

КонецФункции // ДанныеРеквизитовОбъекта()

Достоинства алгоритма:

1. Может работать с различными типами объектов конфигурации (которые могут иметь ссылки: Справочники, Документы, ПВХ и т.п.);
2. Получение всех реквизитов за одно обращение к БД;
3. Данные возвращаются в виде структуры, что позволяет их передать далее на клиент без преобразования;
4. С помошью Дополнительных реквизитов можно получить вспомогательные данные (обращение к полям выборки через несколько точек) или на уровне запроса выполнить какие-то действия с данными.
5. Наглядность кода, данные получаются одной функцией, без надобности каждый раз писать запрос к БД с обработкой результата.

Недостатки:

1. Не реализована возможность получения табличных частей объектов

Дополнительные функции использованные в алгоритме:

// Возвращает массив имен всех реквизитов переданного объекта
//
Функция МассивИменРеквизитовОбъекта(Объект) Экспорт

    МассивИменРеквизитов = Новый Массив;

    Если ТипЗнч(Объект) = Тип(«ОбъектМетаданных») тогда
        МетаданныеОбъекта = Объект;
    иначе
        МетаданныеОбъекта = Метаданные.НайтиПоТипу(ТипЗнч(Объект));
        Если МетаданныеОбъекта = Неопределено тогда
            Возврат МассивИменРеквизитов;
        КонецЕсли;
    КонецЕсли;

    Для индекс = 0 по 1 Цикл
        КоллекцияРеквизитов = ?(индекс = 0, МетаданныеОбъекта.СтандартныеРеквизиты, МетаданныеОбъекта.Реквизиты);
        Для Каждого Реквизит Из КоллекцияРеквизитов Цикл
            МассивИменРеквизитов.Добавить(Реквизит.Имя);
        КонецЦикла;
    КонецЦикла;
    Для каждого ОбщийРеквизит Из Метаданные.ОбщиеРеквизиты Цикл
        Если ИспользуетсяОбщийРеквизит(ОбщийРеквизит, МетаданныеОбъекта) тогда
            МассивИменРеквизитов.Добавить(ОбщийРеквизит.Имя);
        КонецЕсли;
    КонецЦикла;

    Возврат МассивИменРеквизитов;

КонецФункции

// Проверяет используется ли в Объекте указанный общий реквизит
//
Функция ИспользуетсяОбщийРеквизит(ОбщийРеквизит, Объект) Экспорт

    Если ТипЗнч(Объект) = Тип(«ОбъектМетаданных») тогда
        МетаданныеОбъекта = Объект;
    иначе
        МетаданныеОбъекта = Метаданные.НайтиПоТипу(ТипЗнч(Объект));
        Если МетаданныеОбъекта = Неопределено тогда
            Возврат Ложь;
        КонецЕсли;
    КонецЕсли;

    Если ТипЗнч(ОбщийРеквизит) = Тип(«ОбъектМетаданных») тогда
        МетаданныеОбщегоРеквизита = ОбщийРеквизит;
    иначе
        МетаданныеОбщегоРеквизита = Метаданные.ОбщиеРеквизиты.Найти(ОбщийРеквизит);
        Если МетаданныеОбщегоРеквизита = Неопределено тогда
            Возврат Ложь;
        КонецЕсли;
    КонецЕсли;

    ЭлементСостава = МетаданныеОбщегоРеквизита.Состав.Найти(МетаданныеОбъекта);
    Если ЭлементСостава = Неопределено тогда
        Возврат Ложь;
    КонецЕсли;

    пИспользованиеОбщегоРеквизита = Метаданные.СвойстваОбъектов.ИспользованиеОбщегоРеквизита;
    Если ЭлементСостава.Использование = пИспользованиеОбщегоРеквизита.Использовать тогда
        Возврат Истина;
    иначеЕсли ЭлементСостава.Использование = пИспользованиеОбщегоРеквизита.НеИспользовать тогда
        Возврат Ложь;
    иначе
        пАвтоИспользованиеОбщегоРеквизита = Метаданные.СвойстваОбъектов.АвтоИспользованиеОбщегоРеквизита;
        Если МетаданныеОбщегоРеквизита.АвтоИспользование = пАвтоИспользованиеОбщегоРеквизита.Использовать тогда
            Возврат Истина;
        иначе
            Возврат Ложь;
        КонецЕсли;
    КонецЕсли;

КонецФункции

При выборе ссылочного значения в поле ввода иногда возникает необходимость специальным образом обработать выбирамемое значение. Например, в документе нужно выбрать поставщика. Но нужно вмешаться в процесс выбора значения и кроме ссылки на поставщика получить еще и другую информацию о поставщике. Например, его полное наименование и ИНН, которые являются реквизитами поставщика.

Для того, чтобы вмешаться в процесс выбора значения используется событие ОбработкаВыбора элемента формы Поле. Это событие поставляется расширением поля ввода. Обработчик этого события имеет такой синтаксис:

ОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)

В параметре ВыбранноеЗначение платформа передает в обработчик то значение, которое выбрал пользователь. В данном случае это будет ссылка на поставщика. Но проблема заключается в том, что обработчик ОбработкаВыбора исполняется на клиенте. А на клиенте возможности ссылки очень сильно ограничены. В частности, от нее нельзя через точку получить значения реквизитов.

Поэтому для того, чтобы в этой ситуации получить значения реквизитов ссылки, нужно из этого обработчика вызвать серверную функцию и в ней получить нужные реквизиты. Например так:

&НаКлиенте
Процедура ОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
    ИНН = ПолучитьРеквизитВыбранногоЗначения(ВыбранноеЗначение);
КонецПроцедуры

&НаСервереБезКонтекста
Функция ПолучитьРеквизитВыбранногоЗначения(ВыбранноеЗначение)
    Возврат ВыбранноеЗначение.ИНН;
КонецФункции

При этом следует иметь ввиду два момента:

• Во-первых, для получения реквизитов используется неконтекстный серверный вызов (&НаСервереБезКонтекста). Это важно, т.к. в этом обработчике нельзя использовать контекстные серверные вызовы (&НаСервере).
• Во-вторых, любое обращение к серверу требует дополнительных ресурсов системы и может замедлять работу пользователя, особенно в случае подключения по низкоскоростному каналу связи. Поэтому нужно прежде всего внимательно оценить, а так ли необходимо в этом месте получать реквизиты ссылки или можно обойтись без этого? И если нужно получать несколько реквизитов и при этом используется какой-то сложный алгоритм — нужно постараться реализовать его так, чтобы все необходимые данные получить за один серверный вызов, вернуть их на клиента и на клиенте только поместить их в нужные поля формы, не проводя каких-то сложных вычислений.

Справка

УправляемаяФорма.ОбработкаВыбора(ВыбранноеЗначение, ИсточникВыбора)

Параметры:

• ВыбранноеЗначение, тип Произвольный. Результат выбора в подчиненной форме. В случае множественного выбора возвращается массив выбранных значений.
• ИсточникВыбора, тип Произвольный. Форма, где осуществлен выбор.

Описание:

• Возникает на клиенте при выборе объекта в одной из подчиненных форм или при вызове в одной из подчиненных форм метода ОповеститьОВыборе.

УправляемаяФорма.ОповеститьОВыборе(ЗначениеВыбора)

Параметры:

• ЗначениеВыбора, обязательный, тип Произвольный. Результат выбора.

Описание:

• Посылает оповещение владельцу формы о выполнении выбора или подбора, передает ему выбранное значение. Закрывает форму в соответствии со значением свойства ЗакрыватьПриВыборе. Данное действие аналогично выполнению выбора в форме, открытой для выбора в поле ввода или ячейке табличного поля.

Доступность:

• Тонкий клиент, веб-клиент, толстый клиент, мобильное приложение (клиент).

Примечание:

• Может применяться в случае, когда открытие формы выбора или подбора выполнено средствами языка.

Поиск:
1С:Предприятие • Обработка выбора • Оповестить о выборе • Управляемая форма • Элемент формы